Drilldown on Subtotal

I have a report that counts items received and displays the counts in columns by month. I have this set up to drill down to a report that provides a listing of the details for the items in that count. I have added a subtotal to the BY that sorts the information and have set up the drill down to work on that data, too. My question is this: Is there a way to prevent the *TOTAL label from acting as a drilldown hyperlink?

posted

Where would you like the hyperlink to be? Could you please post a snippet of your code?

posted

OK, but be kind. I'm still new!

The report output looks like a matrix with row and column headings and counts totals at each row/columnn intersection. These counts drill down to another report. The Subtotals for each column also drill down. I do NOT want the label for the Subtotal line to drill down, but it is trying to do so. I have quite a bit of dialogue manager stuff going on before this, but one branch is as follows:

TABLE FILE PARCWKUT
SUM
CNT.CLMT_SSN AS 'CNT,CLMT_SSN'
BY
OWNR_RONUM NOPRINT AS 'Reg'
BY
OWNR_OCD AS 'HO'
BY
SOCSEC_OCD AS 'SSO'
ACROSS
&ACROSSVAL AS ' '

ON OWNR_OCD SUBTOTAL
CLMT_SSN AS 'TOTAL'
ON OWNR_OCD UNDER-LINE
HEADING
"&PeriodLabel.EVAL Receipts by Hearing Office and Field Office"
"Region: "Within the range &StartDate to &EndDate"
""
FOOTING
"&DATEtMDYY <+0> "
-*Activate WHERE below for production.
-*WHERE ORIGG_OCD EQ OWNR_OCD
WHERE ( HRREC_Date GE
'&StartDate.Select Start Date - mm/dd/yyyy.'
)
AND ( HRREC_Date LE
'&EndDate.Select End Date - mm/dd/yyyy.'
);
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='SCREEN',
LEFTMARGIN=0.000000,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
TOPGAP=0.000000,
BOTTOMGAP=0.000000,
$
TYPE=DATA,
ACROSSCOLUMN=N1,
COLOR='BLUE',
STYLE=UNDERLINE,
FOCEXEC=RECEIPTS(HO=N2 FO=N3 PeriodVal=A1 ACROSSVAL2='&ACROSSVAL' RO=N1 OutputFmt2='&OutputFmt' StartDate='&StartDate' EndDate='&EndDate' PeriodLabel = '&PeriodLabel'),
$
TYPE=TITLE,
ACROSSCOLUMN=N1,
COLOR='BLUE',
STYLE=BOLD+UNDERLINE,
FOCEXEC=RECEIPTS(HO=N2 FO=N3 PeriodVal=A1 ACROSSVAL2='&ACROSSVAL' RO=N1 OutputFmt2='&OutputFmt' StartDate='&StartDate' EndDate='&EndDate' PeriodLabel = '&PeriodLabel'),
$
TYPE=HEADING,
STYLE=BOLD,
$
TYPE=FOOTING,
STYLE=BOLD,
$
TYPE=SUBHEAD,
STYLE=BOLD,
$
TYPE=SUBFOOT,
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BY=2,
FOCEXEC=RECEIPTS(HO=N2 FO='$$$' PeriodVal=A1 ACROSSVAL2='&ACROSSVAL' RO=N1 OutputFmt2='&OutputFmt' StartDate='&StartDate' EndDate='&EndDate' PeriodLabel = '&PeriodLabel'),
$
TYPE=ACROSSVALUE,
SIZE=9,
$
TYPE=ACROSSTITLE,
STYLE=BOLD,
$
ENDSTYLE
END
-RUN
-EXIT

posted

Hopefully this helps. I've set colours in the stylesheet to show how to address particular parts of the sub total.

TABLE FILE CAR
SUM DEALER_COST RETAIL_COST
BY COUNTRY
BY CAR
BY MODEL
ON CAR SUBTOTAL AS 'Total Car'
ON COUNTRY SUBTOTAL AS 'Total Country'

ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, FONT='VERDANA', SIZE=8, $
TYPE=SUBTOTAL, BY=1, COLUMN=DEALER_COST, COLOR=GREEN, $
TYPE=SUBTOTAL, BY=1, COLUMN=RETAIL_COST, COLOR=BLUE, $
TYPE=SUBTOTAL, BY=2, COLUMN=DEALER_COST, COLOR=PURPLE, $
TYPE=SUBTOTAL, BY=2, COLUMN=RETAIL_COST, COLOR=RED, $
ENDSTYLE
END

posted

Thanks for your input. I tried working with the COLUMN subtype as you suggest but didn't have success. I was probably missing something. Anyway, since it was only the label for the subtotal that was causing me the problem (it would send a null value for one of the drill down parameters when clicked), I simply altered the code in the child report to branch to a different set of instructions that did not require that parameter when the requesting FEX did not supply a value for it. This turned out to be a better solution as it furnishes the user with an additional report option.

Please Wait. Your request is being processed...

Read-Only Topic

Focal Point

Focal Point Forums

WebFOCUS/FOCUS Forum on Focal Point

Drilldown on Subtotal

Focal Point | Privacy Statement | Terms of Service