As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only. Moving forward, myibi is our community platform to learn, share, and collaborate. We have the same Focal Point forum categories in myibi, so you can continue to have all new conversations there. If you need access to myibi, contact us at myibi@ibi.com and provide your corporate email address, company, and name.
I have a table for Store License. Table Lay out is as follows:
Store License
1 ABC
1 EDG
2 BCD
2 KJK
3 LKM
4 KJI
4 IUY
4 BUY
I Want to be able to Prsent this information as
Store
1 ABC EDG
2 BCD KJK
3 LKM
4 KJI IUY BUY
Is there a way to accomplish this?This message has been edited. Last edited by: Kerry,
Here's an example with the CAR file - I *think* you can't avoid doing it in two steps.
TABLE FILE CAR
SUM
COUNTRY NOPRINT
BY COUNTRY
BY BODYTYPE
ON TABLE HOLD AS H001
END
DEFINE FILE H001
BODYCOUNT/I4 = IF COUNTRY EQ LAST COUNTRY THEN BODYCOUNT + 1 ELSE 1;
END
TABLE FILE H001
SUM
BODYTYPE
ACROSS BODYCOUNT NOPRINT
BY COUNTRY
END
Francis
Give me code, or give me retirement. In FOCUS since 1991
Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server
The problem with the CAR table is it's a hierarchical FOCUS table so each COUNTRY only exists physically once in the top segment so the "LAST" function only sees it once and the counter doesn't work. Adding "...(IF BODYTYPE EQ LAST BODYTYPE THEN BODYCOUNT ELSE BODYCOUNT + 1) ELSE 1;" solves that.
DEFINE FILE CAR
BODYCOUNT/I4 = IF COUNTRY EQ LAST COUNTRY THEN (IF BODYTYPE EQ LAST BODYTYPE THEN BODYCOUNT ELSE BODYCOUNT + 1) ELSE 1;
END
TABLE FILE CAR
SUM BODYTYPE AS ''
ACROSS BODYCOUNT NOPRINT
BY COUNTRY AS ''
ON TABLE SET PAGE NOPAGE
END
DavidThis message has been edited. Last edited by: DavSmith,
In FOCUS since 1985 - WF 8.009/8.104 Win 8 Outputs: ALL of 'em! Adapters: Sql Server Teradata Oracle