Hello

I am working on a report and got HTML version to work. I need equivalent in PDF format and having trouble with it. Any help is appreciated.

TABLE FILE CAR
SUM
	COMPUTE IMG/A200  = '<img src = "/ibi_apps/WFServlet.ibfs?IBFS1_action=RUNFEX&|IBFS_path=/WFC/Repository/images/img.png " border=0 style="width:10px;height:10px;"/>'; NOPRINT
	COMPUTE FLD1/A10  =	'10.25%'; AS 'COLUMN1'
	COMPUTE SPACE/A1 = '';	AS ''
	COMPUTE FLD2/A100 = '10.25%' || '<BR><span style="color:black; font-size:11">BETTER</SPAN>'; AS 'COLUMN2'
	COMPUTE SPACE/A1 = '';	AS ''
	COMPUTE FLD3/A225 = IMG | ' ' | '-1.25%'; AS 'COLUMN3'
	COMPUTE SPACE/A1 = '';	AS ''
	COMPUTE FLD4/A600 = '10.25%' || '<br><span style="color:black; font-size:11">GOOD</span>'; AS 'COLUMN4'
BY COUNTRY AS ''
HEADING
"<+0> <+0>CURRENT YEAR<+0> <+0>PRIOR YEAR"
ON TABLE HOLD AS H001 FORMAT HTMTABLE
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET HTMLCSS ON
ON COUNTRY SKIP-LINE
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, SIZE=10, STYLE=NORMAL, PAGESIZE=LETTER, ORIENTATION=LANDSCAPE, SQUEEZE=ON, $
TYPE=HEADING, SIZE=12, STYLE=BOLD, COLOR=BLACK, HEADALIGN=BODY, JUSTIFY=CENTER, BACKCOLOR=RGB(0 255 255), $
TYPE=HEADING, ITEM=1, COLSPAN=1, $
TYPE=HEADING, ITEM=2, COLSPAN=3, $
TYPE=HEADING, ITEM=3, COLSPAN=1, $
TYPE=HEADING, ITEM=4, COLSPAN=3, $
TYPE=REPORT, COLUMN=N1, WRAP=1.00, BORDER=OFF, $
TYPE=REPORT, COLUMN=N3, WRAP=1.50, BORDER=OFF, $
TYPE=REPORT, COLUMN=N4, WRAP=0.10, BORDER=OFF, $
TYPE=REPORT, COLUMN=N6, WRAP=0.10, BORDER=OFF, $
TYPE=REPORT, COLUMN=N8, WRAP=0.10, BORDER=OFF, $
TYPE=DATA, BACKCOLOR=RGB(200 200 200), COLOR=BLACK, TOPGAP=0.05, BOTTOMGAP=0.05, JUSTIFY=CENTER, $
ENDSTYLE
END
-RUN
-HTMLFORM BEGIN
!IBI.FIL.H001;
<style type="text/css">
TD { vertical-align:middle; }
</style>
-HTMLFORM END

Thank you.

This message has been edited. Last edited by: BI_Developer,

Though not equivalent, this is similar in PDF:

 TABLE FILE car
 SUM
 COMPUTE FLD1/A10  = '10.25%';                                  AS 'COLUMN1'
 COMPUTE SPACE/A1  = ' ';                                       AS ''
 COMPUTE FLD2/A100 = '10.25%' | CHAR(13) | CHAR(10) | 'BETTER'; AS 'COLUMN2'
 COMPUTE SPACE/A1  = ' ';	                                    AS ''
 COMPUTE IMG/A1    = ' ';                                       AS '' 
 COMPUTE FLD3/A225 = '-1.25%';                                  AS 'COLUMN3' 
 COMPUTE SPACE/A1  = ' ';	                                    AS ''
 COMPUTE FLD4/A600 = '10.25%' | CHAR(13) | CHAR(10) | 'GOOD';   AS 'COLUMN4'
      BY COUNTRY	                                            AS ''
 HEADING
 "<+0> <+0>CURRENT YEAR<+0> <+0>PRIOR YEAR"
 " "
 ON COUNTRY SKIP-LINE
 ON TABLE SET PAGE-NUM NOLEAD
 ON TABLE PCHOLD FORMAT PDF
 ON TABLE SET STYLE *
 TYPE=REPORT, LINEBREAK='CRLF', SIZE=10, SQUEEZE=ON, ORIENTATION=LANDSCAPE, $
 TYPE=REPORT, COLUMN=COUNTRY, WRAP=1.00, BORDER=OFF, $
 TYPE=REPORT, COLUMN=FLD1, WRAP=1.50, BORDER=OFF, $ 
 TYPE=HEADING, SIZE=12, STYLE=BOLD, COLOR=BLACK, HEADALIGN=BODY, JUSTIFY=CENTER, BACKCOLOR=RGB(0 255 255), $
 TYPE=HEADING, ITEM=1, COLSPAN=1, $
 TYPE=HEADING, ITEM=2, COLSPAN=3, $
 TYPE=HEADING, ITEM=3, COLSPAN=1, $
 TYPE=HEADING, ITEM=4, COLSPAN=3, $
 TYPE=DATA, BACKCOLOR=RGB(200 200 200), COLOR=BLACK, TOPGAP=0.05, BOTTOMGAP=0.05, JUSTIFY=CENTER, $ 
 TYPE=title, COLUMN=FLD2, JUSTIFY=center, $ 
 TYPE=title, COLUMN=FLD4, JUSTIFY=center, $ 
 TYPE=DATA, COLUMN=IMG, IMAGE=IBFS:/WFC/Repository/image/img.png, SIZE=(.1 .1), JUSTIFY=RIGHT, $
 ENDSTYLE
 END  

Thanks a lot. This is very helpful and I think I can take it from here.

quote:

Originally posted by dbeagan:
Though not equivalent, this is similar in PDF:

 TABLE FILE car
 SUM
 COMPUTE FLD1/A10  = '10.25%';                                  AS 'COLUMN1'
 COMPUTE SPACE/A1  = ' ';                                       AS ''
 COMPUTE FLD2/A100 = '10.25%' | CHAR(13) | CHAR(10) | 'BETTER'; AS 'COLUMN2'
 COMPUTE SPACE/A1  = ' ';	                                    AS ''
 COMPUTE IMG/A1    = ' ';                                       AS '' 
 COMPUTE FLD3/A225 = '-1.25%';                                  AS 'COLUMN3' 
 COMPUTE SPACE/A1  = ' ';	                                    AS ''
 COMPUTE FLD4/A600 = '10.25%' | CHAR(13) | CHAR(10) | 'GOOD';   AS 'COLUMN4'
      BY COUNTRY	                                            AS ''
 HEADING
 "<+0> <+0>CURRENT YEAR<+0> <+0>PRIOR YEAR"
 " "
 ON COUNTRY SKIP-LINE
 ON TABLE SET PAGE-NUM NOLEAD
 ON TABLE PCHOLD FORMAT PDF
 ON TABLE SET STYLE *
 TYPE=REPORT, LINEBREAK='CRLF', SIZE=10, SQUEEZE=ON, ORIENTATION=LANDSCAPE, $
 TYPE=REPORT, COLUMN=COUNTRY, WRAP=1.00, BORDER=OFF, $
 TYPE=REPORT, COLUMN=FLD1, WRAP=1.50, BORDER=OFF, $ 
 TYPE=HEADING, SIZE=12, STYLE=BOLD, COLOR=BLACK, HEADALIGN=BODY, JUSTIFY=CENTER, BACKCOLOR=RGB(0 255 255), $
 TYPE=HEADING, ITEM=1, COLSPAN=1, $
 TYPE=HEADING, ITEM=2, COLSPAN=3, $
 TYPE=HEADING, ITEM=3, COLSPAN=1, $
 TYPE=HEADING, ITEM=4, COLSPAN=3, $
 TYPE=DATA, BACKCOLOR=RGB(200 200 200), COLOR=BLACK, TOPGAP=0.05, BOTTOMGAP=0.05, JUSTIFY=CENTER, $ 
 TYPE=title, COLUMN=FLD2, JUSTIFY=center, $ 
 TYPE=title, COLUMN=FLD4, JUSTIFY=center, $ 
 TYPE=DATA, COLUMN=IMG, IMAGE=IBFS:/WFC/Repository/image/img.png, SIZE=(.1 .1), JUSTIFY=RIGHT, $
 ENDSTYLE
 END