Focal Point
[Closed] Blocked Design versus focexec

This topic can be found at:
https://forums.informationbuilders.com/eve/forums/a/tpc/f/7971057331/m/1057068495

December 06, 2010, 04:50 AM
MichaelBalle
[Closed] Blocked Design versus focexec
Hi all,

I have to show the data of column COUNTRY as greyed block like it works witout the commented focexec call in the fex below.
If I uncomment the focexec line the COUNTRY block was shown with a border after every CAR.

Is there a possibility to show the border only if the COUNTRY changes?

Thank you very much


The code for the "main" fex:
TABLE FILE CAR
  PRINT
    CAR
    MODEL
  BY COUNTRY
-*
  ON TABLE SET PAGE-NUM OFF
  ON TABLE NOTOTAL
  ON TABLE SET HTMLCSS ON
  ON TABLE PCHOLD FORMAT HTML
  ON TABLE SET STYLE *
-*
  UNITS=IN, SQUEEZE=ON, SIZE = 8, FONT= ARIAL, ORIENTATION=LANDSCAPE,PAGESIZE=A4,
-*
$
  TYPE=REPORT, SIZE=8, FONT = ARIAL,
$
  TYPE=TITLE, SIZE=8, FONT = ARIAL, JUSTIFY = CENTER,
       BORDER-TOP=LIGHT, BORDER-BOTTOM=LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,
       BORDER-TOP-COLOR=WHITE, BORDER-BOTTOM-COLOR=WHITE, BORDER-LEFT-COLOR=WHITE, BORDER-RIGHT-COLOR=WHITE,
       COLOR=WHITE, BACKCOLOR=RGB(240 78 45),
-*
$
  TYPE=DATA, SIZE=8,  FONT= ARIAL,
       BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,
       BORDER-LEFT-COLOR=WHITE, BORDER-RIGHT-COLOR=WHITE, BACKCOLOR=( WHITE RGB(238 238 238) ),
$
-* spalten-inhaltsspezifische Formatierung
  TYPE=DATA,
    COLUMN=COUNTRY,
    BACKCOLOR=SILVER,
    BORDER-BOTTOM=LIGHT,
    BORDER-BOTTOM-COLOR=WHITE,
-*    FOCEXEC=car_country(param1=COUNTRY),
$
END


The code for the called fex:
TABLE FILE CAR
  PRINT
    CAR
    MODEL
  BY CAR
-*
  WHERE COUNTRY EQ ¶m1.QUOTEDSTRING
-*
  ON TABLE SET PAGE-NUM OFF
  ON TABLE NOTOTAL
  ON TABLE SET HTMLCSS ON
  ON TABLE PCHOLD FORMAT HTML
  ON TABLE SET STYLE *
-*
  UNITS=IN, SQUEEZE=ON, SIZE = 8, FONT= ARIAL, ORIENTATION=LANDSCAPE,PAGESIZE=A4,
-*
$
  TYPE=REPORT, SIZE=8, FONT = ARIAL,
$
  TYPE=TITLE, SIZE=8, FONT = ARIAL, JUSTIFY = CENTER,
       BORDER-TOP=LIGHT, BORDER-BOTTOM=LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,
       BORDER-TOP-COLOR=WHITE, BORDER-BOTTOM-COLOR=WHITE, BORDER-LEFT-COLOR=WHITE, BORDER-RIGHT-COLOR=WHITE,
       COLOR=WHITE, BACKCOLOR=RGB(240 78 45),
-*
$
  TYPE=DATA, SIZE=8,  FONT= ARIAL,
       BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,
       BORDER-LEFT-COLOR=WHITE, BORDER-RIGHT-COLOR=WHITE, BACKCOLOR=( WHITE RGB(238 238 238) ),
$
-* spalten-inhaltsspezifische Formatierung
  TYPE=DATA,
    COLUMN=COUNTRY,
    BACKCOLOR=SILVER,
    BORDER-BOTTOM=LIGHT,
    BORDER-BOTTOM-COLOR=WHITE,
    FOCEXEC=car_country(prod_art=COUNTRY),
$
END

This message has been edited. Last edited by: MichaelBalle,


WebFOCUS 7.6, 7.7
Windows, All Output formats
December 06, 2010, 05:31 AM
Tony A
Slight reversal of thinking behind this -

TABLE FILE CAR
PRINT CAR
      MODEL
      COMPUTE CNTR/I3 = IF COUNTRY EQ LAST COUNTRY THEN CNTR + 1 ELSE 1; NOPRINT
   BY COUNTRY
-*
  ON TABLE SET PAGE-NUM OFF
  ON TABLE NOTOTAL
  ON TABLE SET HTMLCSS ON
  ON TABLE PCHOLD FORMAT HTML
  ON TABLE SET STYLE *
-*
  UNITS=IN, SQUEEZE=ON, SIZE = 8, FONT= ARIAL, ORIENTATION=LANDSCAPE,PAGESIZE=A4, $
  TYPE=REPORT, SIZE=8, FONT = ARIAL, $
  TYPE=TITLE, SIZE=8, FONT = ARIAL, JUSTIFY = CENTER,
       BORDER-TOP=LIGHT, BORDER-BOTTOM=LIGHT, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,
       BORDER-TOP-COLOR=WHITE, BORDER-BOTTOM-COLOR=WHITE, BORDER-LEFT-COLOR=WHITE, BORDER-RIGHT-COLOR=WHITE,
       COLOR=WHITE, BACKCOLOR=RGB(240 78 45), $
  TYPE=DATA, SIZE=8,  FONT= ARIAL,
       BORDER-TOP=OFF, BORDER-BOTTOM=OFF, BORDER-LEFT=LIGHT, BORDER-RIGHT=LIGHT,
       BORDER-LEFT-COLOR=WHITE, BORDER-RIGHT-COLOR=WHITE, BACKCOLOR=(WHITE RGB(238 238 238)), $
-* spalten-inhaltsspezifische Formatierung
  TYPE=DATA,
    COLUMN=COUNTRY,
    BACKCOLOR=SILVER,
$
  TYPE=DATA,
    COLUMN=COUNTRY,
    BACKCOLOR=SILVER,
    BORDER-TOP=LIGHT,
    BORDER-TOP-COLOR=WHITE,
    FOCEXEC=car_country(param1=COUNTRY), WHEN=CNTR EQ 1, 
$
END

T



In FOCUS
since 1986
WebFOCUS Server 8.2.01M, thru 8.2.07 on Windows Svr 2008 R2  
WebFOCUS App Studio 8.2.06 standalone on Windows 10