This is probably answered somewhere but I cant manage to find it.

I want to use a fieldname in the column title for a column.
My Code looks like this:

  
TABLE FILE BLAHBLAH
PRINT
	REVISION AS 'Revision #' OVER
	REVISION_DETAILS AS 'Details'
BY REVISION_DATE NOPRINT

I have another field called REVISION_NUMBER that I would like to add to the REVISION column title so I would have 'Revision #REVISION_NUMBER'

Thanks

This message has been edited. Last edited by: Kerry,

The simple solution is to turn the titles off, and add the titles to the heading, then you can add data to them.

DEFINE FILE CAR
 CarHead/A20 = 'Car ' | COUNTRY ;
END
TABLE FILE CAR
HEADING
"Heading"
" "
"<CarHead<+0>Model"
PRINT
CAR AS ''
MODEL AS ''
BY COUNTRY NOPRINT PAGE-BREAK
ON TABLE SET STYLE *
TYPE=HEADING, HEADALIGN=BODY, $
END

Thanks Waz. Unfortunately, I forgot part of the code. The First Field has an OVER in it.

Oh dear,



Can you repro the basics of the report in one of the sample files ?

Maybe something like this?

DEFINE FILE CAR
ASEATS/A5 = FTOA(SEATS,'(F5)',ASEATS);
NAUGHT/A5=' ';
END

TABLE FILE CAR
PRINT ASEATS AS 'Revision' CAR     AS ''
 OVER NAUGHT AS 'Country'  COUNTRY AS ''
 OVER NAUGHT AS 'Model'    MODEL   AS ''

ON    TABLE SET PAGE NOLEAD
ON    TABLE NOTOTAL
ON    TABLE SET LINES 9999
ON    TABLE PCHOLD FORMAT HTML
ON    TABLE SET STYLE *
TYPE=REPORT,
     SIZE= 9,
     GRID=OFF,
     FONT='verdana',
     COLOR=RGB(0 47 47),
     SQUEEZE=ON,
$
TYPE=DATA,
     BACKCOLOR=( 'WHITE' RGB(239 236 202) ),
$
TYPE=TITLE,
     STYLE=BOLD,
     COLOR=RGB(239 236 202),
     BACKCOLOR=RGB(4 99 128),
$
TYPE=DATA, COLUMN=ASEATS,
     STYLE=BOLD,
     COLOR=RGB(239 236 202),
     BACKCOLOR=RGB(4 99 128),
$
TYPE=DATA, COLUMN=N3,
     STYLE=BOLD,
     COLOR=RGB(239 236 202),
     BACKCOLOR=RGB(4 99 128),
$
TYPE=DATA, COLUMN=N5,
     STYLE=BOLD,
     COLOR=RGB(239 236 202),
     BACKCOLOR=RGB(4 99 128),
$
TYPE=HEADING,
     SIZE=10,
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=SUBHEAD,
     BORDER-TOP=HEAVY,
     BORDER-BOTTOM=LIGHT,
     BORDER-TOP-COLOR=RGB(167 163 126),
     BORDER-BOTTOM-COLOR=RGB(167 163 126),
     SIZE=10,
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     BACKCOLOR=RGB(230 226 175),
     STYLE=BOLD,
$
TYPE=ACROSSTITLE,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=HEAVY,
     BORDER-TOP-COLOR=RGB(167 163 126),
     BORDER-BOTTOM-COLOR=RGB(167 163 126),
     SIZE=9,
     STYLE=-UNDERLINE+BOLD,
$
ENDSTYLE
END

It's the closest as I could get without going to too extreme measures.

Thanks GamP, This looks like it will do the trick for what I am trying to do.