I've been trying to get a compound PDF to print reports in a flexible way, but am not very successful.
Issue is:
I have two reports on the compound PDF page.
Both occupy half the page (when designing) so nr 2 has been placed immediately below nr 1.
Problem is that I do not know up front how many records there will be in report1.
What I'd like to see as a result is that report1 starts and fills the page, overflows and goes to the next page etc etc, until there are no more records, and that only then report2 starts.
What I see happening is that report1 starts, overflows to next pages and such, but report2 is also started on the first page and overwrites report1.
And I can't seem to get it right ...

This message has been edited. Last edited by: GamP,

What sort of compound report are you using ?

Can you post code ?

Mke the first report "Flowing" and link the second report to it.

Hi.

We hardly ever use the actual PDF-composer.

SET COMPOUND = OPEN NOBREAK
-INCLUDE PART1.PDF
SET COMPOUND = NOBREAK
-INCLUDE PART2.PDF
SET COMPOUND =
-INCLUDE PART3.PDF
SET COMPOUND = CLOSE
-INCLUDE PART4.PDF

etc.

Thanks, but alas no success.
My code:

-* Default Mode: ResourceLayout
SET HTMLARCHIVE=ON
*-HOLD_SOURCE
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=CM, $
SECTION=section1, LAYOUT=ON, METADATA='prop_with_names^Margins_Left=0.5^Margins_Top=0.5^Margins_Right=0.5^Margins_Bottom=0.5^thumbnailscale=4', 
 MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=A4, SHOW_GLOBALFILTER=OFF, $
PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5,
 METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2, POSITION=(0.476 0.794), DIMENSION=(* *), BYTOC=0,  ARREPORTSIZE=DIMENSION,
 METADATA='left: 0.476cm; top: 0.794cm; width: 20.108cm; height: 14.817cm; position: absolute; z-index: 1;', $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=2, POSITION=(1.216 16.415), DIMENSION=(* *), BYTOC=0,  ARREPORTSIZE=DIMENSION,
 METADATA='left: 1.216cm; top: 16.415cm; width: 19.844cm; height: 12.965cm; position: absolute; z-index: 2;', $
END
SET COMPONENT='report1'
-*component_type report
-INCLUDE try_it1.fex
SET COMPONENT='report2'
-*component_type report
-INCLUDE try_it2.fex
COMPOUND END

The try_it fexes:

-* File try_it1.fex

-DEFAULT &STRNG = 'a'

TABLE FILE HR
PRINT *
WHERE LASTNAME CONTAINS &STRNG.QUOTEDSTRING;
ON TABLE SET PAGE-NUM NOLEAD
-*ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
     INCLUDE = ENblue-medium,
$
ENDSTYLE
END

and:

-* File: try_it2.fex

-DEFAULT &STRNG = 'a'

TABLE FILE INVENTO
SUM   PRICE
      COST
      QUANTITYINSTOCK
BY    PRODUCTNAME
BY    PRODUCTCATEGORY
WHERE PRODUCTCATEGORY CONTAINS &STRNG.QUOTEDSTRING;
ON TABLE SET PAGE-NUM NOLEAD
-*ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
     INCLUDE = ENblue-medium,
$
ENDSTYLE
END

Dave: I tried the compound open nobreak, no luck.
Doug: Both reports are set to flowing. I have no idea how to link report2 to report1. There is nothing in the graphical interface that even hints to this possibility.

Any ideas anyone?

Hi Gamp,

You need to change the POSITION ttributes to relative instead of arbitary by using + or - and also make use of the RELATIVE-TO, RELATIVE-POINT and POSITION-POINT syntax.

You should be able to locate them in the online help files - there's too much to include it here

Good luck.

T

Thanks Tony, that helped me out!
I now have coded:

PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1', $
COMPONENT='report1', TEXT='report1', POSITION=( 0.6  0.6), DIMENSION=(* *), 
   OVERFLOW-POSITION=(0.6 0.6), OVERFLOW-DIMENSION=(20 28), $
COMPONENT='report2', TEXT='report2', POSITION=(+0.0 +0.6), DIMENSION=(* *),
   RELATIVE-TO='report1', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT, $

which does exactly what I want it to do.
Just don't try to open it in the graphical tool - it will totally mess up the output....

GamP,
IMHO you should tag your post as [SOLVED] not [CLOSED] since you found a solution; just to follow forum's guidelines.

[SOLVED] – This should be placed in the subject title when a solution to the question has been posted in the thread. There are many great discussions and solutions on Focal Point. Using this keyword will help communicate to everyone when a solution has been received. This will also be helpful in the future for new Focal Point members when they are searching for answers to questions they have. If this keyword appears in the subject title they will know there is a solution in the thread.

[CLOSED] – This should be placed in the subject title when if a solution/suggestion is given, or if a request for more info is made, e.g. code, master files, and we follow-up with the topic starter via one private message, but there is no response or update from the topic starter in 2 business days. This is similar to [SOLVED] except that there is no final confirmation from the topic starter.