Hi,

Am getting a Styling issue if I use the column name as 'A10000'
Why my code is throwing error?
Here is my code....

 
TABLE FILE CAR
BY CAR AS 'A10000'
BY COUNTRY AS 'A20000'
BY SALES
BY MPG
ON TABLE SET ASNAMES ON 
ON TABLE HOLD AS AFORMAT
END
-RUN
TABLE FILE AFORMAT
BY A10000
BY A20000
BY SALES
ON TABLE SET PAGE NOPAGE
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,SQUEEZE=ON,ORIENTATION=LANDSCAPE,HEADALIGN = BODY,$
TYPE=REPORT, FONT='ARIAL', SIZE=10, COLOR='BLACK', STYLE=NORMAL, $
TYPE=TITLE,  FONT='ARIAL NARROW', COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, BACKCOLOR=RGB(102 102 102),$
TYPE=DATA, COLUMN=A10000, JUSTIFY=CENTER, $
ENDSTYLE
END
 

This message has been edited. Last edited by: Dev,

Naming column starting with an "A" seems to be a reserved letter. I know about "C" and "N" that are reserved.
Using "Z", it's ok

TABLE FILE CAR
BY CAR AS 'Z10000'
BY COUNTRY AS 'Z20000'
BY SALES
BY MPG
ON TABLE SET ASNAMES ON 
ON TABLE HOLD AS AFORMAT
END
-RUN

TABLE FILE AFORMAT
BY Z10000
BY Z20000
BY SALES
ON TABLE SET PAGE NOPAGE
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
-*ON TABLE PCHOLD FORMAT XLSX 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,SQUEEZE=ON,ORIENTATION=LANDSCAPE,HEADALIGN = BODY,$
TYPE=REPORT, FONT='ARIAL', SIZE=10, COLOR='BLACK', STYLE=NORMAL, $
TYPE=TITLE,  FONT='ARIAL NARROW', COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, BACKCOLOR=RGB(102 102 102),$
TYPE=DATA, COLUMN=Z10000, JUSTIFY=CENTER, $
ENDSTYLE
END

Is there any reason why you need to use "A10000" and "A20000" as column's name ?

Columns are coming from DB and we taking it dynamically.
Like converting Rows to columns...

quote:

N

Every thing taking dynamically, so we couldn't take COLUMN=n1.
Let me try to find out the data which are start with A....(with numeric) in DB and to replace as other letter...

If TABLE ... STYLE chokes on the DB column name, you can use DEFINE to effectively rename it (assuming DEFINE doesn't choke). Or use a business view.

Does E01, E02, etc. work?

Fernando

quote:

Does E01, E02, etc. work?

If I use E10000 and E20000 it works. Perhaps a combo of the previous two replies. Do the initial HOLD using some letter other than A such as I did with the E. Then down the line do a DEFINE setting the value of A10000 to what is held in E10000?

One method, if you don't mind building a new synonym on the fly, is to interrogate the contents of the HOLD synonym and then insert your own ALIAS equal to the fieldname prefixed with something (I used "Z_") and then reference the ALIAS in your styling. Then WebFOCUS will not complain

FILEDEF Z_AMASTER DISK Z_AFORMAT.MAS (APPEND
FILEDEF Z_AFORMAT DISK   AFORMAT.FTM
-RUN

TABLE FILE CAR
BY CAR AS 'A10000'
BY COUNTRY AS 'A20000'
BY SALES
BY MPG
ON TABLE SET ASNAMES ON 
ON TABLE HOLD AS AFORMAT
END
-RUN

TABLE FILE SYSCOLUM
PRINT COMPUTE SYNLINE/A4000 = 'FILENAME='||TBNAME||',SUFFIX='||TBTYPE||',$';
      COMPUTE CRLF/A2       = HEXBYT(13,'A1')||HEXBYT(10,'A1');
      COMPUTE SYNLINE/A4000 = 'SEGNAME='||SEGNAME||',SEGTYPE='||SEGTYPE||LJUST(11,FPRINT(SKEYS,'I11','A11'),'A11')||',$';
   BY LOWEST 1 COLNO NOPRINT
WHERE TBNAME EQ 'aformat'
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SAVE AS Z_AMASTER
END
-RUN

TABLE FILE SYSCOLUM
PRINT COMPUTE SYNLINE/A4000 = 'FIELD='||NAME||',ALIAS=Z_'||NAME||',USAGE='||USAGE||',ACTUAL='||ACTUAL||',$';
   BY SEGNO NOPRINT
   BY COLNO NOPRINT
WHERE TBNAME EQ 'aformat'
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SAVE AS Z_AMASTER
END
-RUN

TABLE FILE Z_AFORMAT
BY A10000
BY A20000
BY SALES
ON TABLE SET PAGE NOPAGE
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,SQUEEZE=ON,ORIENTATION=LANDSCAPE,HEADALIGN = BODY,$
TYPE=REPORT, FONT='ARIAL', SIZE=10, COLOR='BLACK', STYLE=NORMAL, $
TYPE=TITLE,  FONT='ARIAL NARROW', COLOR='WHITE', STYLE=BOLD, JUSTIFY=CENTER, BACKCOLOR=RGB(102 102 102),$
TYPE=DATA, COLUMN=Z_A10000, JUSTIFY=CENTER, COLOR=RED, $
ENDSTYLE
END

T

Thanks to all your reply and suggestions

I used Tony's way, achieved in different method.

I find the data's which are starting with "A" then am replacing in to another character to load as column and again revert it back for showing the proper title in the same column.

Thanks,
Dev