Can anyone help me in converting the following report into pdf format with the box around it?

-SET &ECHO=ALL;
TABLE FILE EDUCFILE
PRINT COURSE_CODE
BY EMP_ID
ON TABLE HOLD AS HOLD01
END
DEFINE FILE HOLD01
YCOURSE_CODE/I8 = EDIT(COURSE_CODE);
XCOURSE_CODE/D8c = YCOURSE_CODE;
WCOURSE_CODE/A8 = FTOA(XCOURSE_CODE, '(D8c)', 'A8');
ZCOURSE_CODE/A8 = LJUST(8, WCOURSE_CODE, 'A8');
CONCAT_COURSE/A200 = IF EMP_ID EQ LAST EMP_ID
THEN (SUBSTR(200, CONCAT_COURSE, 1, ARGLEN(200, CONCAT_COURSE, 'I4'), ARGLEN(200, CONCAT_COURSE, 'I4'), 'A190')
|| '-' || ZCOURSE_CODE) ELSE ZCOURSE_CODE;
END
TABLE FILE HOLD01
SUM CONCAT_COURSE AS 'course'
BY EMP_ID AS 'Employee'
ON TABLE SUBHEAD
""
ON TABLE SUBFOOT
""
ON TABLE SET PAGE NOPAGE
ON TABLE HOLD FORMAT HTMTABLE
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TITLE, FONT='ARIAL', SIZE=9, STYLE=-UNDERLINE+BOLD, $
TYPE=TITLE, COLUMN=P1, CLASS=t1Border, $
TYPE=TITLE, COLUMN=P2, CLASS=t2Border, $
TYPE=DATA, COLUMN=P1, CLASS=d1Border, $
TYPE=DATA, COLUMN=P2, CLASS=d2Border, $
TYPE=TABFOOTING, ITEM=1, CLASS=tBorder, $
TYPE=TABFOOTING, ITEM=2, CLASS=tBorder, $
END
-RUN

-HTMLFORM BEGIN
style type="text/css">
table { border-collapse: collapse; font-size: 8pt; font-family: tahoma, verdana, arial; width: 100%;}
td {border: 0px; }
.t1Border { width: 12%; border-top: 1px solid black; border-bottom: 1px solid black; border-left : 1px solid black; font-weight: bold; padding-left: 6px; padding-right: 6px; text-align: right; }
.t2Border { width: 85%; border-top: 1px solid black; border-bottom: 1px solid black; border-right: 1px solid black; border-left: 1px solid black; font-weight: bold; padding-left: 6px; padding-right: 6px; }
.d1Border { width: 12%; border-left : 1px solid black; padding-left: 6px; padding-right: 6px; text-align: right;}
.d2Border { width: 85%; border-left : 1px solid black; border-right: 1px solid black; padding-left: 6px; padding-right: 6px; }
.tBorder { border-top : 1px solid black; }
/style>
!IBI.FIL.HOLD;
-HTMLFORM END

Could anyone please suggest me some idea to draw a box around a report in pdf format?

Here is a sample that Robert Palmer and Peter Azzarello from the Toronto office helped me setup. This creates a frame style report and you can control the number of lines per page.

DEFINE FILE CAR

LINECOUNTER/I5 WITH SALES=IF LINECOUNTER LT 8 THEN LINECOUNTER+1 ELSE 1;
PAGECOUNTER/I5 WITH SALES=IF LINECOUNTER EQ 7 THEN PAGECOUNTER+1 ELSE PAGECOUNTER;

END
TABLE FILE CAR
SUM
CNT.SALES
BY PAGECOUNTER NOPRINT
PRINT
COUNTRY
CAR
MODEL
SALES

COMPUTE COUNTER/I5=IF PAGECOUNTER EQ LAST PAGECOUNTER THEN COUNTER+1 ELSE 1;

BY PAGECOUNTER NOPRINT
BY SALES

ON PAGECOUNTER PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
TYPE=REPORT,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
RIGHTGAP=0.125000,
TOPGAP=0.013889,
BOTTOMGAP=0.027778,
$
TYPE=DATA,
BORDER-LEFT=LIGHT,
BORDER-RIGHT=LIGHT,
$
TYPE=DATA,
BORDER-BOTTOM=LIGHT,
WHEN=COUNTER EQ CNT.SALES,
$
TYPE=TITLE,
BORDER=LIGHT,
STYLE=BOLD,
$
TYPE=TABHEADING,
SIZE=12,
STYLE=BOLD,
$
TYPE=TABFOOTING,
SIZE=12,
STYLE=BOLD,
$
TYPE=HEADING,
SIZE=12,
STYLE=BOLD,
$

ENDSTYLE
END
-* File BOXRPT.fex


Cheers

Jayem Nolan
Montreal.

Thanks a lot Jayem.. This gives me something to start with..You have a gr8 weekend.