Hello Everyone,

I am trying to display a bar chart with a report below the chart representing the same information.

For now I am combining the two fex files (one for chart and the other for report) for the required display.

My requirement is to display the cash/amount across dates.

I want the report horizontally i.e; column 1 should have Date and Cash as Rows 1 and 2. the remaining columns should display the Dates and Respective Amount.

Looking for suggestions

Thanks,
Nihitha

This message has been edited. Last edited by: FP Mod Chuck,

Nihitha

I would suggest creating two separate fex files and creating a document and referencing them separately so you can place them the way you wish.
.
I am not sure I understand your horizontal report requirements. Can you post a sample of how you want the output to look

Nihitha

I hope someone else can help with this, I don't have a trick to put the labels to the left of the data...

I don't know any setting that will allow you that.

Can accomplish with this

DEFINE FILE GGSALES
DTE/A10V = FPRINT(DATE, 'I8YYMD', 'A10V');
END
TABLE FILE GGSALES
SUM COMPUTE DOL /D8CM = DOLLARS; NOPRINT
    COMPUTE VAL /A15V = FPRINT(DOL, 'D8CM', 'A15V');
BY TOTAL COMPUTE COLID /I2 = 2;
BY DTE
WHERE DATE GT 19970101
ON TABLE HOLD AS DATAFIL
END
-RUN

TABLE FILE GGSALES
SUM COMPUTE VAL /A15V = 'Cash';
BY TOTAL COMPUTE COLID /I2 = 1;
BY TOTAL COMPUTE DTE /A10V = 'Date';
BY CITY NOPRINT
WHERE READLIMIT   EQ 1;
WHERE RECORDLIMIT EQ 1;
ON TABLE HOLD AS LABELFIL
END
-RUN

TABLE FILE LABELFIL
SUM VAL
BY COLID
BY DTE
ON TABLE HOLD AS RPTDATA
MORE
FILE DATAFIL
END
-RUN

TABLE FILE RPTDATA
SUM VAL AS ''
ACROSS COLID NOPRINT
ACROSS DTE AS ''
ON TABLE SET PAGE-NUM NOLEAD
END
-RUN

You could use the ACROSSTITLE setting like this:

 DEFINE FILE ibisamp/ggsales
 Cash/A9='Cash';
 END
 TABLE FILE ibisamp/ggsales
    SUM DOLLARS/P9M AS ''
     BY Cash        AS ''
 ACROSS DATE        AS 'Date'
 WHERE DATE GE 19970101
 ON TABLE SET ACROSSTITLE SIDE
 ON TABLE SET STYLE *
 TYPE=ACROSSTITLE, COLOR=BLUE,$
 TYPE=DATA, COLUMN=Cash, COLOR=BLUE,$
 END