Hy,

I have I problem with a compound report in PDF format. Each part of the compound report is posted on a page like this:
page 1 - report 1
page 2 - report 2
page 3 - report 3

Is it possible to obtain this compound report on a single page ?
For example when I use the Excel format I have something like

'ON TABLE PCHOLD FORMAT EXL2K OPEN NOBREAK' but for PDF I can't use NOBREAK.
I wonder if there is a similar syntax.

Thanks in advance for your answers.

You can definitely use NOBREAK for PDF compound reports:

-* Report 1 ----------------------------

SET PAGE-NUM=OFF
TABLE FILE CAR
  SUM SALES/D10
  BY COUNTRY
  BY CAR

  HEADING
  "1 - Sales Report"
  " "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=RED, $
TYPE=HEADING, SIZE=12, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF OPEN NOBREAK
END
-RUN

-* Report 2 ----------------------------

TABLE FILE CAR
  SUM DEALER_COST
  BY COUNTRY
  BY MODEL

  HEADING
  "2 - Inventory Report"
  " "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=BLUE, $
TYPE=HEADING, SIZE=12, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF NOBREAK
END
-RUN

-* Report 3 ----------------------------

TABLE FILE CAR
  SUM BODYTYPE
  BY COUNTRY
  BY BODYTYPE NOPRINT

  HEADING
  "3 - Body Type Report"
  " "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=GREEN, $
TYPE=HEADING, SIZE=12, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF CLOSE
END
-RUN

This message has been edited. Last edited by: Francis Mariani,

Angel

Welcome here, please update your personal signature with some version information so we all know what you are using.

The answer from Francis is the basic on.
Depending on your version there might be other ways to solve this.
One is the PDF layout painter which give you the possibility to "paint" your report with a header, logo, and put the various report components including graphics on the paper as you like it.

Hello again,

I'm using WF 5.3.3.
I tried again to use NOBREAK for PDF but I got the same strange result:each report has an independent orientation
My compound report looks like this
||
||
=
where each || is a report.

And also I can't 'paint' my report because there are a lot of labels, conditional instructions.
I can only made it by hand

Thanks,

Mady

Hi

Use FOCFIRSTPAGE to set the page And Compound Command To Open And Close Compound Report
Here is the example


SET FOCFIRSTPAGE = &FOCNEXTPAGE
SET COMPOUND = OPEN

-* Report 2 ----------------------------
TABLE FILE CAR
SUM SALES/D10
BY COUNTRY
BY CAR

HEADING
"1 - Sales Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=RED, $
TYPE=HEADING, SIZE=12, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF
END
-RUN

-* Report 2 ----------------------------
SET FOCFIRSTPAGE = &FOCNEXTPAGE
TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
BY MODEL

HEADING
"2 - Inventory Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=BLUE, $
TYPE=HEADING, SIZE=12, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF
END
-RUN

-* Report 3 ----------------------------
SET FOCFIRSTPAGE = &FOCNEXTPAGE
TABLE FILE CAR
SUM BODYTYPE
BY COUNTRY
BY BODYTYPE NOPRINT

HEADING
"3 - Body Type Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=GREEN, $
TYPE=HEADING, SIZE=12, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF
END
-RUN
SET COMPOUND = CLOSE

Aren't you gonna need a NOBREAK in there somewhere?

Angel, please try running the code I posted. If it works, there may be something small in your stylesheet that needs to be tweaked. If my code does not work, then there could be a bug or some other issue.

Alternative code:

SET PAGE-NUM=OFF

-* Report 1 ----------------------------

SET COMPOUND = OPEN
-RUN

TABLE FILE CAR
SUM SALES/D10
BY COUNTRY
BY CAR

HEADING
"1 - Sales Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=RED, $
TYPE=HEADING, SIZE=11, STYLE=BOLD,$
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF NOBREAK
END
-RUN

-* Report 2 ----------------------------

TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
BY MODEL

HEADING
"2 - Inventory Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=BLUE, $
TYPE=HEADING, SIZE=11, STYLE=BOLD,$
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF NOBREAK
END
-RUN

-* Report 3 ----------------------------

SET COMPOUND = CLOSE
-RUN

TABLE FILE CAR
SUM BODYTYPE
BY COUNTRY
BY BODYTYPE NOPRINT

HEADING
"3 - Body Type Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, SQUEEZE=ON, FONT='Arial', COLOR=GREEN, $
TYPE=HEADING, SIZE=11, STYLE=BOLD,$
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF
END
-RUN

(wf1998, your example does not use NOBREAK, which is the objective of this post, and page numbering was not mentioned as an issue).

Cheers.

This message has been edited. Last edited by: Francis Mariani,

And now the final post about this problem:

I wanna thank you for your answers. The code posted by mr. Francis worked just fine so I started to study the stylesheet and I found a small but ugly bug about orientation.

Mady, The Angel

So, you're not really an angel, then?

Sometimes I am

Bucket of cold water for Francis please

Nice one, Tony.

I think this thread has strayed from the original question.

Time to put this one to rest.

Whaa?