[CLOSED] How to border item in the report header ?

March 21, 2014, 04:23 PM

In my report header, I put 3 lines, each line have 4 items, I need to put the border at item 2 and 4 of line 2 and 3. Anybody have solution for this ?
Thanks in advance.

This message has been edited. Last edited by: hainguyen,

March 21, 2014, 04:53 PM

njsden

As far as I know, you can't put borders around inner items in a HEADING, only around the whole HEADING itself.

March 21, 2014, 05:11 PM

njsden

When I've had similar needs in the past, I had resorted to use SUBHEAD to simulate the heading and column titles (one-pager HTML report only!) as shown in the sample below:

DEFINE FILE CAR
BRK/A1 = ' ';
END
TABLE FILE CAR
PRINT
        CAR AS ''
        MODEL AS ''
        DEALER_COST AS ''
BY BRK NOPRINT
BY COUNTRY AS ''
ON BRK SUBHEAD
"1.1<+0>1.2<+0>1.3<+0>1.4"
"2.1<+0>2.2<+0>2.3<+0>2.4"
"3.1<+0>3.2<+0>3.3<+0>3.4"
"COUNTRY<+0>CAR<+0>MODEL<+0>DEALER_COST"
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE OFF
ON TABLE HOLD AS HREPORT FORMAT HTMTABLE
ON TABLE SET STYLE *
TYPE=REPORT, UNITS=PTS, $
TYPE=DATA, BORDER=0.5, $
TYPE=TITLE, BORDER=0.5, $
$
TYPE=SUBHEAD, HEADALIGN=BODY, $
$
TYPE=SUBHEAD, LINE=2, OBJECT=TEXT, ITEM=2, CLASS=cellborder, $
TYPE=SUBHEAD, LINE=3, OBJECT=TEXT, ITEM=4, CLASS=cellborder, $
TYPE=SUBHEAD, LINE=2, OBJECT=TEXT, ITEM=2, CLASS=cellborder, $
TYPE=SUBHEAD, LINE=3, OBJECT=TEXT, ITEM=4, CLASS=cellborder, $
-* "TITLE" formatting
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT, ITEM=1, CLASS=title, $
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT, ITEM=2, CLASS=title, $
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT, ITEM=3, CLASS=title, $
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT, ITEM=4, CLASS=title, $
ENDSTYLE
END
-RUN

-HTMLFORM BEGIN
<html><head>
<style type="text/css">
.title, .cellborder {
   border-top: 0.50pt SOLID #000000; border-bottom: 0.50pt SOLID #000000;
   border-right: 0.50pt SOLID #000000; border-left: 0.50pt SOLID #000000; 
}
.title { background-color: lightgray; }
</style>
<body>
!IBI.FIL.HREPORT;
</body>
</html>
-HTMLFORM END

This message has been edited. Last edited by: njsden,

March 24, 2014, 10:25 AM

hainguyen

Thanks njsden. This is a very cool trick.

This message has been edited. Last edited by: hainguyen,

March 24, 2014, 01:48 PM

njsden

I learned this technique from one of the many cool ones presented by Rob Palmer from IBI

A very useful trick indeed.

March 24, 2014, 02:19 PM

MartinY

Maybe we're not able to add border to specific element in a header, however if it's to put in evidence some info, you can highlight element in heading :

 TABLE FILE CAR
PRINT
     CAR.CARREC.MODEL
BY  LOWEST CAR.COMP.CAR
HEADING
"Hd R1C1<+0>Hd R1C2: <CAR.ORIGIN.COUNTRY<+0>Hd R1C3<+0>Hd R1C4"
"Hd R2C1<+0>Hd R2C2<+0>Hd R2C3<+0>Hd R2C4"
WHERE CAR.ORIGIN.COUNTRY EQ 'ENGLAND';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     LEFTMARGIN=0.250000,
     RIGHTMARGIN=0.250000,
     TOPMARGIN=0.250000,
     BOTTOMMARGIN=0.250000,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=HEADING,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,
     BORDER-LEFT=LIGHT,
     BORDER-RIGHT=LIGHT,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     JUSTIFY=RIGHT,
     WIDTH=1.375,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=3,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=4,
     JUSTIFY=CENTER,
     WIDTH=2.000,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.625,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     COLOR='WHITE',
     BACKCOLOR='GREEN',
     JUSTIFY=CENTER,
     WIDTH=3.000,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=3,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=4,
     COLOR='WHITE',
     BACKCOLOR='GREEN',
     JUSTIFY=CENTER,
     WIDTH=2.000,
$
ENDSTYLE
END