I have a query that I cannot specify what fields(variable) I need to retrieve. For some of the fields that are fixed, can we use style sheet to hide it?

This message has been edited. Last edited by: Kerry,

There is a HIDE StyleSheet option, but I think it may only work for PDF (I've never used it). The NOPRINT command is another way to prevent columns from displaying.

Looks like HIDE can only be used with Active reports.

Waz, thanks for the correction.

I was only following my on suggestions.

RTFM

If it's an HTML report, then you can reference an external stylesheet:

ON TABLE SET HTMLCSS OFF
ON TABLE SET CSSURL '/approot/project/stylesheet.css'

In that stylesheet you can add a CSS class definition that says:

.hidden { display: none; }

In your report style sheet you can assign that class to a column like so:

TYPE=TITLE, COLUMN=Nx, CLASS=hidden,$
TYPE=DATA, COLUMN=Nx, CLASS=hidden,$
...etc.

You need to do this for every type of output in your stylesheet (titles, data, grand-totals if you have any, etc) that the column you want to hide crosses. It's probably going to look quite ugly in some browsers as well, table cells aren't meant to be hidden.

Dear Dan, Waz and Wep5622,

Thank you for the info. I learned a lot from your tips.

I need to create an Excel2K summary report that have row and column average. I cannot specify the fields like I normally do. I can only print * since majority of fields are variables. I now can white-out those fields I want to hide, but they still take up some space and make the report look kind of funny. That is why I am searching for style sheet solution. My code is as followed:

DEFINE FILE SLS9
Payerinfo/A120 = PAYER|'-'|PayerName;
END
-*
TABLE FILE SLS9
PRINT * Payerinfo
ON TABLE HOLD AS SLS10 FORMAT FOCUS
END
-*
JOIN CLEAR *
JOIN FILE SLS10 AT CLRYR TO MULTIPLE FILE VZT009B AT ZYEAR AS J7
WHERE SLS10.AUGDT GE VZT009B.FPDAY AND SLS10.AUGDT LE VZT009B.LPDAY;
END
-*
TABLE FILE SLS10
PRINT *
ON TABLE HOLD AS SLS11 FORMAT ALPHA
END
-*
DEFINE FILE SLS11
SUMPERIOD/A6 = IF '&MOTYPE' EQ 'C' THEN EDIT(AUGDT, '999999$$') ELSE PERIOD;
END
-*
-*
TABLE FILE SLS11
SUM CNT.SUMPERIOD NOPRINT
BY PAYER
BY SUMPERIOD
ON TABLE HOLD AS SLS12
END
-*
DEFINE FILE SLS12
PYRCNT/P13 = 1;
END
-*
TABLE FILE SLS12
SUM PYRCNT
BY PAYER
ON TABLE HOLD AS SLS13
END
-*
JOIN CLEAR *
JOIN LEFT_OUTER PAYER IN SLS11 TO PAYER IN SLS13
END
-*
DEFINE FILE SLS11
PYRCNTR/P13 = 1;
SUMPERIOD/A6 = IF '&MOTYPE' EQ 'C' THEN EDIT(AUGDT, '999999$$') ELSE PERIOD;
END
-*
TABLE FILE SLS11
PRINT * SUMPERIOD PYRCNTR
BY PERIOD
ON TABLE HOLD AS SLS14
END
-*
TABLE FILE SLS14
SUM PYRCNTR Payerinfo AS PAYER CLRDTERMDAYS AS CLRDAYS
COMPUTE CUSTAVG/P13.1 = CLRDTERMDAYS / PYRCNTR;
BY Payerinfo
BY PYRCNT
BY PERIOD
ON TABLE HOLD AS SLS15
END
-*
TABLE FILE SLS15
PRINT PYRCNT AS 'Y'
BY Payerinfo AS 'X'
ON TABLE HOLD AS SLS16
END
-*
TABLE FILE SLS15
SUM AVE.CUSTAVG AS ''
BY Payerinfo
ACROSS PERIOD AS ''
ON TABLE HOLD AS SLS17
END
-*
TABLE FILE SLS17
PRINT * ROW-TOTAL/P13.1 AS 'T'
BY Payerinfo NOPRINT
ON TABLE HOLD AS SLS18
END
-*
JOIN CLEAR *
JOIN LEFT_OUTER Payerinfo IN SLS18 TO X IN SLS16
END
-*
TABLE FILE SLS18
PRINT *
COMPUTE Customer_Avg/P13.1 = T / Y;
ON TABLE HOLD AS SLS19
END
-*
TABLE FILE SLS19
PRINT *
BY Payerinfo NOPRINT
-*
HEADING CENTER
"Medline Industries, Inc."
"Average Days to Clear For SOLD-TOs in &VRSNHDR &ACCT Summary"
"For &CALHDR Period: &STRHDATE through &ENDHDATE"
"<0> NOTE1: If an invoice is partially paid (regardless of the amount) then the entire invoice is 'cleared' in full and a residual invoice is created. This report does not include residual invoices."
"<0> NOTE2: Credits/Credit Memo transactions are also excluded."
"<0> Run Date: &RUNDATE &TOD"
"<0> Report: ar9100.fex"
"<0> Last Updated: &LastUpdate"
FOOTING
"*** End of Report ***"
-*
ON TABLE RECOMPUTE AVE. AS 'Monthly_Avg'
ON TABLE PCHOLD AS SUMRPT FORMAT EXL2K OPEN
-*
ON TABLE SET STYLE *
TYPE=REPORT, FONT='ARIEL NARROW', SIZE=8, COLOR=BLACK, BACKCOLOR=NONE, STYLE=NORMAL, WRAP=OFF, $
TYPE=REPORT, TITLETEXT='SUMMARY', $
TYPE=HEADING, FONT='TAHOMA', SIZE=10, STYLE=BOLD, COLOR=BLACK, BACKCOLOR=WHITE, $
TYPE=HEADING, FONT='TAHOMA', SIZE=10, STYLE=BOLD, COLOR=BLACK, BACKCOLOR=WHITE, $
TYPE=HEADING, LINE=6, FONT='TAHOMA', SIZE=8, STYLE=-BOLD, BACKCOLOR=WHITE, $
TYPE=HEADING, LINE=7, FONT='TAHOMA', SIZE=8, STYLE=-BOLD, BACKCOLOR=WHITE, $
TYPE=HEADING, LINE=8, FONT='TAHOMA', SIZE=8, STYLE=-BOLD, BACKCOLOR=WHITE, $
TYPE=TITLE, SIZE=9, STYLE=BOLD, BACKCOLOR=RGB(141 180 227), WRAP=ON, $
TYPE=TITLE, COLUMN=T, COLOR=RGB(141 180 227),SIZE=1, STYLE=BOLD, BACKCOLOR=RGB(141 180 227), WRAP=ON,$
TYPE=DATA, COLUMN=T, SIZE=1, COLOR=WHITE, STYLE=BOLD, WRAP=ON, $
TYPE=TITLE, COLUMN=X, COLOR=RGB(141 180 227),SIZE=1, STYLE=BOLD, BACKCOLOR=RGB(141 180 227), WRAP=ON, $
TYPE=DATA, COLUMN=X, SIZE=1, COLOR=WHITE, STYLE=BOLD, WRAP=ON, $
TYPE=TITLE, COLUMN=Y, COLOR=RGB(141 180 227),SIZE=1, STYLE=BOLD, BACKCOLOR=RGB(141 180 227), WRAP=ON, $
TYPE=DATA, COLUMN=Y, SIZE=1, COLOR=WHITE, STYLE=BOLD, WRAP=ON, $
TYPE=DATA, COLUMN=Customer_Avg, SIZE=8, COLOR=BLACK, STYLE=BOLD, WRAP=ON, $
TYPE=GRANDTOTAL, SIZE=8, STYLE=BOLD, BACKCOLOR=RGB(141 180 227), $
TYPE=GRANDTOTAL, COLUMN=T, SIZE=8, COLOR=RGB(141 180 227),STYLE=BOLD, BACKCOLOR=RGB(141 180 227), $
TYPE=GRANDTOTAL, COLUMN=Y, SIZE=8, COLOR=RGB(141 180 227),STYLE=BOLD, BACKCOLOR=RGB(141 180 227), $
TYPE=FOOTING, FONT='TAHOMA', SIZE=8, STYLE=BOLD, COLOR=BLACK, $
ENDSTYLE
END

You don't have to use PRINT *

Once you've accumulated all the possible columns (in SLS19), produce an includable ordered list (via CHECK and TABLE), limited to the desired ones, and reference that field-list, via -INCLUDE, in place of "*"

CHECK FILE SLS19 HOLD AS SLS19F
TABLEF FILE SLS19F
PRINT FIELDNAME
WHERE ... ;
ON TABLE SAVE AS SLS19I
END
-RUN <- important

and then

TABLE FILE SLS19
PRINT
-INCLUDE SLS19I
...

The WHERE clause is up to you to build, based on the run-time parameters. Take it from there.