How to get column titles in one line when both BY and ACROSS are used

Focal Point

This topic can be found at:
https://forums.informationbuilders.com/eve/forums/a/tpc/f/7971057331/m/1547035126

June 22, 2012, 04:07 AM

Satish Bandimata

How to get column titles in one line when both BY and ACROSS are used

HI

I want the column titles to be in one row instead of in the scenario like this:

TABLE FILE CAR
SUM
SALES
BY COUNTRY
ACROSS CAR AS ''
END
-EXIT

-Satish

June 22, 2012, 07:11 AM

Danny-SRL

Satish,

quote:
TABLE FILE CAR
SUM
SALES
BY COUNTRY
ACROSS CAR AS ''
END

Using this syntax you cannot.
However, nothing is impossible with FOCUS. Try this:

  
TABLE FILE CAR
BY CAR
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE HOLD AS ALLCARS FORMAT ALPHA
END
-RUN
-SET &NCARS=&LINES;
DEFINE FILE CAR
-REPEAT #CSALES FOR &I FROM 1 TO &NCARS;
-READFILE ALLCARS
'&CAR' / I6S = IF CAR EQ '&CAR' THEN SALES ELSE 0;
-#CSALES
END 
-RUN
-CLOSE ALLCARS
TABLE FILE CAR
SUM
-REPEAT #PSALES FOR &I FROM 1 TO &NCARS;
-READFILE ALLCARS
'&CAR'
-#PSALES
BY COUNTRY
END

June 28, 2012, 08:24 AM

Ram Prasad E

READFILE supported with WF77 is so handy. No need to worry about field order and field format.

Thanks Daniel for sharing.

-Ram

June 28, 2012, 09:13 AM

Doug

Danny,

quote:
However, nothing is impossible with FOCUS.

June 28, 2012, 12:04 PM

Dan Satchell

Here's a trick that might work for you:

TABLE FILE CAR
 SUM SALES 
 BY COUNTRY AS ''
 ACROSS CAR AS 'COUNTRY'
 ON TABLE SET ACROSSTITLE SIDE
END

June 28, 2012, 04:00 PM

Doug

Satish, Did Dan's trick do it for you? IF not THEN 'Please elaborate' ELSE 'Let us know' ;

June 29, 2012, 01:52 AM

Satish Bandimata

quote:
Originally posted by Doug:
Satish, Did Dan's trick do it for you? IF not THEN 'Please elaborate' ELSE 'Let us know' ;

Doug,
Sorry for late response
Dan's trick is not working for me. Also Readfile is not supported in WF 769. Can I achieve this with FILEDEF

June 29, 2012, 07:56 AM

Danny-SRL

Dan,

quote:
TABLE FILE CAR
SUM SALES
BY COUNTRY AS ''
ACROSS CAR AS 'COUNTRY'
ON TABLE SET ACROSSTITLE SIDE
END

Thanks for the tip.
As always: RTFM...

June 29, 2012, 11:17 AM

George Patton

WoW !! Dan's trick is most excellent. Kudos to the programmer who invented it too. Love it!

WebFOCUS 7.7.05 Windows, Linux, DB2, IBM Lotus Notes, Firebird, Lotus Symphony/OpenOffice. Outputs PDF, Excel 2007 (for OpenOffice integration), WP

June 29, 2012, 03:19 PM

Dan Satchell

Since neither -READFILE nor SET ACROSSTITLE are available until release 7.7, here's another trick that might work for you:

TABLE FILE CAR
 SUM SALES
 BY COUNTRY NOPRINT
 ACROSS CAR AS ''
 COMPUTE XCOUNTRY/A15 = COUNTRY ; AS 'COUNTRY'
 ON TABLE SET STYLE *
  TYPE=REPORT, COLUMN=XCOUNTRY, SEQUENCE=1, $
 ENDSTYLE
END