Hi,
I want to find out yesterdaty's date. I'm trying this code:
DEFINE FILE A2PER1
THISDATE/A8YYMD WITH PTNO = EDIT('&YYMD','99999999');
THIS_DATE/I8YYMD WITH PTNO = EDIT(THISDATE);
YESTERDAY/I8YYMD WITH PTNO = AYMD(THIS_DATE,-1,YESTERDAY);
YESTERDAY1/MDYYTR WITH PTNO = YESTERDAY;
END
and when I print the dates, it gives me blank.
Please help.

I put your code in a define against the car file and it worked just fine. I also did a less steps version straight use of smart dates.

TESTTWO/YYMD = '&YYMD';
TESTTHREE/YYMD = TESTTWO - 1;

Thanks Leah,
I tried to use your code i.e.
DEFINE FILE A2PER1 CLEAR
TESTTWO/YYMD = '&YYMD';
TESTTHREE/YYMD = TESTTWO - 1;
END
now i'm getting

DEFINE FILE A2PER1 CLEAR
TESTTWO/YYMD = '&YYMD';
(FOC177) INVALID DATE CONSTANT: ;
TESTTHREE/YYMD = TESTTWO - 1;
(FOC258) FIELDNAME OR COMPUTATIONAL ELEMENT NOT RECOGNIZED: TESTTWO
END
Please advise.

Take the quotes off &YYMD.

As always, there are multiple ways to do things like this:

-SET &YESTERDAY=AYMD(&YYMD,-1,'I8YYMD');
DEFINE FILE A2PER1 CLEAR
TESTTHREE/YYMD = &YESTERDAY;
END

Now the previous day is available to the whole fex without having to recompute it everytime it is needed.

TODAY/MDYY = &MDYY ;
YESTERDAY/MDYY = DATEADD(TODAY, 'D', -1);

quote:

now i'm getting

DEFINE FILE A2PER1 CLEAR
TESTTWO/YYMD = '&YYMD';
(FOC177) INVALID DATE CONSTANT: ;
...

How are you executing this code?

The echo of a fex would not show '&YYMD', it would list the substituted value ('20080507').

If this is executing in a context that does not recognize Dialog Manager variables (e.g. reading from std input, or executing a file via a FILEDEF ddname), the FOC177 is appropriate: the alpha expression '&YYMD' is not a valid date value.

quote:

Take the quotes off &YYMD

No, the quotes are appropriate.

You can assign a literal value to a smart date in the form of either a date literal or an integer constant representing a date offset.

After the substitution for &YYMD,

='20080507';
unambiguously provides a date value.

But
=20080507;
is ambiguous -- it can be interpreted either as a yyyymmdd date, or as an offset. -- The present behavior of Focus depends on the value: integer values that could be calendar dates are treated as date constants (as if they were quoted); otherwise the value is treated as an offset.

The range of "could be" dates is unspecified and the cutoff points are arbitrary (is 01001231 a very early date, or the offset of a far-off future date?)

-- But AFAIK the interpretation of some unquoted integer values as dates and others as offsets is undocumented, and subject to code tightening without notice.

Hi,

I used this for a similar need:

-SET &YESTER = DATECVT((DATEADD((DATECVT(&TODAY,'I8YYMD','YYMD')), 'D', -1)), 'YYMD','I8YYMD');

MYDATE/YYMD = '&YYMD' ;

should always work. E.g.

DEFINE FILE CAR
MYDATE/YYMD WITH COUNTRY = '&YYMD' ;
END
-RUN
TABLE FILE CAR
PRINT MYDATE
IF RECORDLIMIT EQ 1
END
-RUN

In your case, &YYMD seems to be garbage. Try executing with ECHO=ON.

quote:

THISDATE/A8YYMD WITH PTNO = EDIT('&YYMD','99999999');
THIS_DATE/I8YYMD WITH PTNO = EDIT(THISDATE);

Try changing it to: THIS_DATE/I8YYMD =&YYMD;