I have a sample car file request below.
I am trying to position the subtotal text under their respective columns.
For example: country subtotal column text should list under country and model subtotal text should list under text.
Is there a way to acheive this? Also, is there a way to reduce the gap between the acrosscolumn values and column title?
TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY SUBTOTAL DEALER_COST AS ' '
BY MODEL SUBTOTAL DEALER_COST AS ' '
ACROSS CAR
ON TABLE SET SUBTOTALS ABOVE
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='LETTER', SQUEEZE=ON, ORIENTATION=LANDSCAPE,$
TYPE=REPORT, FONT='VERDANA', SIZE=8,$
TYPE=TITLE, STYLE=BOLD,$
TYPE=SUBTOTAL, BACKCOLOR=RGB(234 234 234),$
TYPE=DATA,COLUMN=COUNTRY,COLOR=WHITE,$
TYPE=DATA,COLUMN=MODEL,COLOR=WHITE,#
ENDSTYLE
END
-EXIT

Please advice.

Thanks.

This message has been edited. Last edited by: ReddyP,

quote:

1. I am trying to position the subtotal text under their respective columns. For example: country subtotal column text should list under country and model subtotal text should list under text. Is there a way to acheive this?
2. Also, is there a way to reduce the gap between the acrosscolumn values and column title?

Answer to (2): No
Answer to (1): You will have to use SUBFOOT and either COLSPAN (for HTML) or POSITION (for PDF)
[Could it be that in WF8 syntax will be the same for both???]

Thank you Danny-SRL.
I cannot use SUBFOOT because I have to show subtotals across the months. If it is just one year timeframe, I could harcode it for Jan-Dec months. Since timeframe is a parameter, I will not be able to do that.
Also, subtotals need to be represented on top of the detail instead of at the bottom.

Thank you.

Hi Reddy,

Maybe a bit convoluted, but it should give you a solution.

  
-SET &ECHO=ALL;
-* File Reddy01.fex
SET ASNAMES=ON, HOLDLIST=PRINTONLY
TABLE FILE CAR
BY SEATS
ON TABLE SAVE AS SNUM
END
-RUN
-SET &SEATS=&LINES;
DEFINE FILE CAR
BODY/A12='TOTAL';
MOD/A24=' ';
RK/I7=0;
END
TABLE FILE CAR
SUM DEALER_COST AS DEALER
BY COUNTRY
BY RK
BY BODY
BY RK AS RKB
BY MOD
ACROSS SEATS
ON TABLE HOLD AS BBB FORMAT ALPHA
END
-RUN
FILEDEF BBB DISK BBB.FTM (APPEND
DEFINE FILE CAR
RKB/I7=0;
MOD/A24='TOTAL';
END
TABLE FILE CAR
SUM DEALER_COST
BY COUNTRY
RANKED BY BODYTYPE
BY RKB
BY MOD
ACROSS SEATS
ON TABLE SAVE AS BBB
END
-RUN
TABLE FILE CAR
PRINT DEALER_COST 
BY COUNTRY
RANKED BY BODYTYPE
RANKED BY MODEL
ACROSS SEATS
ON TABLE SAVE AS BBB
END
-RUN
TABLE FILE BBB
PRINT
-REPEAT #DEALERS &SEATS TIMES
-READ SNUM,&DNUM
DEALER&DNUM AS '&DNUM,SEATERS'
-#DEALERS
BY COUNTRY
BY RK NOPRINT
BY BODY AS BODYTYPE
BY RKB NOPRINT
BY MOD AS MODEL
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
INCLUDE=ENDEFLT, $
TYPE=TITLE, JUSTIFY=CENTER, $
ENDSTYLE
END

Ah, but in a senior moment I forgot our Swiss Army Knife: the ever present McGuyver!

  
JOIN BLANK WITH BODYTYPE IN CAR TO BLANK IN FSEQ AS M_
DEFINE FILE CAR
BLANK/A1 WITH BODYTYPE = ' ';
XBODY/A12=IF COUNTER EQ 1 THEN 'TOTAL' ELSE BODYTYPE;
XMOD/A24=IF COUNTER EQ 1 THEN ' ' ELSE IF COUNTER EQ 2 THEN 'TOTAL' ELSE MODEL;
NBODY/I5=IF COUNTER EQ 1 THEN 1 ELSE 2;
END
TABLE FILE CAR
SUM DEALER_COST
ACROSS SEATS
BY COUNTRY
BY NBODY NOPRINT
BY XBODY AS BODYTYPE
BY COUNTER NOPRINT
BY XMOD AS MODEL
IF COUNTER LE 3
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
INCLUDE=ENDEFLT, $
TYPE=TITLE, JUSTIFY=CENTER, $
ENDSTYLE
END

where FSEQ is the McGuyver file. Example follows:

  
Master:
FILE=FSEQ, SUFFIX=FIX, DATASET=FOCALPOINT/FSEQ.DAT, $
  SEGNAME=SEG1
   FIELD=CONTROL, BLANK , A1, A1, $
  SEGNAME=SEG2, PARENT=SEG1, OCCURS=VARIABLE
   FIELD=WHATEVER, , A1, A1, $
   FIELD=COUNTER, ORDER, I4,  I4,$

Data:
 FILEFORMCGUYVERFILEFORMCGUYVERFILEFORMCGUYVER

Notice that the first character is a space!

Thank you for the solutions.