I am creating a Vertical Stacked Bar Chart with the following GRAPH FILE command:

GRAPH FILE CAR
SUM    DEALER_COST
       RETAIL_COST
BY     COUNTRY
ON GRAPH PCHOLD FORMAT JSCHART
ON GRAPH SET VZERO OFF
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET GRWIDTH 1
ON GRAPH SET GRMERGE OFF
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET AUTOFIT ON
END  

I see each country as one single bar, and each bar is divided into Dealer and Retail Cost.

I would now like to see each bar/country as a single Pie Chart.

Here is the code I have so far:

GRAPH FILE CAR
SUM    DEALER_COST
       RETAIL_COST
BY     COUNTRY
ACROSS COUNTRY
ON GRAPH PCHOLD FORMAT JSCHART
ON GRAPH SET VZERO OFF
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET GRWIDTH 1
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 1
ON GRAPH SET GRLEGEND 0
ON GRAPH SET GRXAXIS 1
ON GRAPH SET LOOKGRAPH PIEMULTR
ON GRAPH SET AUTOFIT ON
END  

This seems to work for the first country 'ENGLAND', but for the 2nd COUNTRY I see two pie charts (one being an empty pie), and for the third COUNTRY I see three charts (two being empty pies)...

How do I only see one chart per country?

This message has been edited. Last edited by: <Kathryn Henning>,

Check out GRMERGE.

quote:

Originally posted by Doug:
Check out GRMERGE.

Thanks Doug, I did review GRMERGE, but am not able to descern how to set, in order to get the results I am looking for.

My current GRMERGE settings, are giving me instances for each COUNTRY, but only 'ENGLAND' has the one pie I am looking for.

ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 1
ON GRAPH SET GRLEGEND 0 
ON GRAPH SET GRXAXIS 1 

Hi David,

Does this give you what you are after?

ON GRAPH SET GRMERGE ON

T

I used the MacGyver technique to create a new field: COST_TYPE. Once I did that the GRAPH FILE command seemed easier to write, so I'd get one pie chart for each COUNTRY:

FILEDEF FSEQ DISK common/fseq.txt
-RUN
JOIN CLEAR *
JOIN BLANK WITH DEALER_COST IN CAR TO BLANK IN FSEQ AS J1
DEFINE FILE CAR
 BLANK/A1 WITH DEALER_COST = ' ';
 COST_TYPE/A10 = IF COUNTER EQ 1 THEN 'DEALER' ELSE 'RETAIL';
 COST/D12.2 = IF COUNTER EQ 1 THEN DEALER_COST ELSE RETAIL_COST;
END
TABLE FILE CAR
SUM   COST
BY    COUNTRY
BY    COST_TYPE
IF COUNTER LE 2
ON TABLE HOLD AS FOCCACHE/HLDCOST
END
-RUN
ENGINE INT CACHE SET ON
-DEFAULTH &WF_STYLE_UNITS='PIXELS';
-DEFAULTH &WF_STYLE_HEIGHT='205.0';
-DEFAULTH &WF_STYLE_WIDTH='350.0';
GRAPH FILE HLDCOST
SUM HLDCOST.HLDCOST.COST
BY HLDCOST.HLDCOST.COUNTRY
BY HLDCOST.HLDCOST.COST_TYPE
ON GRAPH PCHOLD FORMAT JSCHART
ON GRAPH SET VZERO OFF
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET UNITS &WF_STYLE_UNITS
ON GRAPH SET HAXIS &WF_STYLE_WIDTH
ON GRAPH SET VAXIS &WF_STYLE_HEIGHT
ON GRAPH SET GRWIDTH 2
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 1
ON GRAPH SET GRLEGEND 0
ON GRAPH SET GRXAXIS 1
ON GRAPH SET LOOKGRAPH PIERING
ON GRAPH SET AUTOFIT ON
ON GRAPH SET STYLE *
*GRAPH_SCRIPT
setPieDepth(0);
setPieTilt(0);
setDepthRadius(0);
setCurveFitEquationDisplay(false);
setPlace(true);
setPieFeelerTextDisplay(1);
*END
INCLUDE=IBFS:/FILE/IBI_HTML_DIR/javaassist/intl/EN/ENIADefault_combine.sty,$
TYPE=REPORT, TITLETEXT='WebFOCUS Report', $
*GRAPH_SCRIPT
setReportParsingErrors(false);
setSelectionEnableMove(false);
*END
ENDSTYLE
END