Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only. Moving forward, myibi is our community platform to learn, share, and collaborate. We have the same Focal Point forum categories in myibi, so you can continue to have all new conversations there. If you need access to myibi, contact us at myibi@ibi.com and provide your corporate email address, company, and name.


Connect to myibi
Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Report layout painter w/Bookmarks

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] Report layout painter w/Bookmarks
 Login/Join
 
Platinum Member
posted
I am trying to create a dynamic report with bookmarks using report master layout. Unfortuantely with pdf layoutpainter I need to specify how many components I have... but I don't know how many I will have.

For example below is and example of what I need. The Car file brings back a number or cars that I a report for. But in my real case I don't know that there will be 1 or 10 rows in that file.

TABLE FILE CAR 
PRINT CAR
ON TABLE HOLD AS H1 FORMAT ALPHA
END
-RUN

-SET &CRLINES = &LINES;
-SET &CNT = 0;

-REPEAT CRLP &CRLINES TIMES
-READ H1 NOCLOSE &CAR.A16.
-SET &CAR = &CAR;
-SET &CNT=&CNT+1;

-SET &FMT = IF &CNT EQ 1 THEN 'OPEN NOBREAK' ELSE IF &CNT EQ &CRLINES THEN 'CLOSE' ELSE 'NOBREAK';

TABLE FILE CAR
PRINT 
COUNTRY
MODEL
DEALER_COST
WHERE CAR EQ '&CAR.EVAL'
ON TABLE PCHOLD FORMAT PDF &FMT
END

-CRLP



How do I make the above concatenate and spit out as one report ... the below gives me a decent output but only the first report.



SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=IN, $


OBJECT=TOC,
   NAME='Table of Contents',
   TEXT='Table of Contents',
   MARKUP=ON,
   TOC-NUMBERING=ON,
   color=RGB(0 0 0),
   size=10,
   ORIENTATION=LANDSCAPE,
   POSITION=(0.728 0.832),
   DIMENSION=(9.625 7.021),
   font='ARIAL',
 $

OBJECT=bookmarks ,$
SECTION=section1,
   LAYOUT=ON,
   MERGE=OFF,
   PAGESIZE=Letter,
   ORIENTATION=LANDSCAPE, $

PAGELAYOUT=ALL, NAME='Page Master', $
OBJECT=STRING, NAME='text3', TEXT='<font face="ARIAL" size=10> <ibi-page-number/></font>', POSITION=(5.208 8.063), MARKUP=ON, WRAP=ON, DIMENSION=(0.625 0.208),  METADATA=' OUTERHTML: <SPAN style="Z-INDEX: 100; POSITION: absolute; WIDTH: 0.625in; FONT-FAMILY: Arial; HEIGHT: 0.208in; FONT-SIZE: 10pt; TOP: 8.063in; LEFT: 5.208in" id=text3 tabIndex=9> <DIV><SPAN style="BACKGROUND-COLOR: rgb[212,208,200); WIDTH: 57px; HEIGHT: 16px" id="<ibi-page-number/>" contentEditable=false>^lt;Page #^gt;</SPAN></DIV></SPAN>', $
OBJECT=STRING, NAME='text2', TEXT=' ', POSITION=(8.958 0.354), MARKUP=ON, WRAP=ON, DIMENSION=(1.771 0.208),  METADATA=' OUTERHTML: <SPAN style="Z-INDEX: 100; POSITION: absolute; WIDTH: 1.771in; FONT-FAMILY: Arial; HEIGHT: 0.208in; FONT-SIZE: 10pt; TOP: 0.354in; LEFT: 8.958in" id=text2 tabIndex=10><DIV>Fidelity HR Services</DIV></SPAN>', $
COMPONENT='DfltCmpt1', POSITION=(0 0), DIMENSION=(0 0), $

PAGELAYOUT=1,
   NAME='Page layout 1',
   text='Page layout 1',
   TOC-LEVEL=1,
   BOTTOMMARGIN=0.5,
   TOPMARGIN=0.5,
$

COMPONENT='report1',
   TEXT='report1',
   TOC-LEVEL=2,
   POSITION=(0.729 0.874),
   DIMENSION=(* *),
$

END

SET COMPONENT='DfltCmpt1'
TABLE FILE SYSCOLUM
" "
SUM TBNAME NOPRINT
IF READLIMIT EQ 1
ON TABLE SET PREVIEW ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
END


SET COMPONENT='report1'


TABLE FILE CAR
PRINT CAR
ON TABLE HOLD AS H1 FORMAT ALPHA
END
-RUN

-SET &CRLINES = &LINES;
-SET &CNT = 0;

-REPEAT CRLP &CRLINES TIMES
-READ H1 NOCLOSE &CAR.A16.
-SET &CAR = &CAR;
-SET &CNT=&CNT+1;


TABLE FILE CAR
PRINT
COUNTRY
MODEL
DEALER_COST
WHERE CAR EQ '&CAR.EVAL'
ON TABLE PCHOLD FORMAT PDF NOBREAK
END

-CRLP

COMPOUND END




I cannot give it more components because i don't know how many there will be and in the real report the formats for displaying are different. Some outputs are text, others are tables.

Any help is much appreciated!

This message has been edited. Last edited by: Kerry,


Dev, SIT, UAT, Production:7.6.6
Dev Sandbox:7.6.11

Dev Studio - 7.6.6
 
Posts: 178 | Registered: May 11, 2005Report This Post
Platinum Member
posted Hide Post
So I was able to dynamically build the config piece... which is what I need. So now I will try it on a larger scale, but this is a solution if anyone else was needing something similar.


TABLE FILE CAR
PRINT CAR
ON TABLE HOLD AS H1 FORMAT ALPHA
END
-RUN
-SET &CRLINES = &LINES;


SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=IN, $

OBJECT=TOC,
NAME='Table of Contents',
TEXT='Table of Contents',
MARKUP=ON,
TOC-NUMBERING=ON,
color=RGB(0 0 0),
size=10,
ORIENTATION=LANDSCAPE,
POSITION=(0.728 0.832),
DIMENSION=(9.625 7.021),
font='ARIAL',
METADATA=' TOCTITLE: Table of Contents OUTERHTML: Table of Contents', $

OBJECT=bookmarks ,$
SECTION=section1,
LAYOUT=ON,
METADATA='0.5^0.5^0.5^0.5',
MERGE=OFF,
PAGESIZE=Letter,
ORIENTATION=LANDSCAPE, $

PAGELAYOUT=ALL, NAME='Page Master', $
OBJECT=IMAGE, NAME='image1', IMAGE=new_image.gif, POSITION=(0.250 0.250), DIMENSION=(1.522 0.413), METADATA='Z-INDEX: 100; POSITION: absolute; WIDTH: 1.522in; HEIGHT: 0.413in; TOP: 0.25in; LEFT: 0.25in', $
OBJECT=STRING, NAME='text3', TEXT=' ', POSITION=(5.208 8.063), MARKUP=ON, WRAP=ON, DIMENSION=(0.625 0.208), METADATA=' OUTERHTML:
^lt;Page #^gt;
', $
OBJECT=STRING, NAME='text2', TEXT='', POSITION=(8.958 0.354), MARKUP=ON, WRAP=ON, DIMENSION=(1.771 0.208), METADATA=' OUTERHTML:
', $
COMPONENT='DfltCmpt1', POSITION=(0 0), DIMENSION=(0 0), $

PAGELAYOUT=1,
NAME='report',
TEXT='report',
TOC-LEVEL=0,
BOTTOMMARGIN=0.25,
TOPMARGIN=0.25,LEFTMARGIN=0.25, RIGHTMARGIN=0.25,
METADATA='BOTTOMMARGIN=0.25,TOPMARGIN=0.25,LEFTMARGIN=0.25,RIGHTMARGIN=0.25,ORIENTATION=LANDSCAPE,',
ORIENTATION=LANDSCAPE,
$

-SET &CNT = 0;

-REPEAT CLP &CRLINES TIMES
-IF &CNT EQ 0 THEN GOTO NXTRP0;
-SET &rel = 'report'||&CNT;
-NXTRP0

-SET &CNT=&CNT+1;
-SET &rpt = 'report'||&CNT;

COMPONENT='&rpt',
TEXT='&rpt',
TOC-LEVEL=1,
-IF &CNT GT 1 THEN GOTO nxpos;
POSITION=(0.249 0.60),
-GOTO nxdim;
-nxpos
POSITION=(+0.0 +0.0),
-nxdim
DIMENSION=(* *),
-IF &CNT EQ 1 THEN GOTO NXTRP;
RELATIVE-TO='&rel', RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT,
-NXTRP
METADATA='Z-INDEX: 100; POSITION: absolute; WIDTH: 10.249in; HEIGHT: 7.437in; OVERFLOW: auto; TOP: 0.563in; LEFT: 0.249in'
,
$
-CLP

END

SET COMPONENT='DfltCmpt1'
TABLE FILE SYSCOLUM
" "
SUM TBNAME NOPRINT
IF READLIMIT EQ 1
ON TABLE SET PREVIEW ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
END

-SET &CNT = 0;

-REPEAT CRLP &CRLINES TIMES
-READ H1 NOCLOSE &CAR.A16.

-SET &CAR = &CAR;
-SET &CNT=&CNT+1;
-SET &rpt = 'report'||&CNT;
SET COMPONENT='&rpt'

TABLE FILE CAR
PRINT
COUNTRY
MODEL
DEALER_COST
WHERE CAR EQ '&CAR.EVAL'
ON TABLE PCHOLD FORMAT PDF
END

-CRLP


COMPOUND END


Dev, SIT, UAT, Production:7.6.6
Dev Sandbox:7.6.11

Dev Studio - 7.6.6
 
Posts: 178 | Registered: May 11, 2005Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Report layout painter w/Bookmarks

Copyright © 1996-2020 Information Builders