I know this is probably a simple thing but I just can't get it to do what I want. I would like a subhead between the titles and the start of the data, and a subfoot between the end of the data and the subtotals. The following code is close to what I want but if you run it, you will see that the subfoot appear AFTER the subtotal. Any suggestions ?

TABLE FILE CAR
PRINT CAR MODEL SEATS
BY COUNTRY
WHERE COUNTRY EQ 'ENGLAND' OR 'ITALY';
ON COUNTRY SUBHEAD
"subhead"
ON COUNTRY SUBFOOT
"subfoot"
ON COUNTRY SUBTOTAL AS '*'

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=DATA,
SIZE=8,
$
TYPE=TITLE,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
SIZE=9,
COLOR='BLACK',
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
SIZE=9,
COLOR='BLACK',
STYLE=BOLD,
$
ENDSTYLE

ON TABLE NOTOTAL
END

This message has been edited. Last edited by: FP Mod Chuck,

Can you have two lines for subfoot?

  
TABLE FILE CAR
PRINT CAR MODEL SEATS
BY COUNTRY 
WHERE COUNTRY EQ 'ENGLAND' OR 'ITALY';
ON COUNTRY SUBHEAD
"subhead"
ON COUNTRY SUBFOOT
"subfoot"
"<COUNTRY <+0> <+0><ST.SEATS "
-*ON COUNTRY SUBTOTAL AS '*'

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=DATA,
SIZE=8,
$
TYPE=TITLE,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
SIZE=9,
COLOR='BLACK',
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
SIZE=9,
COLOR='BLACK',
STYLE=BOLD,
$ 
TYPE=SUBFOOT, HEADALIGN=BODY, $
ENDSTYLE

ON TABLE NOTOTAL
END

Sorry no good as we want the grid box around the subtotals but not the subfoot.

Ian, this gets you most of the way. Unfortunately, there's a border alignment problem for the last component of the subfoot subtotal, which ALIGN-BORDERS is supposed to fix, but doesn't seem to.

-* File ian_dalton_2.fex

TABLE FILE CAR
PRINT CAR MODEL SEATS
BY COUNTRY

WHERE COUNTRY EQ 'ENGLAND' OR 'ITALY';

ON COUNTRY SUBHEAD
"Subhead"

ON COUNTRY SUBFOOT WITHIN
"Subfoot"
"<COUNTRY <+0> <SEATS"

ON TABLE NOTOTAL

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$

TYPE=REPORT, ALIGN-BORDERS=BODY, $

TYPE=TITLE,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
STYLE=BOLD,
$
TYPE=SUBTOTAL,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
STYLE=BOLD,
$
TYPE=SUBFOOT, HEADALIGN=BODY, $

TYPE=SUBFOOT, LINE=2, ITEM=1,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
STYLE=BOLD,
$
TYPE=SUBFOOT, LINE=2, ITEM=2,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
STYLE=BOLD,
$
TYPE=SUBFOOT, LINE=2, ITEM=3,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
STYLE=BOLD,
$
TYPE=SUBFOOT, LINE=2, ITEM=4,
BORDER=LIGHT,
BORDER-STYLE=RIDGE,
BORDER-COLOR=RGB(51 51 153),
STYLE=BOLD,
$

ENDSTYLE
END

In v7.7.05, there's a section in the documentation called "Creating Reports With WebFOCUS Language > Laying Out the Report Page > Adding Grids and Borders > Align Subheading and Subfooting Margins With the Report Body". This might be improved in a modern version of WebFOCUS.

Thanks Francis - I note you said 'might'....

I suppose it should have been this:

ON COUNTRY SUBFOOT WITHIN
"<COUNTRY <+0> <SEATS"
"Subfoot"

And, if you really need the * in front of COUNTRY subtotal, you'll have to DEFINE or COMPUTE a column...

I think the trick is the WITHIN phrase - seems to do the job. Many thanks.