I have a class assigned to a table cell that formats the background of the cell with a graphic. When I add a FOCEXEC it is applying the same class to the element. Here is what it looks like

<td class="pgout"><a class="pgout" href="http://www....">Click Me</a></td>

How do I prevent the same class that is being applied to the table cell from being applied to the link element?

Thanks for the help!!!!

This message has been edited. Last edited by: Kerry,

Jenny,

How is the link being built? If it is with drill down you could try applying a different class to it in the stylesheet.

Fernando

Fernando,
We applied a different class to it and it is duplicating the class information. IN the "view Source" it shows like this.

  
</TABLE></TD></TR>
<TR>
<TD CLASS='siginfo'>
<A class='siginfo' HREF="/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps&IBIC_server=EDASERVE&IBIWF_msgviewer=OFF&&IBIMR_drill=X,portalyb/portalyb.htm&IBIF_ex=app/cust0026&CLICKED_ON=&JOBNO=8070550&JVERSN=A&CMPCOD=TXT&FORMNO=1&SIDE=A">Flat 001A<span class="compincomp"> Cmpl 4 /1 </span>  <span class="pdfcredit">PDF Earned</span></A>
</TD>
<TD CLASS='pgbackRow1'>
<span class="pgnumber">1     </span> <span class="pgclr">BW</span></TD>

In the actual source it looks like this.

 
TYPE=DATA,
	COLUMN=N1,
	WHEN=PDFCREDIT NE 'Y',
	 CLASS=siginfo,
          FOCEXEC=app/cust0026(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE),
$ 

When I made the class ' ' instead of siginfo it did not duplicate it but created a default class of 'X3' Any ideas?

 
</TABLE></TD></TR>
<TR>
<TD class='x3'>
<A HREF="/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps&IBIC_server=EDASERVE&IBIWF_msgviewer=OFF&&IBIMR_drill=X,portalyb/portalyb.htm&IBIF_ex=app/cust0026&CLICKED_ON=&JOBNO=8070550&JVERSN=A&CMPCOD=TXT&FORMNO=1&SIDE=A">Flat 001A<span class="compincomp"> Cmpl 4 /1 </span>  <span class="pdfcredit">PDF Earned</span></A>
</TD>
<TD CLASS='pgbackRow1'>
<span class="pgnumber">1     </span> <span class="pgclr">BW</span></TD>
 

Jen,

What happens if have this?

  
TYPE=DATA,
	COLUMN=N1,
	 CLASS=otherclass,
$ 
TYPE=DATA,
	COLUMN=N1,
	WHEN=PDFCREDIT NE 'Y',
	 CLASS=siginfo,
          FOCEXEC=app/cust0026(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE),
$ 

Fernando

it still shows the same information as above. No changes.

 
</TABLE></TD></TR>
<TR>
<TD CLASS='siginfo'>
<A class='siginfo' HREF="/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps&IBIC_server=EDASERVE&IBIWF_msgviewer=OFF&&IBIMR_drill=X,portalyb/portalyb.htm&IBIF_ex=app/cust0026&CLICKED_ON=&JOBNO=8070550&JVERSN=A&CMPCOD=TXT&FORMNO=1&SIDE=A">Flat 001A<span class="compincomp"> Cmpl 4 /1 </span>  <span class="pdfcredit">PDF Earned</span></A>
</TD>
<TD CLASS='pgbackRow1'>
<span class="pgnumber">1     </span> <span class="pgclr">BW</span></TD>
 

Have you tried specifying the anchor selector in the css stylesheet, I would hope this overrides anything that WebFOCUS does:

a { color:#FFFF00; }

Maybe I should elaborate on this and give some background. I have a report that shows a bucket with parts received for that bucket as an across row. There can never be more than 8 parts per bucket. The bucket parts have an image imposed on each of them depending on which event has happened according to the external style sheet. EX part not received grey raised box, part received tan flat box, part proof sent purple flat box, part proof received green flat box, each of these parts can have a different image imposed on it. The layout is fine and the buckets and parts are coming up correctly, however when I try to add a link to the bucket part, the layout scewes and adds an extra line, when you look at the view source, the above happens. You get the class doubled.

Since I am relatively new to CSS and in the infant stage of learning, can you explain what you mean by what you wrote below? It is flagging way over my head. I have a hand on it but not much more. I know enough about style sheets to be real dangerous. I am also working with a web developer on the css part so he knows parts of that but no web focus and I am the opposite.

Please explain this:
"Have you tried specifying the anchor selector in the css stylesheet, I would hope this overrides anything that WebFOCUS does:
a { color:#FFFF00; }"

<td class="pgout"><a class="pgout" href="http://www....">Click Me</a></td>

Jen, before I answer your question, could you please elaborate on how the above code is created? Do you have a fex with a TABLE FILE and a COMPUTE or DEFINE statement to generate the link (the < a ) ?

Something like this:

TABLE FILE CAR
PRINT
COMPUTE
LINK1/A100 = '<A CLASS="PGOUT" HREF="HTTP://WWW....">CLICK ME</A>';
BY COUNTRY
END

By the way, the x3 class is generated when you have SET HTMLCSS=ON. I wouldn't have HTMLCSS ON and also use CLASS tags in my WebFOCUS stylesheet - one or the other, but not both.

This information will not solve the problem though.

This fex does not produce a class on the link:

TABLE FILE CAR
SUM
SALES
BY COUNTRY

ON TABLE HOLD AS H001 FORMAT HTMTABLE

ON TABLE SET STYLE *
TYPE=DATA,
  COLUMN=N1,
  CLASS=otherclass,
$
TYPE=DATA,
  COLUMN=N1,
  WHEN=COUNTRY NE 'ENGLAND',
  CLASS=siginfo,
  FOCEXEC=app/cust0026(COUNTRY=COUNTRY),
$
ENDSTYLE
END
-RUN

-HTMLFORM BEGIN
<HTML>
<HEAD>
<STYLE TYPE="TEXT/CSS">
.otherclass { font-family: Arial, sans-serif; font-weight: normal; color: navy; padding: 10px; }
.siginfo    { font-family: Arial, sans-serif; font-weight: normal; color: green; padding: 2px; }
</STYLE>
</HEAD>
<BODY>
!IBI.FIL.H001;
</BODY>
</HTML>
-HTMLFORM END

We need to know how your link is being created.

Sorry for the delay, I was up to my eyeballs in fun stuff! Here is a copy of the code on how this is built. Hope it helsp. By the way the HTMLCSS=ON was on. I removed it and as you said "no difference".

-*
DEFINE FILE JBMSTR0A5
 CMP_MONTH/M = CMPLDATE;
 CMP_DAY/D = CMPLDATE;
 CMPMO/A2 = EDIT(CMP_MONTH,'99$');
 CMPDA/A2 = EDIT(CMP_DAY, '99$');
 CMPM/A2 = TRIM('L', CMPMO, 2, '0', 1, 'A2');
 CMPD/A2 = TRIM('L', CMPDA, 2, '0', 1, 'A2');
 CMPLETE/A45 = IF (CMPLDATE NE '') THEN ('<span class="compincomp">' | 'Cmpl ' |CMPM | '/' | CMPD | '</span>') ELSE '<span class="compincomp">' | ' '| '</span>';
 PDFSTATS/A66 = ('<span class="pdfcredit">' | ' ' |PDFCREDIT | '</span>');
 FORMNUMB/A5 = EDIT(FORMNO, '$$999');
 FORMN/A5 = TRIM('L', FORMNUMB, 5, '0', 1, 'A5');
 FORM_SIDE/A15 = FORMNUMB | ' ' | SIDE;
 PGIMPNUM/A6 = EDIT(PGIMP#, '$$$999');
 PGIMP/A6 = TRIM('L', PGIMPNUM, 6, '0', 1, 'A6');
 ORGPNUM/A4 = EDIT(ORGPRT, '$999');
 ORGP/A4 = TRIM('L', ORGPNUM, 4, '0', 1, 'A4');
 FORMSIDE/A125 = 'Flat ' |EDIT(FORMNO, '$$999') | SIDE | CMPLETE | PDFSTATS;
 PAGECOLOR/A95 =  '<span class="pgnumber">' | PGIMP | '</span>'| ' ' | '<span class="pgclr">' | COLOR | '</span>';
 PRF_STS/A10 = IF PFBKDATE NE '' THEN 'PB' ELSE IF PFOUTDATE NE '' THEN 'PO' ELSE '';
 -*PRFSTATUS/A45 = '<span class="pb">' | PRF_STS | '</span>';
 PRFSTATUS/A45 = '<span class="pb">' | '' | '</span>';
 REC_MONTH/M = RECVDATE;
 REC_DAY/D = RECVDATE;
 RECMO/A2 = EDIT(REC_MONTH, '99$');
 RECM/A2 = TRIM('L', RECMO, 2, '0', 1, 'A2');
 RECDA/A2 = EDIT(REC_DAY, '99$');
 RECD/A2 = TRIM('L', RECDA, 2, '0', 1, 'A2');
 RECEIVED/A6 = RECM | '/' | RECD;
 PARTREC/A90 = IF ORGPRT NE '' THEN '<span class="pgnumber">' | 'Part' | '</span>'| ' '  | '<span class="pgclr">' | ORGP | ' ' | '</span>' | RECEIVED ELSE '';
-*
PINKPG/A1   = IF PRF_STS EQ 'PO' THEN 'Y' ELSE 'N';
GREENPG/A1  = IF PRF_STS EQ 'PB' THEN 'Y' ELSE 'N';
WHITEPG/A1  = IF RECVDATE EQ '' THEN 'Y' ELSE 'N';
YELLOWPG/A1 = IF WHITEPG EQ 'N' AND PINKPG EQ 'N' AND GREENPG EQ 'N' THEN 'Y' ELSE 'N';
END
TABLE FILE JBMSTR0A5
PRINT
	 JOBNO
	 JVERSN
	 CMPCOD
	 FORMNO
	 SIDE
	 PGIMP#
	 PDFCREDIT
	RECEIVED
	PINKPG
	GREENPG
	WHITEPG
	YELLOWPG
	CMPLETE
	FORMSIDE
	PGIMP#
    JBYEAR
    JOBTYP
	CUSNM
    JOBSTS
    PARTNO
    ORGPRT
    RECVDATE
    FORMP#
    CMPLDATE
    CMPLMM
    CMPLDD
	PFOUTDATE
	PFBKDATE
	LASTPROOFOUT
	LASTPROOFBACK
    COLOR
	PAGECOLOR
	PRFSTATUS
	PARTREC
	PDFSTATS
BY FORM_SIDE
BY FORMNO
BY SIDE
WHERE JVERSN EQ 'A';
ON TABLE HOLD AS JBMSTR0A6 FORMAT ALPHA
END
-*************************************************************************************************
-*  PRINT OUT REPORT
-*************************************************************************************************
TABLE FILE JBMSTR0A6
LIST
	 JOBNO
	 JVERSN
	 CMPCOD
	 FORMNO
	 SIDE
	 PGIMP#
	RECEIVED
	PDFCREDIT
	PINKPG
	GREENPG
	WHITEPG
	YELLOWPG
	CMPLETE
	FORMSIDE
	PGIMP#
    JBYEAR
    JOBTYP
	CUSNM
    JOBSTS
    PARTNO
    ORGPRT
    RECVDATE
    FORMP#
    CMPLDATE
    CMPLMM
    CMPLDD
	PFOUTDATE
	PFBKDATE
	LASTPROOFOUT
	LASTPROOFBACK
    COLOR
	PAGECOLOR
	PRFSTATUS
	PARTREC
	PDFSTATS
BY FORM_SIDE
BY FORMNO
BY SIDE
ON TABLE HOLD AS ALLPAGES
END
-RUN
-* ALL DATA IS CORRECT TO HERE
-*
?FF ALLPAGES
-RUN
-*
DEFINE FILE ALLPAGES
 ACROSS_KEY/I5 = LIST;
 END
TABLE FILE ALLPAGES
PRINT
	 JOBNO
	 JVERSN
	 CMPCOD
	 FORMNO
	 SIDE
	 PGIMP#
	PDFCREDIT
	CUSNM AS ''
	PDFSTATS AS ''
    PAGECOLOR AS ''
    PRFSTATUS AS ''
	PARTREC AS ''
	SIDE AS ''
	PINKPG AS ''
	GREENPG AS ''
	WHITEPG AS ''
	YELLOWPG AS ''
BY FORMSIDE AS ''
BY ACROSS_KEY AS ''
ON TABLE HOLD AS ALLPAGE FORMAT ALPHA
END
-RUN
?FF ALLPAGE
-*
DEFINE FILE ALLPAGE
	LEGEND/A700 =
'<div class="legend">'|
'<table>'|
'<tr>'|
'<td class="siginfo">Report Legend</td>'|
'<td class="legendpagenotrecv"><span class="legendtext">Page Not<br/>'|
'  Received</span></td>'|
'<td class="legendpagerecv"><span class="legendtext">Page Received</span></td>'|
'<td class="legendpgout"><span class="legendtext">'|
'  Proofs Sent to School</span></td>'|
'<td class="legendpgback"><span class="legendtext">'|
'  Proofs Back to Walsworth</span></td>'|
'<td class="legendtextcodes">BW = Black and White<br/>'|
'SP  = Spot Color'|
'</td>'|
'<td class="legendtextcodes">4C = Four Color<br/>'|
'4S = Four Color Plus Spot'|
'</td>'|
'<td class="legendtextcodes">Date = Page received<br/>'|
'Part  = Set of proofs'|
'</td>'|
'</tr>'|
'</table>  '|
'</div>';
END
-*
TABLE FILE ALLPAGE
SUM
     PAGECOLOR AS '' OVER
     PRFSTATUS AS '' OVER
     PARTREC AS '' OVER
     SIDE AS ''
     PINKPG NOPRINT
     GREENPG NOPRINT
     WHITEPG NOPRINT
     YELLOWPG NOPRINT
	 JOBNO NOPRINT
	 JVERSN NOPRINT
	 CMPCOD NOPRINT
	 FORMNO NOPRINT
	 SIDE NOPRINT
	 PGIMP# NOPRINT
	PDFCREDIT NOPRINT
BY FORMSIDE AS ''
ACROSS ACROSS_KEY NOPRINT
HEADING
"<CUSNM"
"<LEGEND"
"Please be aware that this report will be updated within three working days of receipt of your pages."
FOOTING
"Please be aware that this report will be updated within three working days of receipt of your pages."
"<LEGEND"
ON TABLE NOTOTAL
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
	CSSURL=/approot/baseapp/pgstatus.css,
$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=1, SIZE=12,  STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=HEADING, LINE=3, OBJECT=TEXT, ITEM=1, SIZE=10,  STYLE=BOLD, JUSTIFY=CENTER,$
     DEFMACRO=COND0001,
     MACTYPE=RULE,
     WHEN=N9 EQ 'Y',
$
     DEFMACRO=COND0002,
     MACTYPE=RULE,
     WHEN=N6 EQ 'Y',
$
     DEFMACRO=COND0003,
     MACTYPE=RULE,
     WHEN=N7 EQ 'Y',
$
     DEFMACRO=COND0004,
     MACTYPE=RULE,
     WHEN=N8 EQ 'Y',
$
     DEFMACRO=COND0005,
     MACTYPE=RULE,
     WHEN=N5 EQ 'A',
$
     DEFMACRO=COND0006,
     MACTYPE=RULE,
     WHEN=N5 EQ 'B',
$
     DEFMACRO=COND0007,
     MACTYPE=RULE,
     WHEN=N9 EQ ' ',
$
TYPE=DATA,
	COLUMN=N1,
	WHEN=PDFCREDIT EQ 'Y',
	 CLASS=siginfo,
     DRILLMENUITEM='Page Information',
          FOCEXEC=app/cust0026(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE),
     DRILLMENUITEM='PDF Credit',
               FOCEXEC=app/cust0025(JOBNO=JOBNO JVERSN=JVERSN),
$
TYPE=DATA,
	COLUMN=N1,
	WHEN=PDFCREDIT NE 'Y',
	 CLASS=siginfo,
          FOCEXEC=app/cust0026(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE),
$
TYPE=DATA,
	ACROSSCOLUMN=N1,
	 CLASS=siginfo,
-*     FOCEXEC=app/cust0024(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE PGIMP#=PGIMP#),
$
TYPE=DATA,
	ACROSSCOLUMN=N2,
	 CLASS=siginfo,
-*     FOCEXEC=app/cust0024(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE PGIMP#=PGIMP#),
$
TYPE=DATA,
	ACROSSCOLUMN=N3,
	 CLASS=siginfo,
-*     FOCEXEC=app/cust0024(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE PGIMP#=PGIMP#),
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
	 COLUMN=PAGECOLOR,
	 CLASS=pgrecvRow1,
     MACRO=COND0001,
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
	 COLUMN=PAGECOLOR,
	 CLASS=pgoutRow1,
     MACRO=COND0002,
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
	 COLUMN=PAGECOLOR,
	 CLASS=pgbackRow1,
     MACRO=COND0003,
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
	 COLUMN=PAGECOLOR,
	 CLASS=pgnotrecvRow1,
     MACRO=COND0004,
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
	 COLUMN=PAGECOLOR,
	 CLASS=pgemptyRow1,
     MACRO=COND0007,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=pgrecvRow2,
     MACRO=COND0001,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=pgoutRow2,
     MACRO=COND0002,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=pgbackRow2,
     MACRO=COND0003,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=pgnotrecvRow2,
     MACRO=COND0004,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=pgemptyRow2,
     MACRO=COND0007,
$
TYPE=DATA,
     ACROSSCOLUMN=N3,
	 COLUMN=PAGECOLOR,
	 CLASS=pgrecvRow3,
     MACRO=COND0001,
$
TYPE=DATA,
     ACROSSCOLUMN=N3,
	 COLUMN=PAGECOLOR,
	 CLASS=pgoutRow3,
     MACRO=COND0002,
$
TYPE=DATA,
     ACROSSCOLUMN=N3,
	 COLUMN=PAGECOLOR,
	 CLASS=pgbackRow3,
     MACRO=COND0003,
$
TYPE=DATA,
     ACROSSCOLUMN=N3,
	 COLUMN=PAGECOLOR,
	 CLASS=pgnotrecvRow3,
     MACRO=COND0004,
$
TYPE=DATA,
     ACROSSCOLUMN=N3,
	 COLUMN=PAGECOLOR,
	 CLASS=pgemptyRow3,
     MACRO=COND0007,
$
TYPE=DATA,
     ACROSSCOLUMN=N4,
	 COLUMN=PAGECOLOR,
	 CLASS=sidea,
     MACRO=COND0005,
$
TYPE=DATA,
     ACROSSCOLUMN=N4,
	 COLUMN=PAGECOLOR,
	 CLASS=sideb,
     MACRO=COND0006,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=sidea,
     MACRO=COND0007,
$
TYPE=DATA,
     ACROSSCOLUMN=N2,
	 COLUMN=PAGECOLOR,
	 CLASS=sideb,
     MACRO=COND0007,
$
TYPE=REPORT,
     COLUMN=N6,
     WRAP=8.000000,
$
TYPE=FOOTING, LINE=1, OBJECT=TEXT, ITEM=1, SIZE=10,  STYLE=BOLD, JUSTIFY=CENTER,
$
ENDSTYLE
END
-EXIT  

!

It might be a bit easier for all concerned (including yourself) if you created a simplified program that generates the same problem. This code is a little difficult to wade through.

that is the big problem, it is not a simple program. Never can it just be simple. let me see what I can do.

I guess to just simply answer your question, the link is just a normal link. When the code is generated as you click run, the extra class='siginfo' is added to the line. The actual code that builds the line is

 
TYPE=DATA,
	COLUMN=N1,
	WHEN=PDFCREDIT NE 'Y',
	 CLASS=siginfo,
          FOCEXEC=app/cust0026(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE),
$ 

When it generates the code it looks like this:

 <TD CLASS='siginfo'>
<A class='siginfo' HREF="/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps&IBIC_server=EDASERVE&IBIWF_msgviewer=OFF&&IBIMR_drill=X,portalyb/portalyb.htm&IBIF_ex=app/cust0026&CLICKED_ON=&JOBNO=8070550&JVERSN=A&CMPCOD=TXT&FORMNO=1&SIDE=A">Flat 001A<span class="compincomp"> Cmpl 4 /1 </span>  <span class="pdfcredit">PDF Earned</span></A>
</TD>
 

Does that help or make sense?

Jen,

I did definitely see this part of the program.

Here's a program where the problem does not occur:

TABLE FILE CAR
SUM
SALES
BY COUNTRY
ACROSS SEATS
-*ON TABLE SET HTMLCSS ON
ON TABLE HOLD AS H001 FORMAT HTMTABLE

ON TABLE SET STYLE *
TYPE=DATA,
  COLUMN=N1,
  CLASS=otherclass,
$
TYPE=DATA,
  COLUMN=N1,
  WHEN=COUNTRY EQ 'ENGLAND',
  CLASS=siginfo,
  DRILLMENUITEM='Page Information',
    FOCEXEC=app/cust0026(COUNTRY=COUNTRY),
  DRILLMENUITEM='PDF Credit',
    FOCEXEC=app/cust0025(COUNTRY=COUNTRY),
$

TYPE=DATA,
  COLUMN=N1,
  WHEN=COUNTRY NE 'ENGLAND',
  CLASS=siginfo,
  FOCEXEC=app/cust0026(COUNTRY=COUNTRY),
$
ENDSTYLE
END
-RUN

-HTMLFORM BEGIN
<HTML>
<HEAD>
<STYLE TYPE="TEXT/CSS">
.otherclass { font-family: Arial, sans-serif; font-weight: normal; color: navy; padding: 10px; }
.siginfo    { font-family: Arial, sans-serif; font-weight: normal; color: green; padding: 2px; }
</STYLE>
</HEAD>
<BODY>
!IBI.FIL.H001;
</BODY>
</HTML>
-HTMLFORM END

Here's a program where the problem does occur:

TABLE FILE CAR
SUM
SALES
BY COUNTRY
ACROSS SEATS
-*ON TABLE SET HTMLCSS ON

ON TABLE SET STYLE *

TYPE=REPORT,
  CSSURL=/approot/testfm/link1.css, $

TYPE=DATA,
  COLUMN=N1,
  CLASS=otherclass,
$
TYPE=DATA,
  COLUMN=N1,
  WHEN=COUNTRY EQ 'ENGLAND',
  CLASS=siginfo,
  DRILLMENUITEM='Page Information',
    FOCEXEC=app/cust0026(COUNTRY=COUNTRY),
  DRILLMENUITEM='PDF Credit',
    FOCEXEC=app/cust0025(COUNTRY=COUNTRY),
$

TYPE=DATA,
  COLUMN=N1,
  WHEN=COUNTRY NE 'ENGLAND',
  CLASS=siginfo,
  FOCEXEC=app/cust0026(COUNTRY=COUNTRY),
$
ENDSTYLE
END
-RUN

It seems like the problem occurs when one uses CSSURL and where the report is NOT saved as a HTMTABLE which is then displayed in an HTMLFORM.

I think I would open a case with IBI - you could reference this FocalPoint thread.

You could try my first method shown above - using a Hold file and HTMTABLE, but it probably cannot be reproduced from the Dev Studio GUI.

Francis,

Jen supplied the code on how this was created right towards the beginning (3rd post) -

TYPE=DATA,
	COLUMN=N1,
	WHEN=PDFCREDIT NE 'Y',
	 CLASS=siginfo,
          FOCEXEC=app/cust0026(JOBNO=JOBNO JVERSN=JVERSN CMPCOD=CMPCOD FORMNO=FORMNO SIDE=SIDE),
$

As for HTMLCSS=ON, I always use it as it can reduce the code size significantly on larger reports by using reuseable styling code (as you are aware). If you combine it with class statements in your WF styling the WF is clever enough not to overwrite your class statements with those it creates such as x1, x2 etc.

However, perhaps it is trying to be too clever by repeating the class statements in both the TD and A tags

T

I will try that and let you know what happens. I don't use the Dev Studio GUI interface unless necessary. Our stuff is most often more complicated than the tools will allow. (Sorry IBI!)

Jen,

I would try using the method I suggested - using a HOLD file and HTMTABLE and not using the CSSURL tag.

Tony,

I can't see how turning HTMLCSS ON while also using a CSS style sheet reduces the code size of the report. If you use css classes in the WebFOCUS stylesheet for all the components of the report, what would be the need for HTMLCSS ON?

Regards,

Because you might have styling that is not covered by your CSS file, and yes, folks do that albiet unintentionally, but they do it.

And generally, it doesn't hurt not to.

Finally, some sites have it turned on in site profiles (oh yes).

T

Tony,

Thanks for the pointers. I think Susannah may have recently found out that using a CSS style-sheet along with HTMLCSS turned on caused a problem, but I do see your point.

Cheers,