Hi ALL,

I want to read the CRJOINTYPE(JOIN type) values from Master File.

please suggest.

This message has been edited. Last edited by: FP Mod Chuck,

Go to textview?

Is this for a Program or just to have a look ?

Hi Veeramani

First of all welcome to Focal Point. I think you will find it very useful for getting answers to your development questions.

If you want to read this information with a WF program there is a table called syscolumn which contains the information you are looking for. The master file can be found in the ibi\srv81\home\catalog directory. You can set a WHERE statement to select on TBNAME.

Hope this helps.

Dear All,

Thanks for your reply.

For Example: Master File Contents are below like as,

car.mas:

FILENAME=TABLE_CURR, SUFFIX=SQLDBC , $
SEGMENT=2020_CURR, SEGTYPE=S0, $
FIELDNAME=MO_NB, ALIAS=MO_NB, USAGE=I6, ACTUAL=I4, MISSING=ON, $
DEFINE COM_IND/A1=IF FIELD_SK EQ 2 THEN 'Y' ELSE 'N'; $
SEGMENT=2020_AGNT, SEGTYPE=U, SEGSUF=SQLDBC , PARENT=2020_CURR, CRJOINTYPE=LEFT_OUTER,
JOIN_WHERE=GRP_SK EQ 2020_AGNT.GRP_SK;, $
FIELDNAME=USER_ID_CD, ALIAS=USER_ID_CD, USAGE=A9, ACTUAL=A9, $
SEGMENT=ACCT_CURR, SEGTYPE=U, SEGSUF=SQLDBC , PARENT=2020_CURR, CRJOINTYPE=LEFT_OUTER,
JOIN_WHERE=2020_CURR.ACCT_NB EQ ACCT_CURR.ACCT_NB;, $

Question:
I want to read all the FILENAME, SEGMENT, PARENT, CRJOINTYPE and JOIN_WHERE metric values through fex code.
please suggest.

I'm not sure it will contain the CRJOINTYPE data, but you can probably get a lot of that info from:

CHECK FILE TABLE_CURR HOLD

TABLE FILE HOLD
PRINT *
END

quote:

CHECK FILE TABLE_CURR HOLD

TABLE FILE HOLD
PRINT *
END

Already, I tried with the above mentioned code. For CRJOINTYPE and JOIN_WHERE columns are blank. Any other way to retrieve this values?.

I suggest that you read the response from Chuck - FP Mod Chuck - above.

T

quote:

Originally posted by FP Mod Chuck:
Hi Veeramani

First of all welcome to Focal Point. I think you will find it very useful for getting answers to your development questions.

If you want to read this information with a WF program there is a table called syscolumn which contains the information you are looking for. The master file can be found in the ibi\srv81\home\catalog directory. You can set a WHERE statement to select on TBNAME.

Hope this helps.

please share the sample code. it's helps to resolve the issue.

Hi Veeramani

Here is some sample code.


DEFINE FILE SYSCOLUM
JOIN_TYPE/A20=
IF SYSCOLUM.SYSSEG.JOINTYPE EQ 'L' THEN 'Left Outer' ELSE
IF SYSCOLUM.SYSSEG.JOINTYPE EQ 'I' THEN 'Inner' ELSE 'No Join Type';
END
TABLE FILE SYSCOLUM
BY SYSCOLUM.SYSCOLUM.TBNAME
BY SYSCOLUM.SYSSEG.SEGNAME
BY SYSCOLUM.SYSSEG.JOIN_TYPE
WHERE SYSCOLUM.SYSCOLUM.TBNAME EQ '&TBNAME.(FIND SYSCOLUM.SYSCOLUM.TBNAME IN SYSCOLUM).TBNAME:.';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END


Well done Chuck.....

Hi Chuck,

Great work. Thanks a lot. I also want the field (JOIN_WHERE) which is used to join two tables.

Thanks,Veeramani

I am working on that hope to have it to you later today. It must be in a different table and I haven't located it yet

Hey Veeramani,

I think you're looking for JOIN_EXPR

TABLE FILE SYSCOLUM
BY SYSCOLUM.SYSSEG.JOIN_EXPR
END

You probably also want PARENT to show the table that originates the join.

Hope that helps.

Dan

So here is the updated code but it only works in WF 8.2 the JOIN_EXPR field does not exist in SYSCOLUMN prior to that. Thanks Dan for your input on including PARENT and finding JOIN_EXPR!


DEFINE FILE SYSCOLUM
JOIN_TYPE/A20=
IF SYSCOLUM.SYSSEG.JOINTYPE EQ 'L' THEN 'Left Outer' ELSE
IF SYSCOLUM.SYSSEG.JOINTYPE EQ 'I' THEN 'Inner' ELSE 'No Join Type';
END
TABLE FILE SYSCOLUM
BY SYSCOLUM.SYSCOLUM.TBNAME
BY SYSCOLUM.SYSSEG.SEGNAME
BY SYSCOLUM.SYSSEG.PARENT
BY SYSCOLUM.SYSSEG.JOIN_TYPE
BY SYSCOLUM.SYSSEG.JOIN_EXPR
WHERE SYSCOLUM.SYSCOLUM.TBNAME EQ '&TBNAME.(FIND SYSCOLUM.SYSCOLUM.TBNAME IN SYSCOLUM).TBNAME:.';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END


Hi Chuck,

Thanks for your help. Currently, We are using WebFOCUS 8.1.05 version. Let me check in WF8.2