Hello all,

I have a delima that I have search the Focal Point site for an answer to (I have also searched TSD site as well) and have not found an answer to my question. I have a case opened, but I thought I'd ask the group also.

The delima is that need to have the Right side of my heading title(this is the right side) to align with a column title of my report (curr_sal). Now, i can acomplish absolute positioning of this item by using the "POSITION" attribute, however when the name of "last_name" is very large/of very short then this position off. I am modifying a report that creates HTML output, however the fex has no actual tags coded inside of it. Straight WF. If I say item2=justify right then item2 moves a little but only a few pixels. When I turn grid on the whole report appears within 1 grid (this is now shown in the example fex below and this sentence is informational only).
Any assistance with this would be greatly appreciated

  TABLE FILE EMPLOYEE
PRINT 
     EMP_ID
     LAST_NAME
     DEPARTMENT
     CURR_SAL
HEADING
"This is a test report"
" "
"This is the left side <+0>This is the right side"
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=HEADING,LINE=1,JUSTIFY=CENTER,$
TYPE=HEADING,LINE=3,item=1,POSITION=0,$
TYPE=HEADING,LINE=3,item=2,COLUMN=curr_sal,$

-*TYPE=HEADING,LINE=3,item=1,position=3,$
-*TYPE=HEADING,LINE=3,item=2,column=curr_sal,$
-*TYPE=HEADING,LINE=3,ITEM=2,COLUMN=N4,$
ENDSTYLE
END

This message has been edited. Last edited by: Kerry,

HEADALIGN=BODY is the key to this:

TABLE FILE EMPLOYEE
PRINT 
     EMP_ID
     LAST_NAME
     DEPARTMENT
     CURR_SAL
HEADING
"THIS IS A TEST REPORT"
" "
"THIS IS THE LEFT SIDE<+0>THIS IS THE RIGHT SIDE"
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$

TYPE=HEADING, HEADALIGN=BODY,  $

TYPE=HEADING,LINE=1,COLSPAN=4, JUSTIFY=CENTER, $

TYPE=HEADING,LINE=3,ITEM=1, COLSPAN=2, COLOR=BLUE, $

TYPE=HEADING, LINE=3,ITEM=2, COLSPAN=2, JUSTIFY=RIGHT, COLOR=RED, $
ENDSTYLE
END

Try this

-*new file
 TABLE FILE EMPLOYEE
PRINT 
     EMP_ID
     LAST_NAME
     DEPARTMENT
     CURR_SAL
HEADING
"This is a test report"
" "
"This is the left side <+0>This is the right side"
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=HEADING, HEADALIGN=BODY, $
TYPE=HEADING,LINE=1,JUSTIFY=CENTER,COLSPAN=4, $
TYPE=HEADING,LINE=3,item=1,COLSPAN=3,$
TYPE=HEADING,LINE=3,item=2,$

-*TYPE=HEADING,LINE=3,item=1,position=3,$
-*TYPE=HEADING,LINE=3,item=2,column=curr_sal,$
-*TYPE=HEADING,LINE=3,ITEM=2,COLUMN=N4,$
ENDSTYLE
END

Do a search for headalign and find out what it does.

Oops, Francis, well done, that is what happens when you have a talk with you manager while posting.

Thanks Allot Francis...

Thanks Allot Waz....

Waz, great minds...

Francis, you mind is styled better