Hello,

I need to use the subtotal values calculated in the subfoot for some further calculations.
Can the subtotal values be stored in a temporary variable to be used further.

Sample Code:

TABLE FILE CAR
PRINT 
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR     
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal DC: <ST.CAR.BODY.DEALER_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal RC: <ST.CAR.BODY.RETAIL_COST "
ON TABLE NOTOTAL
END

I need the subtotal values of Dealer_cost and Retail_cost to calculate some other values, and display in the subfoot.

Thanks,

This message has been edited. Last edited by: Kerry,

To get the values into variables, you'd have to do a separate pass of the data first. Here's one way without variables.

 
TABLE FILE CAR
SUM CAR.BODY.DEALER_COST NOPRINT
    CAR.BODY.RETAIL_COST NOPRINT
COMPUTE DCTOT/I9C = CAR.BODY.DEALER_COST; NOPRINT
COMPUTE RCTOT/I9C = CAR.BODY.RETAIL_COST; NOPRINT
COMPUTE DIFF/I9C = C2-C1; NOPRINT
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
PRINT 
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR     
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal DC: <ST.CAR.BODY.DEALER_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal RC: <ST.CAR.BODY.RETAIL_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal Diff: <ST.DIFF "
ON TABLE NOTOTAL
END
 

Hello Microfich,

The code is working for addition and subtraction of C1 and C2.
I need ((C1/C2)*100).
When I put the formula in the code, I get a wrong answer.

TABLE FILE CAR
SUM CAR.BODY.DEALER_COST NOPRINT
    CAR.BODY.RETAIL_COST NOPRINT
COMPUTE DCTOT/D12.2 = CAR.BODY.DEALER_COST; NOPRINT
COMPUTE RCTOT/D12.2= CAR.BODY.RETAIL_COST; NOPRINT
COMPUTE DIFF/D12.2 = ((C2/C1)*100); NOPRINT
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
PRINT 
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR     
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal DC: <ST.CAR.BODY.DEALER_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal RC: <ST.CAR.BODY.RETAIL_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal Diff: <ST.DIFF "
ON TABLE NOTOTAL
END  

I do not understand why the formula is failing.

Thanks,

I assume that If all of the subtotal values along with the ones you want to calculate happen at the same "break level" as you have 2 SUBFOOT on the same field (COUNTRY) then RECAP may come in handy:

TABLE FILE CAR
PRINT 
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR     
ON CAR.ORIGIN.COUNTRY RECAP
ST_DC_RC/D20.2 = CAR.BODY.DEALER_COST + CAR.BODY.RETAIL_COST;
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal DC: <ST.CAR.BODY.DEALER_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal RC: <ST.CAR.BODY.RETAIL_COST "
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal All: <ST_DC_RC" 
ON TABLE NOTOTAL
END

Or a bit simpler:

TABLE FILE CAR
PRINT 
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
BY  CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR     
ON CAR.ORIGIN.COUNTRY RECAP
ST_DC_RC/D20.2 = CAR.BODY.DEALER_COST + CAR.BODY.RETAIL_COST;
ON CAR.ORIGIN.COUNTRY SUBFOOT
"Subtotal DC: <ST.CAR.BODY.DEALER_COST "
"Subtotal RC: <ST.CAR.BODY.RETAIL_COST "
"Subtotal All: <ST_DC_RC" 
ON TABLE NOTOTAL
END

Oh well, I didn't see your last message about (C2/C1) * 100 but that's a very easy one to make in the RECAP section ...

...
ON CAR.ORIGIN.COUNTRY RECAP
ST_DC_RC/D20.2 = (CAR.BODY.RETAIL_COST / CAR.BODY.DEALER_COST) * 100;
...

Thanks a lot njsden,

My issue is fixed.

Great! You're welcome.

It would be helpful if you please edited the title of your original post prefixing it with [SOLVED] so we know it's done and that no extra support is needed on that one.