Focal Point
[SOLVED] Conditional drill-down not working:

This topic can be found at:
https://forums.informationbuilders.com/eve/forums/a/tpc/f/7971057331/m/3817081776

July 10, 2015, 02:27 PM
CoolGuy
[SOLVED] Conditional drill-down not working:
Hey all!

I've been building out reports and graphs of late and have a certain column that displays cashier or store names that I've had a drill-down for:

Field: Cashier/Store

Record1: Amy <-- Drill 1
Record2: Sally <-- Drill 1
Record3: Bill <-- Drill 1
Record4: Tom <-- Drill 1
Record5: [Store Name] <-- Drill 1 & Drill 2
Record6: Byron <-- Drill 1
...etc...

Each record for the field above has a drill-down to another report. If I want a 2nd drill-down to show for just the [Store Name] records and not for cashiers, is that possible? If so, how is it done? Or where is some documentation where I can learn how to do such? Has anyone here done this before?

Any help is much appreciated. Thanks!

This message has been edited. Last edited by: CoolGuy,


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.
July 10, 2015, 03:36 PM
CoolGuy
So, I read the other similar thread about this, and implemented the WHEN clause within my styling as follows:

TYPE=DATA,
     COLUMN=N8,
     WHEN=N2 EQ '10982',
     FOCEXEC=IBFS:/WFC/Repository/.../Pct_of_No_Sales_to_Customers.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$


I get the functionality I was looking for sort of, but for some reason I get a drill-down for a cashier with an N2 value of '109' as well as the one for '10982'... I don't want a drill-down for that cashier taking them to the linked .fex. Does anyone know why it is acting this way? I really want the expression WHEN=N2 GT '9999' to work. This way only store #s (found in the N2 column with cashier #s) get the drill-down link. Or at least that is what I want it to be.


Thanks in advance!

This message has been edited. Last edited by: CoolGuy,


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.
July 13, 2015, 12:10 PM
CoolGuy
Hey all,

Here's a more thorough description with code dump that may help you understand my issue better. Ultimately I want the condition WHEN=N2 GT '9999' to work on the N8 column so only store #s (found in N2) get the drill-down link, not cashier #s (found in N2 as well).

I have a report that displays a given store's cashiers, and 4-week running totals of some metrics for each of those cashiers. You can then drill down on a
specific cashier and get a report that shows the same metrics (as well as some additional ones) for that cashier, but showing each of the 4 week totals
separately to see the trends. One can also drill down on each of the metrics to see that specific metric represented as a bar graph showing the 4 week
trend of that metric for that specific cashier.

What I've been trying to do is add conditional drill-downs for specific columns/metrics that only show if a certain column value meets a given condition.
I learned that you can use a WHEN= clause within your drill-down code to make the drill-down only show if it does meet the condition you give it. This
hasn't been working for me the way I thought it should be.

When I implemented WHEN=N2 EQ '10982' within the 1st specified drill-down in my code (for testing purposes), I get the drill indicators showing for the
store record with store #10982 and a cashier with the cashier #109 on N8 (it should only be visible for the '10982' record). The conditional expression I
want to work is WHEN=N2 GT '9999',. This should ensure only the store #s show this particular drill-down, and not for the cashiers' #s.
(Store #s are 5 digits long, cashier #s are 3 digits long.)

When I implement WHEN=N2 GT '9999', I get absolutely no drill downs on any N8 column data/values.
Not even the one I want to have it show on: GT '9999' or '10982', etc.

Do you guys/gals know why the conditional expression I want to use isn't working?

My code is as follows:

-* Top-level summary report that displays user-selected business week summary data for each
-* cashier within a selected account/store.  Shows the 4 week total that includes the business
-* week selected and 3 previous weeks for each cashier of their measures shown.  This report
-* allows the user to drill down by cashier and get that cashier's summarized measures from this top-level
-* report separated by each week that make up the total seen in this top-level report.  They also
-* are able to drill on metrics to get similar data displayed graphically.

-SET &ECHO = ALL;

-INCLUDE IBFS:/WFC/Repository/retail_reporting/retail_reports/user_filter.fex

-*-DEFAULTH &HIDDEN = 'Y';
-DEFAULTH &HIDDEN = 'N';
-IF &HIDDEN = 'N' THEN GOTO Wait;

-DEFAULTH &DSACCTNO = '10982';
-DEFAULTH &WEEKENDING = '20150704';

-SET &THREEWKSPREV = AYMD(&WEEKENDING.QUOTEDSTRING, -21, 'YYMD');
-SET &FRMT3WKSPRV = CHGDAT('YYMD', 'MDYY', &THREEWKSPREV, 'A10');
-SET &THWKSPRV = EDIT(&FRMT3WKSPRV, '99/99/9999');

DEFINE FILE SRPROD
RINGTIMEMIN/P11.2=SRPROD.SRPROD.SRPDRINGTIMESEC / 60;
TNDRTIMEMIN/P11.2=SRPROD.SRPROD.SRPDTENDERTIMES / 60;
SESSTIMEMIN/P11.2=SRPROD.SRPROD.SRPDSESSIONTIMESEC / 60;
IDLETIMEMIN/P11.2=SRPROD.SRPROD.SRPDIDLETIMESEC / 60;
LCKTIMEMIN/P11.2=SRPROD.SRPROD.SRPDLOCKTIMESEC / 60;
RTPERCUST/D12.2=RINGTIMEMIN / SRPROD.SRPROD.SRPDCUSTCNT;
RTPERITMSOLD/D12.2=RINGTIMEMIN / SRPROD.SRPROD.SRPDITEMSOLD;
TTPERCUST/D12.2=TNDRTIMEMIN / SRPROD.SRPROD.SRPDCUSTCNT;
TTPERITMSOLD/D12.2=TNDRTIMEMIN / SRPROD.SRPROD.SRPDITEMSOLD;
STPERCUST/D12.2=SESSTIMEMIN / SRPROD.SRPROD.SRPDCUSTCNT;
STPERITMSOLD/D12.2=SESSTIMEMIN / SRPROD.SRPROD.SRPDITEMSOLD;
ITPERCUST/D12.2=IDLETIMEMIN / SRPROD.SRPROD.SRPDCUSTCNT;
LTPERCUST/D12.2=LCKTIMEMIN / SRPROD.SRPROD.SRPDCUSTCNT;
WKEND_MDYY/MDYY=DATECVT(SRPROD.DIMDATE.WEEKENDING, 'YYMD', 'MDYY');
END
-RUN
TABLE FILE SRPROD
SUM
     SRPROD.SRPROD.SRPDCASHIERNO AS 'Cashier #'
     SRPROD.SRPROD.SRPDCUSTCNT AS 'Cstmr Cnt'
     SRPROD.SRPROD.SRPDOPENDEPTCNT AS 'Open Dept Cnt'
     SRPROD.SRPROD.SRPDKEYENTRYCNT AS 'Keyed Entry Cnt'
     SRPROD.SRPROD.SRPDVOIDAMT/P10.2M AS 'Void Amt'
     SRPROD.SRPROD.SRPDNOSALECNT AS 'No Sale Cnt'
     COMPUTE PCT_NOSALE_TO_CUST_CNT/P11.1% = ( ( SRPDNOSALECNT / SRPDCUSTCNT ) * 100 ); AS '% of No Sales,to Cstmr Cnt'
     SRPROD.SRPROD.SRPDSTORECOUPCNT AS 'Store Cpn Cnt'
     SRPROD.SRPROD.SRPDSTORECOUPAMT/P10.2M AS 'Store Cpn Amt'
BY  LOWEST SRPROD.SRPROD.SRPDCASHIERNAME AS 'Cashier'
ON TABLE SUBHEAD
"Cashier Stats - 4 Week Running Totals"
"including Week Ending &THWKSPRV to Week Ending <SRPROD.DIMDATE.WKEND_MDYY at <SRPROD.DIMSTORE.DSNAME"
WHERE ( SRPROD.DIMSTORE.DSACCTNO EQ &DSACCTNO.(FIND SRPROD.DIMSTORE.DSACCTNO IN SRPROD).DSACCTNO:. );
WHERE ( SRPROD.DIMDATE.WEEKENDING GE '&THREEWKSPREV');
WHERE ( SRPROD.DIMDATE.WEEKENDING LE '&WEEKENDING');
ON TABLE SET AUTOFIT ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     LINES-PER-PAGE=UNLIMITED,
$
TYPE=DATA,
     COLUMN=N8,
-*	 WHEN=N2 GT '9999',
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Pct_of_No_Sales_to_Customers.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
     TARGET='_self',
$
TYPE=DATA,
     COLUMN=N10,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Store_Cpn_Amt_By_Cashier.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=DATA,
     COLUMN=N6,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Void_Amt_By_Cashier.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=DATA,
     COLUMN=N9,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Store_Cpn_Cnt_By_Cashier.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=DATA,
     COLUMN=N5,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Keyed_Entry_By_Cashier.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=DATA,
     COLUMN=N4,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Open_Dept_Cnt_By_Cashier.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=DATA,
     COLUMN=N7,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/No_Sale_Cnt_By_Cashier.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=DATA,
     COLUMN=N1,
     FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Reports/Cashier_Trending_Drilldown.fex( \
     SRPDCASHIERNAME=N1 \
     DSACCTNO=&DSACCTNO.QUOTEDSTRING \
     WEEKENDING=&WEEKENDING.QUOTEDSTRING \
     ),
          TARGET='_self',
$
TYPE=TABHEADING,
     SIZE=14,
     STYLE=BOLD,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=3,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     SIZE=12,
     BACKCOLOR='WHITE',
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=FIELD,
     ITEM=3,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=FIELD,
     ITEM=1,
     SIZE=12,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=FIELD,
     ITEM=2,
     SIZE=12,
$
ENDSTYLE
END

-IF &HIDDEN EQ 'Y' THEN GOTO TheEnd;

-Wait

-HTMLFORM IBFS:/WFC/Repository/retail_reporting/Hidden_Content/html/PlzWaitForFilters.htm

-TheEnd



Thank you for your help!

This message has been edited. Last edited by: CoolGuy,


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.
July 13, 2015, 12:20 PM
j.gross
The displayed code is incomplete -- the spot markers in the SUBHEAD are the problem -- you need to edit your post and utilize the "code" tags to escape the <'s


- Jack Gross
WF through 8.1.05
July 13, 2015, 12:33 PM
CoolGuy
quote:
Originally posted by j.gross:
The displayed code is incomplete -- the spot markers in the SUBHEAD are the problem -- you need to edit your post and utilize the "code" tags to escape the <'s


Just fixed my post so it uses the code tags. Sorry about that.

My header displays just fine. What does that have to do with my drill links not working?

Thanks for your patience and help.


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.
July 13, 2015, 12:36 PM
j.gross
quote:
WHEN=N2 GT '9999',
What is the format of SRPROD.SRPROD.SRPDCASHIERNO (a/k/a N2)?

If it's an alpha field containing numeric characters (as your comparison to a character literal suggests), it is unlikely to ever exceed '9999' (LJSF to the field length).


- Jack Gross
WF through 8.1.05
July 13, 2015, 12:42 PM
CoolGuy
quote:
Originally posted by j.gross:
quote:
WHEN=N2 GT '9999',
What is the format of SRPROD.SRPROD.SRPDCASHIERNO (a/k/a N2)?

If it's an alpha field containing numeric characters, it is unlikely to ever exceed '9999' (LJSF to the field length).


SRPDCASHIERNO has the format A10V. Which should give it more that the 5 characters I would guess it needs to test the condition. Then again, since it's alphanumeric, does that mean I can't use that field's values in such a conditional expression because it's not strictly a numeric instead? What is LJSF?


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.
July 13, 2015, 01:23 PM
Spence
Try making N2 a BY field. That should allow the WHEN=N2 GT '9999' to work.

BY SRPROD.SRPROD.SRPDCASHIERNO NOPRINT


WF 8 version 8.2.04. Windows.
In focus since 1990.
July 13, 2015, 01:29 PM
Tom Flynn
TABLE FILE SRPROD
SUM
SRPROD.SRPROD.SRPDCASHIERNO AS 'Cashier #'
SRPROD.SRPROD.SRPDCUSTCNT AS 'Cstmr Cnt'
SRPROD.SRPROD.SRPDOPENDEPTCNT AS 'Open Dept Cnt'
SRPROD.SRPROD.SRPDKEYENTRYCNT AS 'Keyed Entry Cnt'
SRPROD.SRPROD.SRPDVOIDAMT/P10.2M AS 'Void Amt'
SRPROD.SRPROD.SRPDNOSALECNT AS 'No Sale Cnt'
COMPUTE PCT_NOSALE_TO_CUST_CNT/P11.1% = ( ( SRPDNOSALECNT / SRPDCUSTCNT ) * 100 ); AS '% of No Sales,to Cstmr Cnt'
SRPROD.SRPROD.SRPDSTORECOUPCNT AS 'Store Cpn Cnt'
SRPROD.SRPROD.SRPDSTORECOUPAMT/P10.2M AS 'Store Cpn Amt'
COMPUTE FLAG/A1 = IF SRPROD.SRPROD.SRPDCASHIERNO GT '9999' THEN 'Y' ELSE 'N'; NOPRINT
BY LOWEST SRPROD.SRPROD.SRPDCASHIERNAME AS 'Cashier'
ON TABLE SUBHEAD
"Cashier Stats - 4 Week Running Totals"
"including Week Ending &THWKSPRV to Week Ending WHERE ( SRPROD.DIMSTORE.DSACCTNO EQ &DSACCTNO.(FIND SRPROD.DIMSTORE.DSACCTNO IN SRPROD).DSACCTNO:. );
WHERE ( SRPROD.DIMDATE.WEEKENDING GE '&THREEWKSPREV');
WHERE ( SRPROD.DIMDATE.WEEKENDING LE '&WEEKENDING');
ON TABLE SET AUTOFIT ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
LINES-PER-PAGE=UNLIMITED,
$
TYPE=DATA,
COLUMN=N8,
WHEN=FLAG EQ 'Y',
FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Pct_of_No_Sales_to_Customers.fex( \
SRPDCASHIERNAME=N1 \
DSACCTNO=&DSACCTNO.QUOTEDSTRING \
WEEKENDING=&WEEKENDING.QUOTEDSTRING \
),
TARGET='_self',
$[/quote]


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe
July 13, 2015, 01:47 PM
j.gross
If it's an A10V, I believe it's treated as A10 for the comparison.  

In that case, the values compared are left-justified, and extended (space-filled) on the right to 10 places, -- as my "LJSF" was meant to indicate.  

Both 
     "1234"       ("1234      ") 
and 
     "12345"      ("12345     ")
are less than 
     "9999"       ("9999      "),
even though in terms of the underlying integer values,
1,234 < 9,999 < 12,345


Hence, the condition in "WHEN=N2 GT '9999'" is never satisfied.



- Jack Gross
WF through 8.1.05
July 13, 2015, 02:06 PM
CoolGuy
Spence,

That wouldn't work for what I need. Thanks though.

Tom,

Thanks for you attempt to help, but when I implement your solution it still acts as if no records match the condition and no drill indicators are present on column N8. I think Jack is on to something.

Jack,

quote:
Originally posted by j.gross:
If it's an A10V, I believe it's treated as A10 for the comparison.  

In that case, the values compared are left-justified, and extended (space-filled) on the right to 10 places, -- as my "LJSF" was meant to indicate.  

Both 
     "1234"       ("1234      ") 
and 
     "12345"      ("12345     ")
are less than 
     "9999"       ("9999      "),
even though in terms of the underlying integer values,
1,234 < 9,999 < 12,345


Hence, the condition in "WHEN=N2 GT '9999'" is never satisfied.


So, with Alpha values, the comparisons are not made with the underlying integer values, but with the ???
So, how are you seeing "12345" ("12345     ") as less that "9999" ("9999      ") again?

Sorry, I'm trying to wrap my head around what you are telling me. Thanks for your help and patience.
So, what should my WHEN clause/attribute be to get it to work?

This message has been edited. Last edited by: CoolGuy,


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.
July 13, 2015, 02:22 PM
Tom Flynn
VARCHAR columns have the length of the value at the beginning; change it:

TABLE FILE SRPROD
SUM
SRPROD.SRPROD.SRPDCASHIERNO AS 'Cashier #'
SRPROD.SRPROD.SRPDCUSTCNT AS 'Cstmr Cnt'
SRPROD.SRPROD.SRPDOPENDEPTCNT AS 'Open Dept Cnt'
SRPROD.SRPROD.SRPDKEYENTRYCNT AS 'Keyed Entry Cnt'
SRPROD.SRPROD.SRPDVOIDAMT/P10.2M AS 'Void Amt'
SRPROD.SRPROD.SRPDNOSALECNT AS 'No Sale Cnt'
COMPUTE PCT_NOSALE_TO_CUST_CNT/P11.1% = ( ( SRPDNOSALECNT / SRPDCUSTCNT ) * 100 ); AS '% of No Sales,to Cstmr Cnt'
SRPROD.SRPROD.SRPDSTORECOUPCNT AS 'Store Cpn Cnt'
SRPROD.SRPROD.SRPDSTORECOUPAMT/P10.2M AS 'Store Cpn Amt'
COMPUTE X_CASHIER/A10 = SRPROD.SRPROD.SRPDCASHIERNO; NOPRINT
COMPUTE FLAG/A1 = IF X_CASHIER GT '9999' THEN 'Y' ELSE 'N'; NOPRINT

BY LOWEST SRPROD.SRPROD.SRPDCASHIERNAME AS 'Cashier'
ON TABLE SUBHEAD
"Cashier Stats - 4 Week Running Totals"
"including Week Ending &THWKSPRV to Week Ending WHERE ( SRPROD.DIMSTORE.DSACCTNO EQ &DSACCTNO.(FIND SRPROD.DIMSTORE.DSACCTNO IN SRPROD).DSACCTNO:. );
WHERE ( SRPROD.DIMDATE.WEEKENDING GE '&THREEWKSPREV');
WHERE ( SRPROD.DIMDATE.WEEKENDING LE '&WEEKENDING');
ON TABLE SET AUTOFIT ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
LINES-PER-PAGE=UNLIMITED,
$
TYPE=DATA,
COLUMN=N8,
WHEN=FLAG EQ 'Y',
FOCEXEC=IBFS:/WFC/Repository/retail_reporting/retail_reports/Cashier_Productivity/Graphs/Pct_of_No_Sales_to_Customers.fex( \
SRPDCASHIERNAME=N1 \
DSACCTNO=&DSACCTNO.QUOTEDSTRING \
WEEKENDING=&WEEKENDING.QUOTEDSTRING \
),
TARGET='_self',
$


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe
July 13, 2015, 02:26 PM
j.gross
quote:
So, with Alpha values, the comparisons are not made with the underlying integer values, but
...character by character, starting from the left, until a pair of nonmatching characters is encountered. Since "9" > "1" (in the character collation order), the comparison to either "1234" or "12345" goes no farther than the first position, and "9999" is greater than both the others.
July 13, 2015, 02:39 PM
CoolGuy
Tom and Jack,

You guys are life savers! Thank you for your help Tom. I actually modified what you gave me a bit and got it to work finally:

  
COMPUTE X_CASHIER/I10 = EDIT(SRPROD.SRPROD.SRPDCASHIERNO); NOPRINT
COMPUTE FLAG/A1 = IF X_CASHIER GT 9999 THEN 'Y' ELSE 'N'; NOPRINT


Jack, that is very good information to know and understand! I will keep that in mind for the future! Thank you so much for sharing that.

Thank you both tons,
CoolGuy


8.2.02M (production), 8.2.02M (test), Windows 10, all outputs.