I want a nice blue underlined link when there is something to drill down on, and blank normal text where there is nothing to drill down on, Or, ideally, no hyperlink at all.

I get the nice blue underline when the condition SOME_RECORD_FAILS is true, but when NO_RECORD_FAILS is true I get a weird light blue. Anyone have any ideas?

Thanks!

-Jeff

 

TYPE=DATA,
     COLUMN=N4,
     COLOR='BLACK',
     MACRO=NO_RECORD_FAILS,
     DRILLMENUITEM='Download Records Needing Remediation',
          FOCEXEC=IBFS:/WFC/Repository/Public/Record_Data_Quality/Record-Failure-Detail-Report.fex( \
     CAL_YR_MTH=N1 \
     Vendor=N3 \
     DQ_RULE_DESC=N4 \
     DQ_PROCESS_DESC=N2 \
     ),
          TARGET='_blank',
$
TYPE=DATA,
     COLUMN=N4,
     COLOR='BLUE',
     STYLE=UNDERLINE,
     MACRO=SOME_RECORD_FAILS,
     DRILLMENUITEM='Download Records Needing Remediation',
          FOCEXEC=IBFS:/WFC/Repository/Public/Record_Data_Quality/Record-Failure-Detail-Report.fex( \
     CAL_YR_MTH=N1 \
     Vendor=N3 \
     DQ_RULE_DESC=N4 \
     DQ_PROCESS_DESC=N2 \
     ),
          TARGET='_blank',

 

This message has been edited. Last edited by: FP Mod Chuck,

So, I just took out the DRILLDOWN on the condition I didn't want it to, and it turned black AND removed the drilldown.

Maybe drilldown won't allow black font?

Anyways, I solved it, but leaving this for others.

Why do you add a DRILLMENUITEM, FOCEXEC and TARGET when you don't want a hyperlink/drilldown?

Jeff,

I would check your MACROs.

Try this example to show that it can be achieved if you have the correct checks etc.

TABLE FILE GGSALES
SUM COMPUTE C_DOLLARS/D12.2c = IF CITY CONTAINS 'a' THEN 0 ELSE DOLLARS; AS 'Amount'
BY REGION
BY ST
BY CITY
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
  TYPE=DATA, COLUMN=C_DOLLARS,
     COLOR='BLACK',
     WHEN=C_DOLLARS NE 0,
     DRILLMENUITEM='Download Records Needing Remediation',
          FOCEXEC=carinst.fex,
     TARGET='_blank',
$
ENDSTYLE
END
-RUN

T

Use the WHEN statement in your drilldown. Back when we first started using WebFOCUS (original reports were in FOCUS/HP-UX). We developed our own security for giving access to reports based on the security in the user application that maintains the database. We have reports that are summary in nature and everyone can see those but drilling down to detail requires that one have the proper security in the application. In the following, the user id is passed to WebFOCUS. That is then checked in staff table. For anyone without the proper permissions, their &&WORKERTYP is set to 'G' for Guest. They can run the report but have cannot drill to the supporting detail. For example:

 
 TABLE FILE MGMTDATA
   SUM PSRTKEY AS '&SRTHD' OVER
       INPCT   AS '% Within Policy' OVER
       DENOM   AS 'Completed' OVER
       NUMER   AS 'Within Policy' OVER
       DIFF    AS 'Not Within Policy' OVER
       ALOT    AS 'ALOT to Complete (Days)'
       COMPUTE DRILL3/I2=DENOM GT 0 AND '&&WORKERTYP' NE 'G'; NOPRINT
       COMPUTE DRILL4/I2=NUMER GT 0 AND '&&WORKERTYP' NE 'G'; NOPRINT
       COMPUTE DRILL5/I2=DIFF  GT 0 AND '&&WORKERTYP' NE 'G'; NOPRINT
       MAX.SRTKEY NOPRINT
ACROSS SRTLVL  NOPRINT
ACROSS PSRTKEY NOPRINT
FOOTING
"&FOOT1"
"Data Collected on &&RUNTIME"
    ON TABLE SET PAGE-NUM NOLEAD
    ON TABLE SET PRINT ONLINE
    ON TABLE NOTOTAL
    ON TABLE HOLD AS DATA1 FORMAT HTMTABLE
    ON TABLE SET STYLE *
 TYPE=REPORT, GRID=ON, FONT='CALIBRI', SIZE=10,$
 TYPE=TITLE, WRAP=OFF,$
 TYPE=TITLE,ACROSSCOLUMN=N1,BACKCOLOR=&TABCDFTBCR,$
 TYPE=TITLE,ACROSSCOLUMN=N2,COLOR=&TABCPCTFCR,BACKCOLOR=&TABCPCTBCR,$
 TYPE=TITLE,ACROSSCOLUMN=N3,BACKCOLOR=&TABCDFTBCR,$
 TYPE=TITLE,ACROSSCOLUMN=N4,BACKCOLOR=&TABCTOTBCR,$
 TYPE=TITLE,ACROSSCOLUMN=N5,BACKCOLOR=&TABCDFTBCR,$
 TYPE=TITLE,ACROSSCOLUMN=N6,BACKCOLOR=&TABCDFTBCR,$
 TYPE=DATA,JUSTIFY=CENTER,$
 TYPE=DATA,ACROSSCOLUMN=N1,BACKCOLOR=&TABDDFTBCR,$
 TYPE=DATA,ACROSSCOLUMN=N2,COLOR=&TABDPCTFCR,BACKCOLOR=&TABDPCTBCR,$
 TYPE=DATA,ACROSSCOLUMN=N3,BACKCOLOR=&TABDDFTBCR,$
 TYPE=DATA,ACROSSCOLUMN=N4,BACKCOLOR=&TABDTOTBCR,$
 TYPE=DATA,ACROSSCOLUMN=N5,BACKCOLOR=&TABDDFTBCR,$
 TYPE=DATA,ACROSSCOLUMN=N6,BACKCOLOR=&TABDDFTBCR,$
$
$  Run Detail Reports
$
 TYPE=DATA, ACROSSCOLUMN=N3, &DTLFEX ROWNUM='3' &MDTLPARM, TARGET=_BLANK, WHEN=DRILL3 GT 0,$
 TYPE=DATA, ACROSSCOLUMN=N4, &DTLFEX ROWNUM='4' &MDTLPARM, TARGET=_BLANK, WHEN=DRILL4 GT 0,$
 TYPE=DATA, ACROSSCOLUMN=N5, &DTLFEX ROWNUM='5' &MDTLPARM, TARGET=_BLANK, WHEN=DRILL5 GT 0,$
 ENDSTYLE
 END
-RUN

When DRILL3/DRILL4/DRILL5 are 0, the data appears but the drill links are not there.