Hi,

I would like to populate a file within WebFocus that contains a list of acceptable values for parameters to be validated against.

I have created the code to do this, however I now get the following error:

(FOC198) FATAL ERROR IN DATABASE I/O. FOCUS TERMINATING ERROR WRITING FOCSORT,
PAGE 28173, CODE 0xffffffff

I have used XFOCUS HOLD files as I believe these are the largest HOLD files available????

Is there a way to do this using HOLD files or do I need to look to a different solution?

Thanks

Mark,

APP HOLD HOLDFILES
SET HOLDLIST=PRINTONLY
SET XFOCUS=ON
SET XFOCUSBINS=1023
-* ---------------------------------------------------------------------------------------------------
-* SET MASTER FILE PATH
-* ---------------------------------------------------------------------------------------------------
-SET &MFD_PATH = 'MFDNODBA';
-* ---------------------------------------------------------------------------------------------------
-* BUILD WHITE LIST FOR EACH ATTRIBUTE
-* ---------------------------------------------------------------------------------------------------
SET BYDISPLAY=ON
-SET &ECHO = ALL;

-* ---------------------------------------------------------------------------------------------------
-* EXRACT COMPLETE LIST OF MASTER FILES INTO A HOLD FILE
-* ---------------------------------------------------------------------------------------------------
TABLE FILE SYSTABLE
PRINT NAME
-*WHERE REMARKS NE ' '
WHERE NAME EQ 'volumes_cube'
ON TABLE HOLD AS Masters FORMAT ALPHA
END

-* ---------------------------------------------------------------------------------------------------
-* SET VARIABLES REQUIRED FOR LOOP THROUGH OF MASTER FILES, AND INITIATE LOOP
-* ---------------------------------------------------------------------------------------------------
-SET &RECCOUNT = &LINES;
-*
-RUN
-SET &I=0;
-START
-SET &I=&I+1;
-* ---------------------------------------------------------------------------------------------------
-* READ THE Masters HOLD FILE LINE BY LINE
-* ---------------------------------------------------------------------------------------------------
-READ Masters NOCLOSE &MasterFile.A50.
-* ---------------------------------------------------------------------------------------------------
-* CONVERT FIELD TO UPPERCASE
-* ---------------------------------------------------------------------------------------------------
-SET &MasterFileUC=UPCASE(50,&MasterFile,'A50');

CHECK FILE &MasterFileUC HOLD
TABLE FILE HOLD
PRINT FIELDNAME/A100 AND FILENAME/A100 AND ACTUAL
BY FIELDNAME NOPRINT
BY FILENAME NOPRINT
WHERE FILENAME = &MasterFileUC.QUOTEDSTRING;
ON TABLE HOLD AS MasterFields FORMAT ALPHA
END

-* ---------------------------------------------------------------------------------------------------
-* EXRACT COMPLETE LIST OF FIELDNAMES WHERE NOT A MEASURE FIELD
-* ---------------------------------------------------------------------------------------------------
TABLE FILE SYSCOLUM
PRINT NAME/A100 AND PROPERTY AND FILENAME/A100
BY NAME NOPRINT
BY FILENAME NOPRINT
WHERE PROPERTY NE 'MEASURE'
ON TABLE HOLD AS NonMeasureFields FORMAT ALPHA
END
-*-*
-*-*
-* ---------------------------------------------------------------------------------------------------
-* JOIN THE TWO DATA SETS
-* ---------------------------------------------------------------------------------------------------
JOIN CLEAR *
JOIN INNER FIELDNAME AND FILENAME IN MasterFields TO NAME AND FILENAME IN NonMeasureFields
END
-*-*
-* ---------------------------------------------------------------------------------------------------
-* STORE THE RESULT FROM THE JOIN IN A HOLD FILE
-* ---------------------------------------------------------------------------------------------------
TABLE FILE MasterFields
PRINT NAME AND ACTUAL
WHERE NAME NE ' '
ON TABLE SAVE AS WhiteListAttributes FORMAT ALPHA
END

-*
-* ---------------------------------------------------------------------------------------------------
-* SET VARIABLES REQUIRED FOR LOOP THROUGH OF FIELDS, AND INITIATE LOOP
-* ---------------------------------------------------------------------------------------------------
-SET &WHTLSTCOUNT = &LINES;
-*
-SET &II=0;
-INNERSTART
-SET &II=&II+1;
-* ---------------------------------------------------------------------------------------------------
-* READ EACH FIELD
-* ---------------------------------------------------------------------------------------------------
-READ WhiteListAttributes NOCLOSE &AllowedValue.A100. &FIELDTYPE.A5.
-* ---------------------------------------------------------------------------------------------------
-* CHECK FORMAT OF EACH FIELD, DATES NEED TO BE HANDLED DIFFERENTLY
-* ---------------------------------------------------------------------------------------------------
-IF &FIELDTYPE NE DATE THEN CONTINUE ELSE GOTO DAT;
-SET &AllowedValue = TRUNCATE(&AllowedValue);
-TYPE &AllowedValue
DEFINE FILE &MasterFileUC
Attribute/A100='&AllowedValue';
AllowedValue/A100=&AllowedValue;
END

-GOTO CONT;

-DAT
-SET &AllowedValue = TRUNCATE(EDIT(&AllowedValue));
DEFINE FILE &MasterFileUC
Attribute/A100='&AllowedValue';
AllowedValue/A100=EDIT(&AllowedValue);
END

-CONT
-* ---------------------------------------------------------------------------------------------------
-* INTERROGATE DATA SOURCES AND RETURN VALUES
-* ---------------------------------------------------------------------------------------------------
TABLE FILE &MasterFileUC
BY Attribute
BY AllowedValue
ON TABLE HOLD AS Src FORMAT XFOCUS
END
-* ---------------------------------------------------------------------------------------------------
-* MERGE DATA SETS INTO ONE FINAL WHITELIST
-* ---------------------------------------------------------------------------------------------------
-IF &II EQ 1 THEN CONTINUE ELSE GOTO MERGE;

TABLE FILE Src
PRINT Attribute AND AllowedValue
ON TABLE HOLD AS Whitelist2 FORMAT XFOCUS
END

-MERGE
TABLE FILE Src
PRINT Attribute AND AllowedValue
ON TABLE HOLD AS Whitelist3 FORMAT XFOCUS
MORE
FILE Whitelist2
END

TABLE FILE Whitelist3
PRINT Attribute AND AllowedValue
ON TABLE HOLD AS Whitelist2 FORMAT XFOCUS
END

-IF &II LT &WHTLSTCOUNT THEN GOTO INNERSTART;
-INNERENDLOOP

-CLOSE WhiteListAttributes

-IF &I LT &RECCOUNT THEN GOTO START;
-ENDLOOP
-CLOSE Masters

This message has been edited. Last edited by: faddybloom,

This looks like an available space issue. 28173 pages is well below the focsort limit and 0xffffffff points to lack of space on the server.