Can anyone explain why the % data format does not work with PCT.CNT. but ti does with PCT.

TABLE FILE CAR

SUM
PCT.DEALER_COST/D12.2%
PCT.CNT.DEALER_COST/D12.2%
BY COUNTRY
END

WebFOCUS version is 7.1.3 on Windows Server

I can not explain why, you can not change it at all, it acts like a by field

try this.

TABLE FILE CAR
SUM 
PCT.DEALER_COST/D12.2%
PCT.CNT.DEALER_COST  (NOPRINT)
COMPUTE PCNT/D8.1%=PCT.CNT.DEALER_COST;
BY COUNTRY
END

Try using an Fn.n% field. An F format is large enough to display any percentage values and only takes half the internal storage of a D type field.

This works in R714 and R760.

TABLE FILE CAR
SUM
DEALER_COST
PCT.DEALER_COST/D12.2%
CNT.DEALER_COST
PCT.CNT.DEALER_COST/F6.2%
BY COUNTRY
END

Karen,
Thanks, it works but it does not explain why the D format works for PCT. but not for PCT.CNT.
Greg

It has to do with the internal format that is used by the pct.cnt. It works a little differently than pct.

Here is some more information on it.

http://techsupport.informationbuilders.com/tech/cof/cof_faq_004.html

Hi Greg,

The reason it doesn't work is that, the two functions are preformed, the first is the CNT then PCT and it loses the % on the second. The answer provided is the best way to accomplish this.

Hope this helps.

Cheers,

Kerry

This looks more like a bug to me. Not only does the '%' get lost when you try to reformat on the fly to a D12.1%, the significant digits do not change either. In the following example I try to reformat on the fly to show only one significant digit. Notice the reformat to D12.1% still shows 2 digits and does not have the '%'.

DEFINE FILE CAR
DEALER_PCT/D12.2%=DEALER_COST;
END
TABLE FILE CAR
SUM

CNT.DEALER_COST AS 'CNT.DEALER_COST' OVER
PCT.DEALER_COST AS 'PCT.DEALER_COST' OVER
PCT.CNT.DEALER_COST AS 'PCT.CNT.DEALER_COST' OVER
PCT.DEALER_COST/F6.1% AS 'PCT.DEALER_COST,MAKE F6.1%' OVER
PCT.DEALER_COST/D12.1% AS 'PCT.DEALER_COST,MAKE D12.1%' OVER
PCT.CNT.DEALER_COST/F6.1% AS 'PCT.CNT.DEALER_COST,MAKE F6.1%' OVER
PCT.CNT.DEALER_COST/D12.1% AS 'PCT.CNT.DEALER_COST,MAKE D12.1%' OVER

CNT.DEALER_PCT AS 'CNT.DEALER_PCT' OVER
PCT.DEALER_PCT AS 'PCT.DEALER_PCT' OVER
PCT.DEALER_PCT/F6.1% AS 'PCT.DEALER_PCT,MAKE F6.1%' OVER
PCT.DEALER_PCT/D12.1% AS 'PCT.DEALER_PCT,MAKE D12.1%' OVER
PCT.CNT.DEALER_PCT AS 'PCT.CNT.DEALER_PCT' OVER
PCT.CNT.DEALER_PCT/F6.1% AS 'PCT.CNT.DEALER_PCT,MAKE F6.1%' OVER
PCT.CNT.DEALER_PCT/D12.1% AS 'PCT.CNT.DEALER_PCT,MAKE D12.1%'

BY COUNTRY
END