Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only. Moving forward, myibi is our community platform to learn, share, and collaborate. We have the same Focal Point forum categories in myibi, so you can continue to have all new conversations there. If you need access to myibi, contact us at myibi@ibi.com and provide your corporate email address, company, and name.


Connect to myibi
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Smart usage of OVERFLOW-POSITION and OVERFLOW-DIMENSION

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] Smart usage of OVERFLOW-POSITION and OVERFLOW-DIMENSION
 Login/Join
 
Guru
posted
Hi,

Can anyone share a smart usage of
OVERFLOW-POSITION and OVERFLOW-DIMENSION from a COMPOUND PDF report?

I have a recursive report that creates a PDF compound. It creates reports A, B, C, D, E. I need to configure these variables to fit 2 reports per page.

Page 1 ( Reports A, B )
Page 2 ( Reports C, D )
Page 3 ( Reports E, F )

Is there a way to set them to be dynamic?


Any hint?

Thanks

This message has been edited. Last edited by: Ricardo Augusto,


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Report This Post
Guru
posted Hide Post
-* File: IBFS:/localhost/EDA/EDASERVE/APPPATH/ibisamp/exemplos/Procedure1.fex Created by WebFOCUS AppStudio



SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF AS TEST
UNITS=PTS, $
SECTION=section1, LAYOUT=ON, METADATA='5^5^5^5^4', MERGE=OFF, ORIENTATION=LANDSCAPE, PAGESIZE=LETTER, SHOW_GLOBALFILTER=OFF, $

PAGELAYOUT=ALL, $
COMPONENT=HEADER, TYPE=REPORT, POSITION=(7 7), DIMENSION=(* *), $
OBJECT=STRING, NAME='Page', TEXT='Page <ibi-page-number/> of <ibi-total-pages/>', POSITION=(+545 50), MARKUP=OFF,
        WRAP=ON, DIMENSION=(6.0 0.2) FONT='FORD CE BLACK', COLOR=RGB(128 128 128), STYLE=BOLD, SIZE=6, $

OBJECT=STRING, NAME='Prog', TEXT='Prog: TEST_COMPOUND_PDF', POSITION=(+535 800), MARKUP=OFF,
        WRAP=ON, DIMENSION=(6.0 0.2) FONT='FORD CE BLACK', COLOR=RGB(128 128 128), STYLE=BOLD, SIZE=6, $

PAGELAYOUT=1, NAME='TEST_COMPOUND_PDF', text='TEST_COMPOUND_PDF', TOC-LEVEL=1, TOPMARGIN=1, ORIENTATION=LANDSCAPE, $
-*OBJECT=IMAGE, NAME='image1', IMAGE=ford_logo.jpg, ALT='', POSITION=(7 7), DIMENSION=(88 32),  $
COMPONENT='RPT1', TEXT='RPT1', POSITION=(10 40), DIMENSION=(150 *), $
COMPONENT='RPT2', TEXT='RPT2', POSITION=(10 330), DIMENSION=(* *),OVERFLOW-POSITION=(10 40), OVERFLOW-DIMENSION=(* *), $
COMPONENT='RPT3', TEXT='RPT3', POSITION=(1 480), DIMENSION=(* *), OVERFLOW-POSITION=(10 40), OVERFLOW-DIMENSION=(* *), $
COMPONENT='RPT4', TEXT='RPT4', POSITION=(1 880), DIMENSION=(* *),OVERFLOW-POSITION=(10 40), OVERFLOW-DIMENSION=(* *), $



-RUN


SET COMPONENT=HEADER
TABLE FILE CAR
HEADING
"TEST COMPOUND REPORT"
"Period: &YYMD"
"Company XPZ"
"&DATEDwMtrYY &TOD"
BY COUNTRY NOPRINT
IF READLIMIT EQ 1
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET STYLE *
TYPE=REPORT, IMAGE=ford_logo.jpg, SIZE=(1.000000 0.300000),  $
TYPE=HEADING, FONT="FORD CE BLACK", $
TYPE=HEADING, POSITION=1.05, $
TYPE=HEADING, LINE=1, SIZE=12, STYLE='BOLD', POSITION=1.05, $
TYPE=HEADING, LINE=2, SIZE=8,  STYLE='BOLD', JUSTIFY=RIGHT, $
TYPE=HEADING, LINE=3, SIZE=8, JUSTIFY=LEFT, $
TYPE=HEADING, LINE=4, SIZE=6, JUSTIFY=RIGHT, $

END

-RUN

SET COMPONENT = RPT1

TABLE FILE CAR
SUM SALES
BY MODEL
ACROSS COUNTRY
HEADING 
"REPORT 1"
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,  ORIENTATION=PORTRAIT, SQUEEZE=ON, $
     INCLUDE = endeflt,
$

TYPE=REPORT, GRID=OFF, SIZE=6, $
TYPE=TITLE, SIZE= 7, $
TYPE=DATA, SIZE=6,BACKCOLOR=( 'WHITE' RGB(235 235 240) ), $
TYPE=ACROSSVALUE, SIZE=7,  $

TYPE=HEADING,
     LINE=1,
	 SIZE=7,
     JUSTIFY=LEFT,
$

ENDSTYLE
END



-* REPORT 2

SET COMPONENT = RPT2

TABLE FILE CAR
SUM SALES

BY COUNTRY
HEADING 
"REPORT 2"
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,  ORIENTATION=PORTRAIT, SQUEEZE=ON, $
     INCLUDE = endeflt,
$

TYPE=REPORT, GRID=OFF, SIZE=6, $
TYPE=TITLE, SIZE= 7, $
TYPE=DATA, SIZE=6,BACKCOLOR=( 'WHITE' RGB(235 235 240) ), $
TYPE=ACROSSVALUE, SIZE=7,  $

TYPE=HEADING,
     LINE=1,
	 SIZE=7,
     JUSTIFY=LEFT,
$

ENDSTYLE
END

-RUN




SET COMPONENT = RPT3

TABLE FILE CAR
SUM SALES

BY MODEL
HEADING 
"REPORT 3"
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,  ORIENTATION=PORTRAIT, SQUEEZE=ON, $
     INCLUDE = endeflt,
$

TYPE=REPORT, GRID=OFF, SIZE=6, $
TYPE=TITLE, SIZE= 7, $
TYPE=DATA, SIZE=6,BACKCOLOR=( 'WHITE' RGB(235 235 240) ), $
TYPE=ACROSSVALUE, SIZE=7,  $

TYPE=HEADING,
     LINE=1,
	 SIZE=7,
     JUSTIFY=LEFT,
$

ENDSTYLE
END

-RUN


SET COMPONENT = RPT4

TABLE FILE CAR
SUM SALES

BY BODYTYPE
HEADING 
"REPORT 4"
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,  ORIENTATION=PORTRAIT, SQUEEZE=ON, $
     INCLUDE = endeflt,
$

TYPE=REPORT, GRID=OFF, SIZE=6, $
TYPE=TITLE, SIZE= 7, $
TYPE=DATA, SIZE=6,BACKCOLOR=( 'WHITE' RGB(235 235 240) ), $
TYPE=ACROSSVALUE, SIZE=7,  $

TYPE=HEADING,
     LINE=1,
	 SIZE=7,
     JUSTIFY=LEFT,
$

ENDSTYLE
END






  


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Report This Post
Guru
posted Hide Post
Ricardo,

OVERFLOW-POSITION and OVERFLOW-DIMENSION only come into play when the report component doesn't fit on the page that it set for. These values then control where on the overflow page to put the rest of the report.

If I am reading your question correctly you want to resize the reports on each page. Assuming that Report A and Report B (and C & D, E & F) together will always fit on a single page then you can do something like this:

SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF AS TEST
UNITS=PTS, $
SECTION=section1, LAYOUT=ON, METADATA='5^5^5^5^4', MERGE=OFF, ORIENTATION=LANDSCAPE, PAGESIZE=LETTER, SHOW_GLOBALFILTER=OFF, $

PAGELAYOUT=ALL, $
COMPONENT=HEADER, TYPE=REPORT, POSITION=(7 7), DIMENSION=(* *), $
OBJECT=STRING, NAME='Page', TEXT='Page <ibi-page-number/> of <ibi-total-pages/>', POSITION=(+545 50), MARKUP=OFF,
        WRAP=ON, DIMENSION=(6.0 0.2) FONT='FORD CE BLACK', COLOR=RGB(128 128 128), STYLE=BOLD, SIZE=6, $

OBJECT=STRING, NAME='Prog', TEXT='Prog: TEST_COMPOUND_PDF', POSITION=(+535 800), MARKUP=OFF,
        WRAP=ON, DIMENSION=(6.0 0.2) FONT='FORD CE BLACK', COLOR=RGB(128 128 128), STYLE=BOLD, SIZE=6, $

PAGELAYOUT=1, NAME='TEST_COMPOUND_PDF', text='TEST_COMPOUND_PDF', TOC-LEVEL=1, TOPMARGIN=1, ORIENTATION=LANDSCAPE, $
-*OBJECT=IMAGE, NAME='image1', IMAGE=ford_logo.jpg, ALT='', POSITION=(7 7), DIMENSION=(88 32),  $
COMPONENT='RPT1', TEXT='RPT1', POSITION=(10 40), DIMENSION=(150 *), $
COMPONENT='RPT2', TEXT='RPT2', POSITION=(+0.00 +0.00), DIMENSION=(* *),RELATIVE-TO='RPT1', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT, $
PAGELAYOUT=2, NAME='TEST_COMPOUND_PDF', text='TEST_COMPOUND_PDF', TOC-LEVEL=1, TOPMARGIN=1, ORIENTATION=LANDSCAPE, $
COMPONENT='RPT3', TEXT='RPT3', POSITION=(10 40), DIMENSION=(* *), $
COMPONENT='RPT4', TEXT='RPT4', POSITION=(+0.00 +0.00), DIMENSION=(* *),RELATIVE-TO='RPT3', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $


Hope that helps

Stu


WebFOCUS 8.2.03 (8.2.06 in testing)
 
Posts: 253 | Location: Melbourne, Australia | Registered: February 07, 2007Report This Post
Guru
posted Hide Post
Good Morning.

Thanks a lot Stu. It works like a charm!


My final code:

 
SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF AS ADVR_0023
UNITS=PTS, $
SECTION=section1, LAYOUT=ON, METADATA='5^5^5^5^4', MERGE=OFF, ORIENTATION=LANDSCAPE, PAGESIZE=A3, SHOW_GLOBALFILTER=OFF, $

PAGELAYOUT=ALL, $
COMPONENT=HEADER, TYPE=REPORT, POSITION=(7 7), DIMENSION=(* *), $
OBJECT=STRING, NAME='Page', TEXT='Page <ibi-page-number/> of <ibi-total-pages/>', POSITION=(+545 50), MARKUP=OFF,
        WRAP=ON, DIMENSION=(6.0 0.2) FONT='FORD CE BLACK', COLOR=RGB(128 128 128), STYLE=BOLD, SIZE=6, $

OBJECT=STRING, NAME='Prog', TEXT='Prog: advr0023', POSITION=(+535 800), MARKUP=OFF,
        WRAP=ON, DIMENSION=(6.0 0.2) FONT='FORD CE BLACK', COLOR=RGB(128 128 128), STYLE=BOLD, SIZE=6, $

PAGELAYOUT=1, NAME='ADVR_0023', text='ADVR_0023', TOC-LEVEL=1, TOPMARGIN=1, ORIENTATION=LANDSCAPE, $
-*OBJECT=IMAGE, NAME='image1', IMAGE=ford_logo.jpg, ALT='', POSITION=(7 7), DIMENSION=(88 32),  $
COMPONENT='CARS', TEXT='CARS', POSITION=(1 50), DIMENSION=(150 *), $
COMPONENT='LIGHTS', TEXT='LIGHTS', POSITION=(+1.00 +35.00), DIMENSION=(* *),RELATIVE-TO='CARS', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $
COMPONENT='BUS', TEXT='BUS', POSITION=(+1.00 +35.00), DIMENSION=(* *),RELATIVE-TO='LIGHTS', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $

PAGELAYOUT=2, NAME='ADVR_0023', text='ADVR_0023', TOC-LEVEL=1, TOPMARGIN=1, ORIENTATION=LANDSCAPE, $

COMPONENT='TRUCKS', TEXT='TRUCKS', POSITION=(1 50), DIMENSION=(* *), $
COMPONENT='MEZCLA', TEXT='MEZCLA', POSITION=(+1.00 +25.00), DIMENSION=(* *), RELATIVE-TO='TRUCKS', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $
COMPONENT='FORD CARS', TEXT='FORD CARS', POSITION=(+1.00 +25.00), DIMENSION=(* *), RELATIVE-TO='MEZCLA', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $
COMPONENT='FORD LIGHTS', TEXT='FORD LIGHTS', POSITION=(+1.00 +25.00), DIMENSION=(* *), RELATIVE-TO='FORD CARS', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $
COMPONENT='FORD TRUCKS', TEXT='FORD TRUCKS',POSITION=(+1.00 +25.00), DIMENSION=(* *), RELATIVE-TO='FORD LIGHTS', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,  $

PAGELAYOUT=3, NAME='ADVR_0023', text='ADVR_0023', TOC-LEVEL=1, TOPMARGIN=1, ORIENTATION=LANDSCAPE, $
COMPONENT='FORD MEZCLA', TEXT='FORD MEZCLA', POSITION=(1 50), DIMENSION=(* *), $

 


WebFOCUS 8.1.05 / APP Studio
 
Posts: 272 | Location: Brazil | Registered: October 31, 2006Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Smart usage of OVERFLOW-POSITION and OVERFLOW-DIMENSION

Copyright © 1996-2020 Information Builders