I'm trying to style an FML report with a PDF output and no matter what I try, I'm finding a very large amount of space between the value and the right border of the column.

I've tried setting the LEFTGAP and RIGHTGAP to 0.00, I've set SPACES=1, I've set SQUEEZE=ON and also SQUEEZE=.85 (in inches). No matter what I've tried I have almost as much space as the number values take up (working with 7digits plus decimal places). I do not have the same problem when outputting the report to HTML so it has to have something to do with PDF specifically.

Here is my styling....

  

SET PAGESIZE=LEGAL
SET ORIENTATION=LANDSCAPE
SET SPACES=1
.
.
.
ON TABLE SET STYLE *
    
    TYPE=REPORT, STYLE=NORMAL, GRID=OFF, BORDER=OFF, SQUEEZE=ON, LEFTGAP=0.01, RIGHTGAP=0.01, SIZE=9,$

    TYPE=HEADING,           STYLE=NORMAL,   JUSTIFY=LEFT,   SIZE=9,$
    TYPE=HEADING, LINE=1,   STYLE=BOLD,     JUSTIFY=CENTER, SIZE=14,$
    TYPE=HEADING, LINE=2,                   JUSTIFY=CENTER,$

    TYPE=ACROSSVALUE, STYLE=BOLD,$    

    -* Bold and underline the income and expense labels
    TYPE=DATA, LABEL=INCOME,  STYLE=UNDERLINE,$
    TYPE=DATA, LABEL=INCOME,  STYLE=BOLD,$
    TYPE=DATA, LABEL=EXPENSE, STYLE=UNDERLINE,$
    TYPE=DATA, LABEL=EXPENSE, STYLE=BOLD,$

    TYPE=DATA, LABEL=NON_TRANS_INCOME,    STYLE=BOLD,$
    TYPE=DATA, LABEL=TOTAL_INCOME,        STYLE=BOLD,$
    TYPE=DATA, LABEL=PS,                  STYLE=BOLD,$
    TYPE=DATA, LABEL=GEN_EXPENSE,         STYLE=BOLD,$
    TYPE=DATA, LABEL=TOTAL_EXPENSE,       STYLE=BOLD,$
    TYPE=DATA, LABEL=NET,                 STYLE=BOLD,$
    TYPE=DATA, LABEL=TOTAL_FUNDS,         STYLE=BOLD,$

    -* Add Right border to TOTAL columns
    TYPE=DATA, 
        COLUMN=N5,
        BORDER-RIGHT=MEDIUM,
        BORDER-RIGHT-STYLE=SOLID,
        BORDER-RIGHT-COLOR='RED',$
    TYPE=DATA,
        COLUMN=N9,
        BORDER-RIGHT=MEDIUM,
        BORDER-RIGHT-STYLE=SOLID,
        BORDER-RIGHT-COLOR='BLUE',$

ENDSTYLE

Any help or suggestions you could offer is appreciated.

This message has been edited. Last edited by: noelmcavoy,

Can you post an example with one of the sample files ?

Absolutely, I'll put that together and post it in the morning. Thanks!

Here's my problem using the cars sample file. When you run this, the red border you see is illustrating the right border and the distance between the value and that side for each column.

Any help or suggestions would be awesome.

 

TABLE FILE CAR
    SUM
        CAR.BODY.DEALER_COST

    ACROSS CAR.BODY.BODYTYPE
    ACROSS CAR.CARREC.MODEL

    FOR CAR.COMP.CAR
        JAGUAR AS 'Jaguar' LABEL JAGUAR OVER
        AUDI AS 'Audi' LABEL AUDI OVER
        JENSEN AS 'Jensen' LABEL JENSEN OVER
        BAR OVER
        RECAP RANDOM/D20.2CB=JAGUAR+AUDI+JENSEN; AS 'Total Random Cars'
    ON TABLE SET PAGE-NUM NOLEAD
    ON TABLE PCHOLD FORMAT PDF
    ON TABLE SET HTMLCSS ON
    ON TABLE HEADING
        "Random Car Report"
        "Run On: &DATE"
        "Org: Mine"
        "FY17 Through FP04"
    ON TABLE FOOTING
        "Footer without meaning here"
    ON TABLE SET LINES 999999
    ON TABLE SET STYLE *
        TYPE=REPORT, STYLE=NORMAL, GRID=OFF, BORDER=OFF, SQUEEZE=ON, LEFTGAP=0.01, RIGHTGAP=0.01, SIZE=9,$
        TYPE=HEADING,           STYLE=NORMAL,   JUSTIFY=LEFT,   SIZE=9,$
        TYPE=HEADING, LINE=1,   STYLE=BOLD,     JUSTIFY=CENTER, SIZE=14,$
        TYPE=HEADING, LINE=2,                   JUSTIFY=CENTER,$
        TYPE=ACROSSVALUE, STYLE=BOLD,$
        TYPE=DATA,
        BORDER-RIGHT=MEDIUM,
        BORDER-RIGHT-STYLE=SOLID,
        BORDER-RIGHT-COLOR='RED',$

END
-RUN
 

It appears that the width of each across column is the same - based on the longest text "100 LS 2 DOOR AUTO".

You can verify this by changing your across dimensions - use SEATS instead of BODYTYPE and MODEL. Seats is one digit, so the across columns are narrower.

I cannot explain why the across column values are not completely right-justified within each column.

Francis is correct.
WF adds spaces to each column on the right instead of on the left to accommodate the width of the ACCROSSVALUE.
See what happens when I changed the formatting of your data:

  
TABLE FILE CAR
    SUM
        CAR.BODY.DEALER_COST/D20.5

    ACROSS CAR.BODY.BODYTYPE
    ACROSS SEATS

    FOR CAR.COMP.CAR
        JAGUAR AS 'Jaguar' LABEL JAGUAR OVER
        AUDI AS 'Audi' LABEL AUDI OVER
        JENSEN AS 'Jensen' LABEL JENSEN OVER
        BAR OVER
        RECAP RANDOM/D20.5=JAGUAR+AUDI+JENSEN; AS 'Total Random Cars'
    ON TABLE SET PAGE-NUM NOLEAD
    ON TABLE PCHOLD FORMAT PDF
    ON TABLE SET HTMLCSS ON
    ON TABLE HEADING
        "Random Car Report"
        "Run On: &DATE"
        "Org: Mine"
        "FY17 Through FP04"
    ON TABLE FOOTING
        "Footer without meaning here"
    ON TABLE SET LINES 999999
    ON TABLE SET STYLE *
        TYPE=REPORT, STYLE=NORMAL, GRID=OFF, BORDER=OFF, SQUEEZE=ON, LEFTGAP=0.01, RIGHTGAP=0.01, SIZE=9,$
        TYPE=HEADING,           STYLE=NORMAL,   JUSTIFY=LEFT,   SIZE=9,$
        TYPE=HEADING, LINE=1,   STYLE=BOLD,     JUSTIFY=CENTER, SIZE=14,$
        TYPE=HEADING, LINE=2,                   JUSTIFY=CENTER,$
        TYPE=ACROSSVALUE, STYLE=BOLD, JUSTIFY=RIGHT,$
        TYPE=DATA,
        BORDER-RIGHT=LIGHT,
        BORDER-RIGHT-STYLE=SOLID,
        BORDER-RIGHT-COLOR='RED',$

END

The values of SEATS are justified RIGHT.
The additional decimals cause the data to "cling" to the right red border.
Conclusion: ask IBI!

You guys are awesome, once you pointed out that it was the longest ACROSSVALUE width that was determining the width of every across column I realized that by wrapping the ACROSSVALUE I may be able to get the width under control (assuming my user doesn't mind them being wrapped. I tried it out and it worked!

I'm posting the code I'm using now for future reference, hopefully it can help someone else as well.

 


TABLE FILE CAR
    SUM
        CAR.BODY.DEALER_COST

    ACROSS CAR.BODY.BODYTYPE
    ACROSS CAR.CARREC.MODEL

    FOR CAR.COMP.CAR
        JAGUAR AS 'Jaguar' LABEL JAGUAR OVER
        AUDI AS 'Audi' LABEL AUDI OVER
        JENSEN AS 'Jensen' LABEL JENSEN OVER
        BAR OVER
        RECAP RANDOM/D20.2CB=JAGUAR+AUDI+JENSEN; AS 'Total Random Cars'
    ON TABLE SET PAGE-NUM NOLEAD
    ON TABLE PCHOLD FORMAT PDF
    ON TABLE SET HTMLCSS ON
    ON TABLE HEADING
        "Random Car Report"
        "Run On: &DATE"
        "Org: Mine"
        "FY17 Through FP04"
    ON TABLE FOOTING
        "Footer without meaning here"
    ON TABLE SET LINES 999999
    ON TABLE SET STYLE *
        TYPE=REPORT, STYLE=NORMAL, GRID=OFF, BORDER=OFF, SQUEEZE=ON, LEFTGAP=0.10, RIGHTGAP=0.10, SIZE=9,$
        TYPE=HEADING,           STYLE=NORMAL,   JUSTIFY=LEFT,   SIZE=9,$
        TYPE=HEADING, LINE=1,   STYLE=BOLD,     JUSTIFY=CENTER, SIZE=14,$
        TYPE=HEADING, LINE=2,                   JUSTIFY=CENTER,$
        TYPE=ACROSSVALUE, STYLE=BOLD, JUSTIFY=RIGHT, WRAP=ON,$
        TYPE=DATA,
        BORDER-RIGHT=MEDIUM,
        BORDER-RIGHT-STYLE=SOLID,
        BORDER-RIGHT-COLOR='RED',$

END
-RUN

 

Noel,
For a newbie you are doing well indeed!