Hi,

My requirement is to produce multiple Excel tabs.If there are no records in one particular tab I should display "There are no records".

 

SET COMPOUND=OPEN

TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ '2';
ON TABLE PCHOLD FORMAT EXL2K
END

-IF &LINES EQ 0 THEN GOTO TABLE1 ELSE GOTO OTHERS;

-TABLE1
TABLE FILE CAR
PRINT SEATS NOPRINT
HEADING
"There are no records"
ON TABLE PCHOLD FORMAT EXL2K
END

-OTHERS
SET COMPOUND=CLOSE

TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ '6';
ON TABLE PCHOLD FORMAT EXL2K
END

-IF &LINES EQ 0 THEN GOTO TABLE2 ELSE GOTO OTHERS1;

-TABLE2

TABLE FILE CAR
PRINT SEATS NOPRINT
HEADING
"There are no records"
ON TABLE PCHOLD FORMAT EXL2K
END

-OTHERS1

-EXIT


 

Here is my code.If the first report(tab) has zero records, the message is being displayed correctly.But for the second tab,if there are zero records I don't see the second tab with the messagae.I am not sure why this is happening.where am I going wrong.Could some one help me.

Thanks

This message has been edited. Last edited by: Kerry,

Because it's a compound report, the second report closes the compound report, even though there's no data. Here is one solution - create a compound report with a dummy last report:

SET COMPOUND=OPEN
-RUN

TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ 2;
ON TABLE PCHOLD FORMAT EXL2K
END
-RUN

-IF &LINES EQ 0 THEN GOTO TABLE1 ELSE GOTO OTHERS;

-TABLE1
TABLE FILE CAR
PRINT SEATS NOPRINT
HEADING
"There are no records"
ON TABLE PCHOLD FORMAT EXL2K
END
-RUN

-OTHERS
TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ 6;
ON TABLE PCHOLD FORMAT EXL2K
END
-RUN

-IF &LINES EQ 0 THEN GOTO TABLE2 ELSE GOTO OTHERS1;

-TABLE2

TABLE FILE CAR
PRINT SEATS NOPRINT
HEADING
"There are no records"
ON TABLE PCHOLD FORMAT EXL2K
END
-RUN

-OTHERS1

SET COMPOUND=CLOSE
-RUN

TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ 999;
ON TABLE PCHOLD FORMAT EXL2K
END
-RUN

-EXIT

That was helpful.Is this the only way to do this.

I think this is the only way.

Another possible way is to add this to the top of your report

SET EMPTYREPORT = ANSI

Although it will not say "There are no records" it will just not have any data rows but keeps everything else (heading, footing, and column titles). If that would be okay for your requirement instead.

Add SET EMPTYREPORT = ON (or ANSI) and omit your branching statements.

SET EMPTYREPORT = ON

SET COMPOUND=OPEN

TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ '2';
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, FONT='Arial', SIZE=8, STYLE=NORMAL, TITLETEXT='Report 1',$
ENDSTYLE
END

TABLE FILE CAR
PRINT SEATS NOPRINT
HEADING
"There are no records"
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, FONT='Arial', SIZE=8, STYLE=NORMAL, TITLETEXT='Empty 1',$
ENDSTYLE
END

TABLE FILE CAR
PRINT SEATS
WHERE SEATS EQ '6';
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, FONT='Arial', SIZE=8, STYLE=NORMAL, TITLETEXT='Report 2',$
ENDSTYLE
END

SET COMPOUND=CLOSE

TABLE FILE CAR
PRINT SEATS NOPRINT
HEADING
"There are no records"
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, FONT='Arial', SIZE=8, STYLE=NORMAL, TITLETEXT='Empty 2',$
ENDSTYLE
END

quote:

SET EMPTYREPORT = ANSI

SET EMPTYREPORT = ANSI

That did it for me.. thanks a lot