Is there a way to leave a blank like or little spacing in between each record?
Thank youThis message has been edited. Last edited by: Kerry,
WF 8.2.01 APP STUDIO PDF,HTML,EXL2K,Active
January 30, 2012, 03:23 PM
<FreSte>
Maybe one of these ??
SET BYDISPLAY = ON
TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
BY CAR
ON CAR SUBFOOT
" "
ON TABLE SET TITLES OFF
ON TABLE SET PAGE NOPAGE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT ,UNITS=PTS ,FONT='VERDANA', SIZE=8 ,$
TYPE=REPORT ,BORDER=1 ,BORDER-COLOR=RGB(210 210 210) ,$
TYPE=TITLE ,STYLE=BOLD ,BACKCOLOR=RGB(230 230 230) ,$
ENDSTYLE
END
... or ...
SET BYDISPLAY=ON
TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
BY CAR
ON TABLE SET TITLES OFF
ON TABLE SET PAGE NOPAGE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT ,UNITS=PTS ,FONT='VERDANA', SIZE=8 ,$
TYPE=REPORT ,BORDER=1 ,BORDER-COLOR=RGB(210 210 210) ,$
TYPE=TITLE ,STYLE=BOLD ,BACKCOLOR=RGB(230 230 230) ,$
TYPE=DATA ,TOPGAP=6 ,BOTTOMGAP=6 ,$
ENDSTYLE
END
January 30, 2012, 03:46 PM
Waz
SKIP-LINE is also an option
Waz...
Prod:
WebFOCUS 7.6.10/8.1.04
Upgrade:
WebFOCUS 8.2.07
OS:
Linux
Outputs:
HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!
January 30, 2012, 03:49 PM
<FreSte>
Yep, I tried that too, but in HTML it doesn't skip a line.
January 30, 2012, 04:04 PM
Waz
Interesting,
Can't find anything in the doco indicating that.
Waz...
Prod:
WebFOCUS 7.6.10/8.1.04
Upgrade:
WebFOCUS 8.2.07
OS:
Linux
Outputs:
HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!
January 30, 2012, 04:16 PM
Glenda
It will work in HTML if GRID=OFF.
Glenda
In FOCUS Since 1990 Production 8.2 Windows
January 30, 2012, 04:47 PM
Waz
Ah yes, thanks Glenda,
SET BYDISPLAY = ON
TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
BY CAR
ON CAR SKIP-LINE
ON TABLE SET TITLES OFF
ON TABLE SET PAGE NOPAGE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
GRID=OFF, $
TYPE=REPORT ,UNITS=PTS ,FONT='VERDANA', SIZE=8 ,$
TYPE=REPORT ,BORDER=1 ,BORDER-COLOR=RGB(210 210 210) ,$
TYPE=TITLE ,STYLE=BOLD ,BACKCOLOR=RGB(230 230 230) ,$
ENDSTYLE
END
