Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] EXL07 footing alignment

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] EXL07 footing alignment
 Login/Join
 
Michele Brooks
Guru
posted
I have an EXL07 report that has a footing at the bottom. I need to right justify columns 2 and 3, or align them some kind of way so that the position doesn't change when the number lengths increase or decrease. See the following Car File example. Thanks.

  


DEFINE FILE CAR
BLANK/A1 = '';
COUNTRY_CNT/I11C = IF COUNTRY EQ 'ENGLAND' THEN 1 ELSE 0;
CAR_CNT/I11C = IF CAR EQ 'JAGUAR' THEN 1 ELSE 0;
MODEL_CNT/I11C = IF MODEL IS NOT MISSING THEN 1 ELSE 0;
END
TABLE FILE CAR
HEADING CENTER
"Car File Report with footing"
""
SUM 
SALES/D20.2CM 
DEALER_COST/D20.2CM 
RETAIL_COST/D20.2CM 
COUNTRY_CNT NOPRINT
CAR_CNT NOPRINT
MODEL_CNT NOPRINT
BY BLANK NOPRINT
BY COUNTRY 
BY CAR 
BY MODEL
ON BLANK SUBFOOT
"Car Information"
"Car Sales Info<+0> ..................................................<+0><ST.SALES<+0> ...........................<+0><ST.COUNTRY_CNT"
"Car Dearler Info<+0> ..................................................<+0><ST.DEALER_COST<+0> ...........................<+0><ST.CAR_CNT"
"Car Retail Info<+0> ..................................................<+0><ST.RETAIL_COST<+0> ...........................<+0><ST.MODEL_CNT"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

-*Heading
TYPE=SUBFOOT, LINE=1, JUSTIFY=LEFT,$
-* # Sales
TYPE=SUBFOOT, LINE=2, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=2, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=2, ITEM=5, OBJECT=TEXT, COLOR=WHITE,$
-* Dealer
TYPE=SUBFOOT, LINE=3, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=3, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=3, ITEM=6, OBJECT=TEXT, COLOR=WHITE,$
-* Retail
TYPE=SUBFOOT, LINE=4, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=4, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=4, ITEM=6, OBJECT=TEXT, COLOR=WHITE,$
-*
TYPE=SUBFOOT, LINE=2, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=2, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=3, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=3, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=4, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=4, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
ENDSTYLE
END

WF App Studio 8201M, Windows 7

This message has been edited. Last edited by: FP Mod Chuck,


WF 8205, Windows 10
Oracle DBMS
EXL07/PDF Output
 
Posts: 244 | Registered: August 27, 2012Report This Post
RSquared
Guru
posted Hide Post
Try this it may work. All I did was play around with the spacing'
/*

DEFINE FILE CAR
BLANK/A1 = '';
COUNTRY_CNT/I11C = IF COUNTRY EQ 'ENGLAND' THEN 1 ELSE 0;
CAR_CNT/I11C = IF CAR EQ 'JAGUAR' THEN 1 ELSE 0;
MODEL_CNT/I11C = IF MODEL IS NOT MISSING THEN 1 ELSE 0;
END
TABLE FILE CAR
HEADING CENTER
"Car File Report with footing"
""
SUM
SALES/D20.2CM
DEALER_COST/D20.2CM
RETAIL_COST/D20.2CM
COUNTRY_CNT NOPRINT
CAR_CNT NOPRINT
MODEL_CNT NOPRINT
BY BLANK NOPRINT
BY COUNTRY
BY CAR
BY MODEL
ON BLANK SUBFOOT
"Car Information"
"Car Sales Info<+0> ...................................................<+0> ............................<+0>"Car Dearler Info<+0> ................................................<+0> ............................<+0>"Car Retail Info<+0> ..................................................<+0> ..........................<+0>ON TABLE SET PAGE-NUM OFF
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

-*Heading
TYPE=SUBFOOT, LINE=1, JUSTIFY=LEFT,$
-* # Sales
TYPE=SUBFOOT, LINE=2, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=2, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=2, ITEM=5, OBJECT=TEXT, COLOR=WHITE,$
-* Dealer
TYPE=SUBFOOT, LINE=3, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=3, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=3, ITEM=6, OBJECT=TEXT, COLOR=WHITE,$
-* Retail
TYPE=SUBFOOT, LINE=4, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=4, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=4, ITEM=6, OBJECT=TEXT, COLOR=WHITE,$
-*
TYPE=SUBFOOT, LINE=2, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=2, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=3, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=3, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=4, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=4, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
ENDSTYLE
END
/*


WF 7.6.11
Oracle
WebSphere
Windows NT-5.2 x86 32bit
 
Posts: 398 | Registered: February 04, 2008Report This Post
Michele Brooks
Guru
posted Hide Post
RSquared, thanks for the reply, but unfortunately no data displayed in the footing. I need something that will give me static positioning that will not change when the number of digits in the dollars and counts increase or decrease. This report will be run for various customers whose numbers will be different. When I ran the first customer report, I tweaked it for that customer but when I ran for another customer the numbers were not aligned. Thanks.


WF 8205, Windows 10
Oracle DBMS
EXL07/PDF Output
 
Posts: 244 | Registered: August 27, 2012Report This Post
MartinY
Virtuoso
posted Hide Post
And what about this ?
You can then adjust the width as you wish.

DEFINE FILE CAR
BLANK/A1 = '';
COUNTRY_CNT/I11C = IF COUNTRY EQ 'ENGLAND' THEN 1 ELSE 0;
CAR_CNT/I11C = IF CAR EQ 'JAGUAR' THEN 1 ELSE 0;
MODEL_CNT/I11C = IF MODEL IS NOT MISSING THEN 1 ELSE 0;
END
TABLE FILE CAR
HEADING CENTER
"Car File Report with footing"
""

SUM COMPUTE TSALES/D20.2CM = SALES; NOPRINT
    COMPUTE TDEALER_COST/D20.2CM = DEALER_COST; NOPRINT
    COMPUTE TRETAIL_COST/D20.2CM = RETAIL_COST; NOPRINT
    COMPUTE TCOUNTRY_CNT/I11C = COUNTRY_CNT; NOPRINT
    COMPUTE TCAR_CNT/I11C = CAR_CNT; NOPRINT
    COMPUTE TMODEL_CNT/I11C = MODEL_CNT; NOPRINT
BY BLANK NOPRINT

SUM 
SALES/D20.2CM 
DEALER_COST/D20.2CM 
RETAIL_COST/D20.2CM 
BY BLANK NOPRINT
BY COUNTRY 
BY CAR 
BY MODEL

FOOTING
"Car Information"
"Car Sales Info<TSALES<TCOUNTRY_CNT"
"Car Dearler Info<TDEALER_COST<TCAR_CNT"
"Car Retail Info<TRETAIL_COST<TMODEL_CNT"

ON TABLE SET PAGE-NUM OFF
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *

TYPE=FOOTING, LINE=1, JUSTIFY=LEFT, $

TYPE=FOOTING, LINE=2, OBJECT=TEXT,  ITEM=1, WIDTH=2.000, COLOR=BLACK, JUSTIFY=LEFT,  $
TYPE=FOOTING, LINE=2, OBJECT=FIELD, ITEM=1, WIDTH=2.000, COLOR=BLACK, JUSTIFY=RIGHT, $
TYPE=FOOTING, LINE=2, OBJECT=FIELD, ITEM=2, WIDTH=2.000, COLOR=BLACK, JUSTIFY=RIGHT, $

TYPE=FOOTING, LINE=3, OBJECT=TEXT,  ITEM=1, WIDTH=2.000, COLOR=BLACK, JUSTIFY=LEFT,  $
TYPE=FOOTING, LINE=3, OBJECT=FIELD, ITEM=1, WIDTH=2.000, COLOR=BLACK, JUSTIFY=RIGHT, $
TYPE=FOOTING, LINE=3, OBJECT=FIELD, ITEM=2, WIDTH=2.000, COLOR=BLACK, JUSTIFY=RIGHT, $

TYPE=FOOTING, LINE=4, OBJECT=TEXT,  ITEM=1, WIDTH=2.000, COLOR=BLACK, JUSTIFY=LEFT,  $
TYPE=FOOTING, LINE=4, OBJECT=FIELD, ITEM=1, WIDTH=2.000, COLOR=BLACK, JUSTIFY=RIGHT, $
TYPE=FOOTING, LINE=4, OBJECT=FIELD, ITEM=2, WIDTH=2.000, COLOR=BLACK, JUSTIFY=RIGHT, $

ENDSTYLE
END


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
Frans
Guru
posted Hide Post
Or if you want to allign it with another column:

DEFINE FILE CAR
BLANK/A1 = '';
COUNTRY_CNT/I11C = IF COUNTRY EQ 'ENGLAND' THEN 1 ELSE 0;
CAR_CNT/I11C = IF CAR EQ 'JAGUAR' THEN 1 ELSE 0;
MODEL_CNT/I11C = IF MODEL IS NOT MISSING THEN 1 ELSE 0;
END
TABLE FILE CAR
HEADING CENTER
"Car File Report with footing"
""
SUM 
SALES/D20.2CM 
DEALER_COST/D20.2CM 
RETAIL_COST/D20.2CM 
COUNTRY_CNT NOPRINT
CAR_CNT NOPRINT
MODEL_CNT NOPRINT
BY BLANK NOPRINT
BY COUNTRY 
BY CAR 
BY MODEL
ON BLANK SUBFOOT
"Car Information"
"Car Sales Info<+0> <ST.SALES <+0> <ST.COUNTRY_CNT"
"Car Dearler Info<+0> <ST.DEALER_COST <+0> <ST.CAR_CNT"
"Car Retail Info<+0> <ST.RETAIL_COST <+0> <ST.MODEL_CNT"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
	HEADALIGN=BODY,$
-*Heading
TYPE=SUBFOOT, LINE=1, JUSTIFY=LEFT,$
-* # Sales
TYPE=SUBFOOT, LINE=2, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=2, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=2, ITEM=5, OBJECT=TEXT, COLOR=WHITE,$
-* Dealer
TYPE=SUBFOOT, LINE=3, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=3, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=3, ITEM=6, OBJECT=TEXT, COLOR=WHITE,$
-* Retail
TYPE=SUBFOOT, LINE=4, ITEM=2, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=4, ITEM=3, OBJECT=TEXT, COLOR=WHITE,$
TYPE=SUBFOOT, LINE=4, ITEM=6, OBJECT=TEXT, COLOR=WHITE,$
-*
TYPE=SUBFOOT, LINE=2, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=2, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=3, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=3, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=4, ITEM=1, OBJECT=FIELD, JUSTIFY=RIGHT,$
TYPE=SUBFOOT, LINE=4, ITEM=2, OBJECT=FIELD, JUSTIFY=RIGHT,$
ENDSTYLE
END


Test: WF 8.2
Prod: WF 8.2
DB: Progress, REST, IBM UniVerse/UniData, SQLServer, MySQL, PostgreSQL, Oracle, Greenplum, Athena.
 
Posts: 454 | Location: Europe | Registered: February 05, 2007Report This Post
pav
Platinum Member
posted Hide Post
Add this code at bottom and adjust the colspan or the subfoot section accordingly

TYPE=SUBFOOT,HEADALIGN=BODY,$
TYPE=SUBFOOT,BY=BLANK,LINE=1,ITEM=1,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=1,ITEM=2,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=1,ITEM=3,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=1,ITEM=4,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=1,ITEM=5,COLSPAN=1,$

TYPE=SUBFOOT,BY=BLANK,LINE=2,ITEM=1,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=2,ITEM=2,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=2,ITEM=3,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=2,ITEM=4,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=2,ITEM=5,COLSPAN=1,$

TYPE=SUBFOOT,BY=BLANK,LINE=3,ITEM=1,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=3,ITEM=2,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=3,ITEM=3,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=3,ITEM=4,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=3,ITEM=5,COLSPAN=1,$

TYPE=SUBFOOT,BY=BLANK,LINE=4,ITEM=1,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=4,ITEM=2,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=4,ITEM=3,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=4,ITEM=4,COLSPAN=1,$
TYPE=SUBFOOT,BY=BLANK,LINE=4,ITEM=5,COLSPAN=1,$
 
Posts: 109 | Registered: February 02, 2016Report This Post
Michele Brooks
Guru
posted Hide Post
Thanks Frans and pav. Adding the HEADALIGN and making a few minor tweaks to the subfoot worked. Thanks to all for your replies. I will be closing this post as SOLVED. Thanks again.


WF 8205, Windows 10
Oracle DBMS
EXL07/PDF Output
 
Posts: 244 | Registered: August 27, 2012Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] EXL07 footing alignment

Copyright © 1996-2020 Information Builders