Hi
While i using across iam getting space between
Column Title and Data in PDF and HTML.

How can i avoid space between Title and Data

quote:

How can i avoid space between Title and Data

I believe that WebFOCUS always assumes one line prior to data. As many have said, can you let us know which environment you are using by adding your signature.

Extra lines in headings could be due to hitting 'new line' in the GUI after the last line which results in an extra line. Is that your issue or is it just the 'standard' line.

NAG,
It is true that when you use ACROSS there will always be a space between the line of across values and the data. This is because that is where a column heading will appear should you have more than one field in your output.
However, never despair, WF always has a solution:

-DEFAULT &OUTPUT=HTML
SET HOLDLIST=PRINTONLY
TABLE FILE CAR
BY SEATS
ON TABLE SAVE
END
-RUN
-SET &MSEAT=&LINES;
DEFINE FILE CAR
-REPEAT #SEATLOOP FOR &I FROM 1 TO &MSEAT;
-READ SAVE,&SEATNUM
-SET &S.&I=&SEATNUM;
SAL&I / I6 = IF SEATS EQ &S.&I THEN SALES ELSE 0;
-#SEATLOOP
END
TABLE FILE CAR
SUM
-REPEAT #SEATREP FOR &I FROM 1 TO &MSEAT;
-SET &S0=IF &I EQ 1 THEN 'SEATS' ELSE ' ';
SAL&I AS '&S.&I'
-#SEATREP
BY COUNTRY
HEADING
"SEATS<+0 "
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT &OUTPUT
-SET &HEAD=IF &OUTPUT EQ PDF THEN 'POSITION=SAL1, JUSTIFY=RIGHT'
-                            ELSE 'COLSPAN=2, JUSTIFY=RIGHT ';
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=REPORT, HEADALIGN=BODY, $
TYPE=HEADING, LINE=1, ITEM=1, &HEAD, $
ENDSTYLE
END

Change the parameter &OUTPUT from HTML to PDF to see the different formats.

Similiar results if you just use an AS '' on your by field.

You lose the column title which is causing the space but more than likely your user will be able to determine the sort field by the data or title of the report.

NAG,

Try this right before the Table file

SET ACROSSLINE=SKIP