In a report request like the following...

SET HOLDLIST=PRINTONLY, ASNAMES=MIXED
TABLE FILE IBIMAGN/CENTURYREVIEWS
PRINT EMAILDATE AS DATE
EMAILSUBJECT/A50 AS SUBJECT
EMAILSENTIMENTIMPRESSION/A50 AS IMPRESSION
EMAILFROMNAME/A25 AS NAME
ON TABLE HOLD
END
TABLE FILE HOLD
  SUM 
        MAX.DATE AS DATE:
  OVER  MAX.SUBJECT AS SUBJECT:
  BY NAME AS FROM
  ACROSS IMPRESSION    AS IMPRESSION
IF NAME CONTAINS 'A' OR 'B' OR 'C'
IF IMPRESSION CONTAINS 'Positive'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
 GRID=ON, PAGESIZE=LEDGER,ORIENTATION=PORTRAIT, FONT=ARIAL,SIZE=8,$
ENDSTYLE
END

...I want to limit the width of the report columns in which the verb objects (here, MAX.DATE and MAX.SUBJECT) are stacked, and wrap the stacked values (so that the DATE will appear as

yyyy-mm-dd
hh:mm:ss.mmm

)

Is there STYLE syntax that will accomplish that?

I tried styling it in the GUI, to no avail. It didn't choke on the ACROSS and OVER combination, but the preview ignored the "OVER" entirely.

This message has been edited. Last edited by: j.gross,

Hi,
By changing GRID to BORDER, I was able to control the WRAP for each column. But with title enabled for DATE: and SUBJECT: wrap is not working as expected. So added these as text along with date for more control on WRAP. Try below code.

SET HOLDLIST=PRINTONLY, ASNAMES=MIXED
 
TABLE FILE IBIMAGN/CENTURYREVIEWS
PRINT EMAILDATE AS DATE
EMAILSUBJECT/A50 AS SUBJECT
EMAILSENTIMENTIMPRESSION/A50 AS IMPRESSION
EMAILFROMNAME/A25 AS NAME
ON TABLE HOLD
END
-RUN
DEFINE FILE HOLD
DATE_A/A20 = HCNVRT(DATE, '(HYYMDS)', 20, 'A20');
DATE_N/A40 = '<B>DATE:</B> ' | DATE_A;
SUBJECT_N/A1020='<B>SUBJECT:</B>' | SUBJECT;
END 
TABLE FILE HOLD
SUM 
MAX.DATE_N AS ''
OVER  MAX.SUBJECT_N AS ''
BY NAME AS FROM
ACROSS IMPRESSION    AS IMPRESSION
IF NAME CONTAINS 'A' OR 'B' OR 'C'
IF IMPRESSION CONTAINS 'Positive'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
BORDER=ON, PAGESIZE=LEDGER,ORIENTATION=PORTRAIT, FONT=ARIAL,SIZE=8, MARKUP=ON, $
TYPE=REPORT, COLUMN=N1, WRAP=1.00, $
TYPE=REPORT, COLUMN=N2, WRAP=1.25, $
TYPE=REPORT, COLUMN=N3, WRAP=2.50, $
TYPE=REPORT, COLUMN=N4, WRAP=1.25, $
TYPE=REPORT, COLUMN=N5, WRAP=2.50, $
ENDSTYLE
END

Hope this helps.

Thanks,
Ram

Thanks, Ram.

But I'd prefer the original layout, if IBI will correct three obvious bugs in the PDF rendition of the report.

1. In the first (left-most) across-value column, the word-wrap places the continuation line's text off to the left of the data cell.

2. The boxes enclosing the across title, and first across value, are incorrectly placed (starting over the title cells in the data rows, rather than over the first across value's column.

3. The page-break splits a logical detail row, placing the first verb object (Date) on page 1 and the second (Subject) on page 2, rather than deferring the entire detail row to page 2. This happens even if you specify NOSPLIT.

This message has been edited. Last edited by: j.gross,

Here's a repro to illustrate the three issues.

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

TABLE FILE IBIMAGN/CENTURYREVIEWS
SUM 
FST.EMAILDATE AS DATE
FST.EMAILSUBJECT/A50 AS SUBJECT
FST.EMAILSENTIMENTIMPRESSION/A50 AS IMPRESSION
FST.EMAILFROMNAME/A25 AS NAME
BY EMAILSENTIMENTIMPRESSION NOPRINT
BY EMAILFROMNAME NOPRINT
ON TABLE SET HOLDLIST PRINTONLY AND ASNAMES MIXED
ON TABLE HOLD
END
 
TABLE FILE HOLD
SUM  DATE AS 'Date:'
OVER SUBJECT AS 'Subject:'
BY NAME AS 'From' NOSPLIT
ACROSS IMPRESSION    AS 'Impression'
IF NAME CONTAINS 'A' OR 'B' OR 'C'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
BORDER=ON, PAGESIZE=LETTER, ORIENTATION=LANDSCAPE,FONT='COURIER NEW', SIZE=8, SQUEEZE=ON, $
TYPE=TITLE,BACKCOLOR=YELLOW,$
TYPE=ACROSSTITLE,BACKCOLOR=YELLOW,$
TYPE=ACROSSVALUE,BACKCOLOR=AQUA,$
ACROSSCOLUMN=P1, WRAP=1.05, $
ACROSSCOLUMN=P2, WRAP=1.05, $
ENDSTYLE
END

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


I'm curious whether the problem already existed in earlier, or was introduced with the recent rewrite of PDF rendition.

I don't have CENTURYREVIEWS. Do you have sample using CAR or GGSALES?
Did you try setting the default WRAP for the report? I couldn't go smaller than 0.25 with out blowing up the reporting server.
Then you can increase the WRAP as needed on the reporting components you access through the style sheet.

  
TABLE FILE GGSALES
SUM
    FST.DATE
	FST.UNITS
	FST.PRODUCT
	FST.REGION
BY REGION NOPRINT
BY PRODUCT NOPRINT
ON TABLE SET HOLDLIST PRINTONLY AND ASNAMES MIXED
ON TABLE HOLD
END
-RUN
 
TABLE FILE HOLD
SUM  DATE AS 'Date:'
OVER UNITS AS 'Units:'
BY PRODUCT AS 'Product' NOSPLIT
ACROSS REGION AS 'Region'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
BORDER=ON, PAGESIZE=LETTER, ORIENTATION=LANDSCAPE,FONT='COURIER NEW', SIZE=8, SQUEEZE=ON, $
TYPE=REPORT,WRAP=0.25,$
TYPE=REPORT,ACROSSCOLUMN=P1,BACKCOLOR=SILVER,WRAP=0.25,$
TYPE=REPORT,ACROSSCOLUMN=P2,BACKCOLOR=PINK,WRAP=0.25,$
TYPE=REPORT,COLUMN=P1,BACKCOLOR=RED,WRAP=0.75,$
TYPE=TITLE,BACKCOLOR=GREEN,$
TYPE=ACROSSTITLE,BACKCOLOR=YELLOW,$
TYPE=ACROSSVALUE,BACKCOLOR=AQUA,$
ENDSTYLE
END
-RUN