-*-* Force to have a displayed 0 in front of the decimal value
SET CENT-ZERO = ON

DEFINE FILE CAR
TSALES /I6 MISSING ON = IF COUNTRY EQ 'FRANCE' THEN MISSING ELSE SALES;
NSALES /D12.2MCB MISSING ON = IF TSALES EQ MISSING THEN 0 ELSE IF COUNTRY EQ 'ENGLAND' THEN TSALES * -1 ELSE TSALES;
-*-* Below line is the real NSALES that should be used assuming that original data SALES may already contains missing value or negative ones
-*NSALES /D12.2MCB MISSING ON = IF SALES EQ MISSING THEN 0 ELSE SALES;
END
TABLE FILE CAR
SUM SALES
    TSALES
    NSALES
BY COUNTRY
ON TABLE PCHOLD FORMAT XLSX
END
-RUN

</>

-*-* This step is only to create an empty row/col value for West and Feb
DEFINE FILE GGSALES
MM       /MONTH = DATE;
END
TABLE FILE GGSALES
SUM DOLLARS/I8 AS 'DOLLARS'
BY REGION
BY MM
WHERE (REGION EQ 'West' AND MM NE 2) OR REGION NE 'West';
ON TABLE HOLD AS EXTDATA
END
-RUN

-*-* This step is to create the default matrix data
TABLE FILE GGSALES
SUM COMPUTE DOLLARS/I8 = 0;
BY REGION
BY MM
ON TABLE HOLD AS DEFAULTDATA
END
-RUN

SET CENT-ZERO = ON
TABLE FILE EXTDATA
SUM DOLLARS/D12.2MCB
BY REGION AS ''
ACROSS MM AS ''
-*-* To perform a MORE, all fields must have the same format and name between each used files
MORE
FILE DEFAULTDATA
END
-RUN