Is there some reason that you can’t format Subhead sections? This is what I have but it has absolutely no impact on the report. Neither the bold or color display. I am on version 7.6.5. Thanks.

These are the subhead sections

ON contractID SUBHEAD
"&&contractCarriers "
"<2>"&&companiesIncluded "
"<2>"
ON contractTermID SUBHEAD
"&&termName :<5>"&&issueDates :<8>&&through<20>&&travelBeginDate :<45>&&through<57>
This is the styling I would like

TYPE=SUBHEAD, BORDER-RIGHT=OFF, BORDER-LEFT=OFF, BORDER-TOP=OFF, BORDER-BOTTOM=OFF,$

TYPE=SUBHEAD, BY=contractID, LINE=1, STYLE=BOLD, BACKCOLOR=(RGB(234 234 255) ),$
TYPE=SUBHEAD, BY=contractID, LINE=3, STYLE=BOLD, BACKCOLOR=(RGB(234 234 255) ),$
TYPE=SUBHEAD, BY=contractID, LINE=5, STYLE=BOLD, BACKCOLOR=(RGB(234 234 255) ),$

TYPE=SUBHEAD, BY=contractTermID, LINE=1, STYLE=BOLD, $
TYPE=SUBHEAD, BY=contractTermID, LINE=2, BACKCOLOR=(RGB(234 234 255) ), $

Laurie,

Color and STYLE work OK providing you hit the correct components of the SUBHEAD. Backcolor seems to be applied to the entire line -

TABLE FILE CAR
SUM RCOST AS ''
    DCOST AS ''
 BY COUNTRY NOPRINT
 BY CAR   AS ''
 BY MODEL AS ''
ON COUNTRY SUBHEAD
"Totals for <COUNTRY"
"<+0> Retail Cost <15> <TOT.RCOST <30> Dealer Cost <45> <TOT.DCOST"
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
 TYPE=REPORT, SIZE=8, $
 TYPE=SUBHEAD, LINE=1, BACKCOLOR=RGB(128 128 255), $
 TYPE=SUBHEAD, LINE=2, ITEM=1, COLOR=RGB(128 128 255), BACKCOLOR=SILVER, STYLE=BOLD, $
 TYPE=SUBHEAD, LINE=2, ITEM=3, COLOR=RGB(000 000 255), $
 TYPE=SUBHEAD, LINE=2, ITEM=5, COLOR=RGB(000 255 000), STYLE=BOLD, $
 TYPE=SUBHEAD, LINE=2, ITEM=7, COLOR=RGB(255 000 000), $
 TYPE=SUBTOTAL, BACKCOLOR=RGB(189 190 194), BORDER=LIGHT, BORDER-COLOR=RGB(66 66 66), $
ENDSTYLE
END

Have you checked out MickeyG's excellent articles in the old FOCUS on Developer section (now just called Tips and Techniques)? - here.

T

Laurie,
Haven't tried this in 764 yet, but in 714 it works fine.
Here's my code I tested it with (place code between the [ and ] code brackets):

TABLE FILE CAR
PRINT DCOST RCOST
BY COUNTRY
BY CAR
BY MODEL
BY BODYTYPE
ON COUNTRY SUBHEAD
"contractCarriers "
"<2>carrierList "
"companiesIncluded "
"<2>companyList "
"gdsText "
ON MODEL SUBHEAD
"termName :<5>contractTermName "
"issueDates :<8>termBeginDate <15>through<20>termEndDate<35>travelBeginDate :<45>travelBeginDate<52>through<57>travelEndDate "
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=SUBHEAD, BORDER-RIGHT=OFF, BORDER-LEFT=OFF, BORDER-TOP=OFF, BORDER-BOTTOM=OFF,$
TYPE=SUBHEAD, BY=COUNTRY, LINE=1, STYLE=BOLD, BACKCOLOR=(RGB(234 234 255) ),$
TYPE=SUBHEAD, BY=COUNTRY, LINE=3, STYLE=BOLD, BACKCOLOR=(RGB(234 234 255) ),$
TYPE=SUBHEAD, BY=COUNTRY, LINE=5, STYLE=BOLD, BACKCOLOR=(RGB(234 234 255) ),$
TYPE=SUBHEAD, BY=MODEL, LINE=1, STYLE=BOLD, $
TYPE=SUBHEAD, BY=MODEL, LINE=2, BACKCOLOR=(RGB(234 234 255) ), $
ENDSTYLE
END

I don't have the &'s nor the fields you have, but just text should not make any difference.
This gives me the output I'd expect.

GamP,

I think the point is the same as the one you've just raised with IB, you can't have more than one background colour on a SUBHEAD or SUBFOOT?

T

This is exactly the same code I am using and it doesn't work. Maybe version 7.6.4 has a bug?

I have run the following in 7.6.4, and it works fine.

TABLE FILE CAR
PRINT DCOST RCOST
BY COUNTRY
BY CAR
BY MODEL
BY BODYTYPE
ON COUNTRY SUBHEAD
"contractCarriers "
"</2>carrierList "
"</2>companiesIncluded "
"</3>companyList "
"gdsText "
ON MODEL SUBHEAD
"termName :<+5>contractTermName "
"</2>issueDates :<+8>termBeginDate <+15>through<+20>termEndDate"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=SUBHEAD, BORDER-RIGHT=OFF, BORDER-LEFT=OFF, BORDER-TOP=OFF, BORDER-BOTTOM=OFF,$
TYPE=SUBHEAD, BY=COUNTRY, LINE=1, STYLE=BOLD, BACKCOLOR=RED,$
TYPE=SUBHEAD, BY=COUNTRY, LINE=4, STYLE=BOLD, BACKCOLOR=ORANGE,$
TYPE=SUBHEAD, BY=COUNTRY, LINE=7, STYLE=BOLD, BACKCOLOR=YELLOW,$
TYPE=SUBHEAD, BY=MODEL, LINE=1, STYLE=BOLD, $
TYPE=SUBHEAD, BY=MODEL, LINE=4, BACKCOLOR=BLUE, $
ENDSTYLE
END

Can you please try using &variables?

Sure,

I played around a bit with &vars, trying to get it to break, but no change, still working for me.

Please take care of your syntax, your initial code had some errors which I assumed to be the move to the forum, but maybe not.

I copied and pasted your code in and still no effect in the report. Thanks anyway.

Just an fyi, I got it to work by using the TYPE = SUBHEAD, BY = 1 or BY = 2.

For whatever reason, it would not recognize the field names in the style sheet.