Focal Point Banner
Community Center Education Summit Technical Support User Groups
Let's Get Social!

Facebook Twitter LinkedIn YouTube
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED]Only show a border after the last over field
Go
New
Search
Notify
Tools
Reply
  
[SOLVED]Only show a border after the last over field
 Login/Join
 
Guru
posted
  
TABLE FILE CAR
SUM
     SEATS AS 'Seat' OVER
     CAR.BODY.RETAIL_COST AS 'RCost' OVER
     CAR.BODY.DEALER_COST AS 'DCost'
BY  CAR
ACROSS COUNTRY AS '' ACROSS-TOTAL AS 'Total'
ON TABLE SUBHEAD
"Format test"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
 UNITS=IN,
 PAGESIZE='Letter',
 LEFTMARGIN=0.100000,
 RIGHTMARGIN=0.100000,
 TOPMARGIN=0.010000,
 BOTTOMMARGIN=0.010000,
 SQUEEZE=OFF,
 ORIENTATION=PORTRAIT,
 WRAP=OFF,
$
TYPE=REPORT,
     FONT='CALIBRI',
     SIZE=6,
     BACKCOLOR='NONE',
     RIGHTGAP=0.027778,
     LEFTGAP=0.027778,
     TOPGAP=0.010000,
     BOTTOMGAP=0.010000,
	 WRAP=.37,
     JUSTIFY=RIGHT,
$
TYPE=TABHEADING,
     FONT='CALIBRI',
     SIZE=6,
     BACKCOLOR='NONE',
     TOPGAP=0.010000,
     BOTTOMGAP=0.010000,
$
TYPE=REPORT,
     COLUMN=N1,
	 WRAP=.65,
$
TYPE=REPORT,
     COLUMN=N2,
	 WRAP=.85,
$
TYPE=DATA,
TOPGAP=0.01,
BOTTOMGAP=0.01,
BORDER-TOP=LIGHT,
BORDER-TOP-COLOR=RGB(219 219 219),
BORDER-BOTTOM=LIGHT,
BORDER-BOTTOM-COLOR=RGB(219 219 219),
$
ENDSTYLE
END


The above creates a border on every line. A need to only show the border after the last over field (DCOST). As well the word DCOST needs to have a border and currently it does not. I also need the entire line that contains DCOST shaded.

Fernando

This message has been edited. Last edited by: Fernando,


Prod WF 8.1.04, QA WF 8.2.03, Dev WF 8.2.03
 
Posts: 259 | Registered: October 10, 2006Reply With QuoteReport This Post
Platinum Member
posted Hide Post
This may not help, but you can add this line ...

ON CAR UNDER-LINE

which will give you a line break

Here's an example ...

TABLE FILE CAR
SUM
SEATS       AS 'Seat'  OVER
RETAIL_COST AS 'RCost' OVER
DEALER_COST AS 'DCost'
BY CAR
ACROSS COUNTRY AS '' ACROSS-TOTAL AS 'Total'
ON CAR UNDER-LINE
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE SET STYLE *
TYPE=REPORT,
     GRID=OFF,
$
ENDSTYLE
END


WebFocus 8.201M, Windows, App Studio
 
Posts: 195 | Location: Lincoln Nebraska | Registered: August 12, 2008Reply With QuoteReport This Post
Virtuoso
posted Hide Post
Don't know if it's what you are looking for, but it seems to be very close.
You need to add color as you wish, but having the border and background the same will result of not seeing the difference between both.
TABLE FILE CAR
SUM SEATS
    RETAIL_COST
    DEALER_COST
BY CAR
BY COUNTRY
ON TABLE HOLD AS EXTDATA
END
-RUN

TABLE FILE EXTDATA
SUM SEATS/D8 AS 'VALUE'
BY TOTAL COMPUTE ROWID  /I2  = 1;
BY TOTAL COMPUTE ROWTXT /A5V = 'Seat';
BY CAR
BY COUNTRY
ON TABLE HOLD AS SEAT
END
-RUN

TABLE FILE EXTDATA
SUM RETAIL_COST/D8 AS 'VALUE'
BY TOTAL COMPUTE ROWID  /I2  = 2;
BY TOTAL COMPUTE ROWTXT /A5V = 'RCost';
BY CAR
BY COUNTRY
ON TABLE HOLD AS RCOST
END
-RUN

TABLE FILE EXTDATA
SUM DEALER_COST/D8 AS 'VALUE'
BY TOTAL COMPUTE ROWID  /I2  = 3;
BY TOTAL COMPUTE ROWTXT /A5V = 'DCost';
BY CAR
BY COUNTRY
ON TABLE HOLD AS DCOST
END
-RUN

TABLE FILE SEAT
SUM VALUE
BY ROWID
BY ROWTXT
BY CAR
BY COUNTRY
ON TABLE HOLD AS RPTDATA
MORE
FILE RCOST
MORE
FILE DCOST
END
-RUN

TABLE FILE RPTDATA
SUM VALUE
BY CAR
BY ROWID  NOPRINT
BY ROWTXT AS ''
ACROSS COUNTRY AS '' ACROSS-TOTAL AS 'Total'
ON TABLE SUBHEAD
"Format test"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
 UNITS=IN,
 PAGESIZE='Letter',
 LEFTMARGIN=0.100000,
 RIGHTMARGIN=0.100000,
 TOPMARGIN=0.010000,
 BOTTOMMARGIN=0.010000,
 SQUEEZE=OFF,
 ORIENTATION=PORTRAIT,
 WRAP=OFF,
$
     DEFMACRO=DCOST_LINE,
     MACTYPE=RULE,
     WHEN=ROWID EQ 3,
$
TYPE=REPORT,
     FONT='CALIBRI',
     SIZE=6,
     BACKCOLOR='NONE',
     RIGHTGAP=0.027778,
     LEFTGAP=0.027778,
     TOPGAP=0.010000,
     BOTTOMGAP=0.010000,
	 WRAP=.37,
     JUSTIFY=RIGHT,
$
TYPE=TABHEADING,
     FONT='CALIBRI',
     SIZE=6,
     BACKCOLOR='NONE',
     TOPGAP=0.010000,
     BOTTOMGAP=0.010000,
$
TYPE=REPORT,
     COLUMN=N1,
	 WRAP=.65,
$
TYPE=REPORT,
     COLUMN=N2,
	 WRAP=.85,
$
TYPE=DATA,
     TOPGAP=0.01,
     BOTTOMGAP=0.01,
$
TYPE=DATA,
     BORDER-TOP=LIGHT,
     BORDER-TOP-COLOR=RGB(0 255 0),
     BORDER-BOTTOM=LIGHT,
     BORDER-BOTTOM-COLOR=RGB(0 255 0),
     BACKCOLOR=RGB(219 219 219),
     MACRO=DCOST_LINE,
$
TYPE=DATA,
     COLUMN=ROWTXT,
     BORDER=LIGHT,
     BORDER-COLOR=RGB(0 255 0),
     BACKCOLOR=RGB(219 219 219),
     MACRO=DCOST_LINE,
$
ENDSTYLE
END
-RUN


WF versions : Prod 8.2.0.1M gen 240, Dev 8.2.04 gen 48, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 1922 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Reply With QuoteReport This Post
Guru
posted Hide Post
Thank you jr99 and MartinY. These do what I need.

Fernando


Prod WF 8.1.04, QA WF 8.2.03, Dev WF 8.2.03
 
Posts: 259 | Registered: October 10, 2006Reply With QuoteReport This Post
  Powered by Social Strata  
 

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED]Only show a border after the last over field

Copyright © 1996-2018 Information Builders, leaders in enterprise business intelligence.