We have one PDF report that needs to be saved in 2 separate network folders. I'm trying to do it in a one-pass fex.

The folders are set up and I can save files to them, as already tested. I can't get the loop logic to work and I'm not sure why, was hoping you could help.

Since looping logic in FOCUS is new to me, I've been reading the documentation and forum posts... this was the post most recently that I modeled the logic from:
PDF with REPEAT

At the start of the fex, I declare the two network folder paths:

 
-SET &FullDate = EDIT(&YYMD, '$$999999');
APP FI PDFPOC1 DISK \\Phibuilddev1\POC\MidnightImpatientStay.pdf
APP FI PDFPOC2 DISK \\Phibuilddev1\POC\Archive\&FullDate|_MidnightImpatientStay.pdf
-RUN 

This sets the path for one PDF to be saved to a 'current' directory, and a duplicate to be saved to an 'archive' folder.

The looping logic I'm trying looks like this:

 
-**  Final Report for 212PatientDaysReport 

-SET &Cnt = 1;
-REPEAT :Loop 2 TIMES;
-SET &Compound = IF &Cnt EQ 1 THEN 'PDFPOC1' ELSE IF &Cnt NE 1 THEN 'PDFPOC2';

-:Loop
TABLE FILE 212PATDAYS1
SUM
  COMPUTE PATDAYS/D5 = PATDAYS; AS 'Month Actual'
  NumMonthlyTarget AS 'Month Target'
  MonthlyVariance AS 'Variance'
  MonthlyPercentVariance AS '% Variance'
  COMPUTE YTDPATDAYS/D5 = YTDPATDAYS; AS 'YTD Actual'
  NumYTDTarget AS 'YTD Target'
  YTDVariance AS 'Variance'
  YTDPercentVariance AS '% Variance'
  FiscalMonth AS '' NOPRINT
BY Category NOPRINT
BY Order NOPRINT
BY REGIONNAME AS ''
BY Grouper ROWS 'Adult & Peds (no Psych or Rehab)' OVER 'Adult & Peds Psych' OVER 'Adult & Peds Rehab'
   OVER 'Adult & Peds Total' OVER 'Nursery' OVER 'Grand Total'
WHERE MonthDatetime LE DT(&completeddate);
ON TABLE SAVE FORMAT PDF AS &Compound
-SET &Cnt = &Cnt + 1;
 

When the code runs, it only runs for the first SAVE location, not the second. What am I doing wrong that it's not looping through correctly?

Any help is greatly appreciated

Thanks so much

This message has been edited. Last edited by: Kerry,

Why not just use an OS command to copy the pdf document to the other location.

quote:

OS command

lol, one more thing I guess that I haven't heard of. I'll check the documentation for it then and see what I can learn.

Thanks again!

Wait, do you mean OS Command as in a FOCUS command, or were you suggesting something like an x-copy through a windows batch file?

I know I can write a .NET C# app that would do it, but we were hoping to encapuslate this completely within FOCUS so that there's one less thing to maintain when we schedule the reports.

quote:

OS Command

APP FI PDFPOC DISK \\Phibuilddev1\POC\MidnightImpatientStay.pdf
-RUN
TABLE FILE 212PATDAYS1
SUM
  COMPUTE PATDAYS/D5 = PATDAYS; AS 'Month Actual'
  NumMonthlyTarget AS 'Month Target'
  MonthlyVariance AS 'Variance'
  MonthlyPercentVariance AS '% Variance'
  COMPUTE YTDPATDAYS/D5 = YTDPATDAYS; AS 'YTD Actual'
  NumYTDTarget AS 'YTD Target'
  YTDVariance AS 'Variance'
  YTDPercentVariance AS '% Variance'
  FiscalMonth AS '' NOPRINT
BY Category NOPRINT
BY Order NOPRINT
BY REGIONNAME AS ''
BY Grouper ROWS 'Adult & Peds (no Psych or Rehab)' OVER 'Adult & Peds Psych' OVER 'Adult & Peds Rehab'
   OVER 'Adult & Peds Total' OVER 'Nursery' OVER 'Grand Total'
WHERE MonthDatetime LE DT(&completeddate);
ON TABLE HOLD AS PDFPOC FORMAT PDF
END
-RUN
! COPY \\Phibuilddev1\POC\MidnightImpatientStay.pdf \\Phibuilddev1\POC\Archive\&FullDate|_MidnightImpatientStay.pdf

This could also be done with APP commands as well.

APP MAP PDFPOC1 \\Phibuilddev1\POC
APP MAP PDFPOC2 \\Phibuilddev1\POC\Archive

APP COPYFILE PDFPOC1 MidnightImpatientStay PDF PDFPOC2 &FullDate|_MidnightImpatientStay PDF

Don't forget that, when using TABLE, the internal matrix is still available after the END statement and can still be acted upon -

APP FI PDFPOC DISK c:\ibi\apps\baseapp\pdfpoc.pdf
APP FI PDFPOC1 DISK c:\ibi\apps\baseapp\pdfpoc1.pdf
-RUN
TABLE FILE CAR
  SUM RCOST
      DCOST
   BY COUNTRY
   BY CAR
   BY MODEL
ON TABLE HOLD AS PDFPOC FORMAT PDF
END
HOLD AS PDFPOC1 FORMAT PDF
-RUN

T

Tony and Waz have expertly addressed your issue in a very efficient way.

To address a loop, -REPEAT is the "start" of the loop, the 2nd part is the "end" of the loop.

-REPEAT :loop 2 TIMES no semi-colon

So, to fix your code for future looping:

  
-SET &FullDate = EDIT(&YYMD, '$$999999');
APP FI PDFPOC1 DISK \\Phibuilddev1\POC\MidnightImpatientStay.pdf
APP FI PDFPOC2 DISK \\Phibuilddev1\POC\Archive\&FullDate|_MidnightImpatientStay.pdf
-RUN 

-**  Final Report for 212PatientDaysReport 

-SET &Cnt = 1;
-REPEAT :Loop 2 TIMES
-SET &Compound = IF &Cnt EQ 1 THEN 'PDFPOC1' ELSE 'PDFPOC2';

TABLE FILE 212PATDAYS1
SUM
  COMPUTE PATDAYS/D5 = PATDAYS; AS 'Month Actual'
  NumMonthlyTarget AS 'Month Target'
  MonthlyVariance AS 'Variance'
  MonthlyPercentVariance AS '% Variance'
  COMPUTE YTDPATDAYS/D5 = YTDPATDAYS; AS 'YTD Actual'
  NumYTDTarget AS 'YTD Target'
  YTDVariance AS 'Variance'
  YTDPercentVariance AS '% Variance'
  FiscalMonth AS '' NOPRINT
BY Category NOPRINT
BY Order NOPRINT
BY REGIONNAME AS ''
BY Grouper ROWS 'Adult & Peds (no Psych or Rehab)' OVER 'Adult & Peds Psych' OVER 'Adult & Peds Rehab'
   OVER 'Adult & Peds Total' OVER 'Nursery' OVER 'Grand Total'
WHERE MonthDatetime LE DT(&completeddate);
ON TABLE SAVE FORMAT PDF AS &Compound
END
-RUN
-SET &Cnt = &Cnt + 1;
-:Loop
-EXIT

You "may" need a fully qualified path in the APP FI command.

hth

wow, didn't know either of those options existed. I'm going to give them both a shot right now, thanks much for the responses guys!

Tom, I tested the loop syntax as well, worked just fine with that change.

Thanks much everyone, the responses helped not just fix the problem but helped with some good instruction I didn't see elsewhere when searching. Appreciate it much.

Just keep in mind that in WebFOCUS there are many ways to skin the proverbial cat.

Also keep in mind that with the loop syntax, you are processing the file twice, if it is from a large table/join structure the program will be doing a lot of work twice.

yeah, thought of that. the loop broke the compound fex anyways, so we went with the COPY command at the end of the compound and it worked fine.

Sure appreciated the help, too