How can I wrap TABFOOTING text in PDF format:

Here is my example:

 
-SET &LONGVAR = 'FGFGHGHGHGFHGGJGHJHJHJHKHKJKJKJKJKJKJKJKJKJKJKHKJKJHKHKH' |
-               '1ABCDEFGHIJKLMNOPQRSTUVWXYZ2ABCDEFGHIJKLMNOPQRSTUVWXYZ' |
-               '3ABCDEFGHIJKLMNOPQRSTUVWXYZ4ABCDEFGHIJKLMNOPQRSTUVWXYZ' |
-               '5ABCDEFGHIJKLMNOPQRSTUVWXYZ6ABCDEFGHIJKLMNOPQRSTUVWXYZ';

TABLE FILE CAR
PRINT
CAR
BY COUNTRY

ON TABLE SUBFOOT
"&LONGVAR"

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='LEGAL',
     ORIENTATION=LANDSCAPE,
     SQUEEZE=ON, $

TYPE=TABFOOTING, FONT='ARIAL', SIZE=9, $

-* Display border around entire table footing page
TYPE=TABFOOTING, BORDER=1, $

ENDSTYLE
END

Thanks,
Sean

This message has been edited. Last edited by: Kerry,

Sean,

Create a DEFINE field instead of a Dialogue Manager field to contain the long value. It should then wrap properly.

Here is some code using the CAR file:

-SET &LONGVALU=
-'A;LDFJ ADSGJ ALJGALKSFJAJFASL ALSDF ASDFJOIWJFE ASDFLKA' |
-'AASDFLJ ASDFJ ASDFJAL ASDFJALSDFJA LAKSFJASDFJ FJ ASFJ ADFJ' |
-'FLKDF ADLKF FASLKDFJDFK AFALSKF ASDFJA ALDSF SFD DSFL; ASDF';
DEFINE FILE CAR
LONGVALU/A256=
'A;LDFJ ADSGJ ALJGALKSFJAJFASL ALSDF ASDFJOIWJFE ASDFLKA' |
'AASDFLJ ASDFJ ASDFJAL ASDFJALSDFJA LAKSFJASDFJ FJ ASFJ ADFJ' |
'FLKDF ADLKF FASLKDFJDFK AFALSKF ASDFJA ALDSF SFD DSFL; ASDF';
END
TABLE FILE CAR
PRINT CAR
BY COUNTRY
ON TABLE SUBFOOT
"The following is the DEFINE field:</1"
"<LONGVALU"
" "
"The following is the Dialogue Manager variable:</1"
"&LONGVALU"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, BORDER=MEDIUM,$
TYPE=TABFOOTING, BORDER=OFF, WRAP=7,$
ENDSTYLE
END

Mickey,

Thanks for the response!

So there aren't any settings that can be done in the style section that will handle amper variables in a generic way? I need to do this for several amper variables in many different types of reports.

Thanks,
Sean

As Mickey said, The report needs a defined field containing the text in order to wrap.

The original example with DEFINE:

-SET &LONGVAR = 'FGFGHGHGHGFHGGJGHJHJHJHKH KJKJKJKJKJKJKJKJKJKJKHKJKJHKHKH' |
-               '1ABCDEFGHIJKLMNOPQRSTUVWX YZ2ABCDEFGHIJKLMNOPQRSTUVWXYZ' |
-               '3ABCDEFGHIJKLMNOPQRSTUVWX YZ4ABCDEFGHIJKLMNOPQRSTUVWXYZ' |
-               '5ABCDEFGHIJKLMNOPQRSTUVWX YZ6ABCDEFGHIJKLMNOPQRSTUVWXYZ';


DEFINE FILE CAR
  LONGVAR/A512 = '&LONGVAR' ;
END

TABLE FILE CAR
  PRINT CAR
  BY COUNTRY
  ON TABLE SUBFOOT
    "<LONGVAR"
  ON TABLE PCHOLD FORMAT PDF

  ON TABLE SET STYLE *
    UNITS=IN,
    PAGESIZE='LEGAL',
    ORIENTATION=LANDSCAPE,
    SQUEEZE=ON, $

    TYPE=TABFOOTING, FONT='ARIAL', SIZE=9, 
    WRAP=5, GRID=ON, $
  ENDSTYLE
END

Regards,
Mikel

OK, thanks Mikel!

I guess I'll have to work with that then.

Thanks for your help guys!

Sean

Sean,

For some reason wrapping does not work for plain text in a FOOTING. This is why it needs to be a field. I'm not sure if this is a known issue or not. I don't know why it does not work with plain text but you would think that it should.

Ya, I would have thought so too Mickey. Unfortunately I have to rework a whole bunch of code just to accommodate wrapping for PDF format (I also support HTML and Excel formats). Oh well, at least there is a way to do it.

Thanks again!
Sean

quote:

I don't know why it does not work with plain text but you would think that it should.

Years later and FocalPoint pulls thru again... Thanks Guys for the good explanation...