Focal Point
[CLOSED] Drilldown in FML

This topic can be found at:
https://forums.informationbuilders.com/eve/forums/a/tpc/f/7971057331/m/5297005695

January 06, 2011, 10:58 AM
richard weinbaum
[CLOSED] Drilldown in FML
I want to create drilldowns in an FML report and am having a problem The following code snipped does not create a drill down link. No error, just no drilldown. Any ideas why? Don't see ANY documentation on how to style the FOR column. Perhpas its not supported?

SUM NUMPROJ 
    DOLPROJ 
    TEST_URL1 NOPRINT
BY  AGENCY_CODE NOPRINT
FOR XRECX 
1 AS 'Projects in Original Plan'                              
.
.
ON TABLE SET PAGE TOP AND EMPTYREPORT ON AND HTMLCSS ON AND EMPTYREPORT ON
ON TABLE SET STYLE *
.
.
TYPE=DATA,COLUMN=XRECX,URL=(TEST_URL1),WRAP=4.5,WHEN=XRECX EQ '1',$

This message has been edited. Last edited by: Kerry,


WF 7.7.3
Windows 2003 Server
PDF
HTML
EXL2k
January 06, 2011, 11:26 AM
T.Peters
I've done drill down in FML , but I don't think you can drill on the FOR item itself. If you need to drill, set it up on one of the SUM items.

Example:
 TABLE FILE CAR
SUM 
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
FOR
     CAR.COMP.CAR
'ALFA ROMEO' AS 'ALFA ROMEO' LABEL R1 OVER 
'AUDI' AS 'AUDI' LABEL R2 OVER 
'BMW' AS 'BMW' LABEL R3 OVER 
'DATSUN' AS 'DATSUN' LABEL R4 OVER 
'JAGUAR' AS 'JAGUAR' LABEL R5 OVER 
'JENSEN' AS 'JENSEN' LABEL R6 OVER 
'MASERATI' AS 'MASERATI' LABEL R7 OVER 
'PEUGEOT' AS 'PEUGEOT' LABEL R8 OVER 
'TOYOTA' AS 'TOYOTA' LABEL R9 OVER 
'TRIUMPH' AS 'TRIUMPH' LABEL R10
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=DATA,
     LABEL=R3,
     COLUMN=N1,
     FOCEXEC=app/car_proc( \
     CAR=N1 \
     ),
$
ENDSTYLE
END
 



WebFOCUS: 7702
O/S : Windows
Data Migrator: 7702
January 06, 2011, 11:34 AM
Tom Flynn
  
APP PREPENDPATH IBISAMP
-RUN
-DEFAULTS &CAR = 'FOC_NONE'
TABLE FILE CAR
SUM 
     DEALER_COST
     RETAIL_COST
FOR
     CAR
'ALFA ROMEO' AS 'ALFA ROMEO' LABEL R1 OVER 
'AUDI' AS 'AUDI' LABEL R2 OVER 
'BMW' AS 'BMW' LABEL R3 OVER 
'DATSUN' AS 'DATSUN' LABEL R4 OVER 
'JAGUAR' AS 'JAGUAR' LABEL R5 OVER 
'JENSEN' AS 'JENSEN' LABEL R6 OVER 
'MASERATI' AS 'MASERATI' LABEL R7 OVER 
'PEUGEOT' AS 'PEUGEOT' LABEL R8 OVER 
'TOYOTA' AS 'TOYOTA' LABEL R9 OVER 
'TRIUMPH' AS 'TRIUMPH' LABEL R10

WHERE CAR EQ '&CAR';

ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
-*     INCLUDE = endeflt,
-*$
TYPE=DATA,
-*     LABEL=R3,
     COLUMN=N1,
     FOCEXEC=SAME_FEX_FILE( \
     CAR=N1 \
     ),
$
ENDSTYLE
END
-EXIT


Take out LABEL=R3, and, they all drill...

Although, he is using a URL, so, that would need to be shown here, between the RED </> tags...


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe
January 06, 2011, 11:57 AM
Tom Flynn
Creating Financial Reports

You'll need to log in to Tech Support...


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe
January 06, 2011, 01:10 PM
Tom Flynn
If the URL is "different" for each FOR value, then you'll need to designate each one. BUT, to do that, you need to -READ each value:

  
SUM
   TEST_URL1
 BY XRECX 
 ON TABLE HOLD FORMAT ALPHA
END
-RUN
-SET &XLINES = &LINES;
-SET &CNTR   = 0;
-REPEAT GET_URL &XLINES TIMES
-SET &CNTR = &CNTR + 1;
-READ HOLD NOCLOSE &XRECX.AXX &URL.&CNTR.AXXX
-GET_URL


So, here is a working example:

APP PREPENDPATH IBISAMP
-RUN
-SET &ECHO=ALL;

DEFINE FILE CAR
  CAR_URL/A100 = IF CAR IN ('AUDI','BMW','DATSUN','JAGUAR') THEN 'http://www.google.com' ELSE 
                                                                 'https://forums.informationbuilders.com/eve/forums'; 
END
TABLE FILE CAR
SUM
   COMPUTE XCNT/I2 = XCNT + 1;
   CAR_URL
  BY CAR NOPRINT
 ON TABLE HOLD FORMAT ALPHA
END
-RUN
-SET &XLINES = &LINES;
-SET &CNTR   = 0;
-REPEAT GET_URL &XLINES TIMES
-SET &CNTR = &CNTR + 1;
-READ HOLD NOCLOSE &XRECX.I2 &URL.&CNTR.A100
-GET_URL
-DEFAULTS &CAR = 'FOC_NONE'
TABLE FILE CAR
SUM 
     DEALER_COST
     RETAIL_COST
	  COMPUTE XRECX/I2 = XRECX + 1; NOPRINT
FOR
     CAR
'ALFA ROMEO' AS 'ALFA ROMEO' LABEL R1 OVER 
'AUDI' AS 'AUDI' LABEL R2 OVER 
'BMW' AS 'BMW' LABEL R3 OVER 
'DATSUN' AS 'DATSUN' LABEL R4 OVER 
'JAGUAR' AS 'JAGUAR' LABEL R5 OVER 
'JENSEN' AS 'JENSEN' LABEL R6 OVER 
'MASERATI' AS 'MASERATI' LABEL R7 OVER 
'PEUGEOT' AS 'PEUGEOT' LABEL R8 OVER 
'TOYOTA' AS 'TOYOTA' LABEL R9 OVER 
'TRIUMPH' AS 'TRIUMPH' LABEL R10

WHERE CAR EQ '&CAR';

ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
-SET &CNTR = 0;
-REPEAT DO_URL &XLINES TIMES
-SET &CNTR = &CNTR + 1;
-SET &X_URL = '&' || 'URL' || &CNTR ;
TYPE=DATA, WHEN=XRECX EQ &CNTR.EVAL, COLUMN=N1, WRAP=4.5,  URL=&X_URL.EVAL , $
-DO_URL

ENDSTYLE
END
-EXIT


hth


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe
January 07, 2011, 04:23 AM
<JG>
With FML put the drill on the label
January 07, 2011, 08:14 AM
Tom Flynn
Hi John,

Happy New Year!

If you have 500 rows, with BARs, BLANK Rows and RECAPs, why would you use the LABEL?

Tom


Tom Flynn
WebFOCUS 8.1.05 - PROD/QA
DB2 - AS400 - Mainframe