Hi,

i want to display column total in first
like this
CAR SEATS RETAIL_COST
TOTAL 8 10
A 2 1
B 5 6
C 1 3

give any example to display in this formate
Can any one help me ...

This message has been edited. Last edited by: Kerry,

This can be doen by using the mcguyver solution
there are some examples you may find usefull

and other option is that you put the data fist in an holdfile, create a dummy with only the totals and combine that to one report.

and this is the 3e option

-* File toptotal.fex
DEFINE FILE CAR
RCOSTN/D7=IF SALES EQ 0 THEN -RCOST ELSE RCOST;
TRCOSTN/D7=RCOSTN;
TRCOST/D7=RCOST;
END
TABLE FILE CAR
SUM
     TRCOST NOPRINT
     TRCOSTN NOPRINT
BY COUNTRY AS ''
SUM
     RETAIL_COST AS ''
     RCOSTN AS ''
BY COUNTRY AS ''
BY CAR AS ''
BY BODYTYPE AS ''

ON COUNTRY SUBHEAD
"Total for <COUNTRY<TRCOST<TRCOSTN"
ON COUNTRY SUBFOOT
" "
HEADING
"Rapport met de telling boven de subset"
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=CM,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     FONT='ARIAL',
     SIZE=10,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
$
TYPE=DATA,
     BORDER=LIGHT,
     BORDER-COLOR=RGB(22 47 97),
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
     BACKCOLOR=( 'WHITE' RGB(225 225 255) ),
$
TYPE=TITLE,
     COLOR=RGB(22 47 97),
     STYLE=BOLD,
$
TYPE=TABHEADING,
     COLOR=RGB(22 47 97),
     STYLE=BOLD,
$
TYPE=TABFOOTING,
     COLOR=RGB(22 47 97),
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=12,
     COLOR=RGB(237 241 213),
     BACKCOLOR=RGB(22 47 97),
     STYLE=BOLD,
$
TYPE=FOOTING,
     SIZE=9,
     COLOR=RGB(237 241 213),
     BACKCOLOR=RGB(22 47 97),
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     SIZE=12,
     COLOR=RGB(22 47 97),
     BACKCOLOR=RGB(225 225 255),
     STYLE=BOLD,
     HEADALIGN=BODY,
$
TYPE=SUBHEAD,
     LINE=1,
     ITEM=2,
     POSITION='N3',
     JUSTIFY=LEFT,
$
TYPE=SUBHEAD,
     LINE=1,
     ITEM=3,
     POSITION='N4',
     JUSTIFY=LEFT,
$
TYPE=SUBHEAD,
     LINE=1,
     ITEM=4,
     POSITION='N5',
     JUSTIFY=RIGHT,
$
TYPE=SUBHEAD,
     LINE=1,
     ITEM=5,
     POSITION='N6',
     JUSTIFY=RIGHT,
$
TYPE=SUBFOOT,
     SIZE=9,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR='WHITE',
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     SIZE=9,
$
TYPE=ACROSSTITLE,
     COLOR=RGB(22 47 97),
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     STYLE=BOLD,
$
ENDSTYLE
END

So there are some ways to get this as wanted.

The mcguyver gives you the most flexability, but is not easy to understand

And one more option: bypass complex MacGyver techniques or multiple hold files with join/match's and instead, use Active reporting. Active reports offer an easy way to add counts and totals to the top of your report either manually when viewing the report using the Calculate option on each column or automatically through StyleSheet coding. Check out the Active reporting manual for more. This option works in Active Html, Active PDF, and FLEX output.

Or:

TABLE FILE CAR
SUM 
SEATS
RETAIL_COST
COMPUTE CAR/A16 = 'TOTAL';
COMPUTE SEQ/A1 = '0';
ON TABLE HOLD AS HTOTCAR
END

DEFINE FILE CAR
SEQ/A1 = '1';
END

TABLE FILE CAR
SUM
SEATS
RETAIL_COST
BY SEQ NOPRINT
BY CAR
MORE
FILE HTOTCAR
END

 CAR               SEATS  RETAIL_COST
 ---               -----  -----------
 TOTAL                70      173,204
 ALFA ROMEO            8       19,565
 AUDI                  5        5,970
 BMW                  29       58,762
 DATSUN                4        3,139
 JAGUAR                7       22,369
 JENSEN                4       17,850
 MASERATI              2       31,500
 PEUGEOT               5        5,610
 TOYOTA                4        3,339
 TRIUMPH               2        5,100

Or:

DEFINE FILE CAR
 BLANK/A1 = ' ';
END
-*
TABLE FILE CAR
 SUM
  SEATS
  RETAIL_COST
 BY BLANK NOPRINT
 BY CAR
 ON BLANK SUBHEAD
  "TOTAL<TOT.SEATS<TOT.RETAIL_COST"
 ON TABLE SET STYLE *
  TYPE=SUBHEAD, HEADALIGN=BODY, JUSTIFY=RIGHT, $
  TYPE=SUBHEAD, OBJECT=TEXT, JUSTIFY=LEFT, $
 ENDSTYLE
END

.. or upgrade to a newer version. Not sure which version introduced this setting

ON TABLE SET SUBTOTALS ABOVE

TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY SUBTOTAL AS 'Subtotal'
BY CAR
ON COUNTRY SUBFOOT
" "
ON TABLE SET SUBTOTALS ABOVE
ON TABLE NOTOTAL
END

interesting

never saw that

this is not working in 7.6.10

so we need to upgrade to 7.7.xxx

quote:

SET SUBTOTALS ABOVE

Yes it's a 7.7.x feature