Please give me solution for graph to use NOPRINT command in BY Field. NOPRINT Column should not display in Graph X-Axis.Also I have to pass that noprint column to drilldown report.here is my example
Eg: GRAPH FILE EMPDATA
SUM
SALARY
BY EMPDATA.EMPDATA.DIV NOPRINT
BY EMPDATA.EMPDATA.JOBCLASS
ON GRAPH SET LOOKGRAPH VBAR2AX
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET GRMERGE ON
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO ON
ON GRAPH SET GRID ON
ON GRAPH SET VAXIS 490
ON GRAPH SET HAXIS 850
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET STYLE *
PAGESIZE='Letter',
LEFTMARGIN=0.00000,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='SansSerif',
SIZE=10,
BACKCOLOR=RGB(255 255 255),
STYLE=NORMAL,
$
TYPE=DATA,
COLUMN=N3,
TARGET=_self,
FOCEXEC=app_drill1.fex(JOBCLASS= JOBCLASS DIV= DIV),
ENDSTYLE
END

This Column BY DIV NOPRINT

This message has been edited. Last edited by: PRAKASH N V,

NOPRINT is not supported on BY fields in GRAPH requests (It is coming soon).

The only thing you can currently do is generate your own labels and include them in the API styling.

There are plenty of posts on the issue. Search for them

You can still do the graph just break the process into two steps..
eg.
SUM SALARY
BY EMPDATA.EMPDATA.DIV NOPRINT
BY EMPDATA.EMPDATA.JOBCLASS
ON TABLE HOLD AS FRED
END
GRAPH FILE FRED
PRINT SALARY
BY JOBCLASS
...rest of graph..

Good suggestions, but what Prakash did not clearly pointed out is why he wants to have the two by fields in the selection.

In one of the last lines of his coding he has a drill down to an other fex where he gives the two values JOBCLASS and DIV as variables to the next process.

If that is the reason for the hidden BY field the problem is still not solved.

Is it Prakash?

I Added the closing '$' just before the ENDSTYLE and a heading line to show different execution results

HEADING
"&DATEMTDYY @ &TOD FOR &|JOBCLASS: &JOBCLASS &|DIV: &DIV"

And it works... and passes the DIV as well. Isn't that what you're looking for?

Is it Prakash - from NJ Spirit 2007?

The issue as I understand it is that the label on the ordinal axis are coming out as

CE:019PTA, CE:019PUA, CE:019PVB etc.

When what he wants to see is

019PTA, 019PUA, 019PVB

The only way that you can do that at the moment is to generate your own labels for the API

TABLE FILE EMPDATA
SUM
COMPUTE COUNTER/I2=LAST COUNTER +1; NOPRINT
-* you must subtract 1 from the counter as java counts from 0
COMPUTE GPOS/I2= COUNTER -1; NOPRINT
COMPUTE LABELTEXT/A80='setGroupLabel('||EDIT(GPOS)||',"'||JOBCLASS||'");';
BY EMPDATA.EMPDATA.DIV NOPRINT
BY EMPDATA.EMPDATA.JOBCLASS NOPRINT
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SAVE AS DATALABEL
END
-RUN
GRAPH FILE EMPDATA
SUM
SALARY
BY EMPDATA.EMPDATA.DIV NOPRINT AS ''
BY EMPDATA.EMPDATA.JOBCLASS AS 'Job class'
ON GRAPH SET LOOKGRAPH VBAR2AX
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET GRMERGE ON
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO ON
ON GRAPH SET GRID ON
ON GRAPH SET VAXIS 490
ON GRAPH SET HAXIS 850
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET GRAPHSTYLE *
-INCLUDE DATALABEL
ENDSTYLE
ON TABLE SET STYLE *
PAGESIZE='Letter',
LEFTMARGIN=0.00000,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='SansSerif',
SIZE=10,
BACKCOLOR=RGB(255 255 255),
STYLE=NORMAL,
$
TYPE=DATA,
COLUMN=N3,
TARGET=_self,
FOCEXEC=app_drill1.fex(JOBCLASS= JOBCLASS DIV= DIV),$
ENDSTYLE
END

Thanks JG, GeraldCohen, FrankDutch, Doug For your reply.As per my requirement, i got exact solution from JG Code.Thanks once again to all.

Prakash,

If your problem is indeed solved, please edit your topic to show it has been solved by putting in the keyword [SOLVED].

Thanks,

Hi

I am able to see the post

Thanks
Pugalendhi.R