I have read all the posts to get subtotal on one line and all the tricks with blank/a1=' ', etc. My users just want one total for the whole report (no subtotals). They want the output in exl2k. I have tried all the tricks I read about and none of them seem to work with a grand total only. If I put a subtotal in the report, then the tricks work. I've tried doing some things in the stylesheet and using on table subfoot, but I can't seem to position my amount column under the correct column in exl2k. It ignores my positioning. Here is sample code with the car file which I'm coloring to show the field, but all the stylesheet options I've tried haven't worked. Any suggestions?

TABLE FILE CAR
PRINT
COUNTRY
BODYTYPE
SALES
ON TABLE SUBFOOT
"TOTAL<+0> WHERE READLIMIT EQ 100
WHERE RECORDLIMIT EQ 100
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
LEFTMARGIN=0.250000,
RIGHTMARGIN=0.250000,
TOPMARGIN=0.250000,
BOTTOMMARGIN=0.250000,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
GRID=OFF,
FONT='TIMES NEW ROMAN',
SIZE=10,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
TYPE=TITLE,
STYLE=BOLD,
$
TYPE=TABFOOTING,
ITEM=3,
COLOR='RED',
JUSTIFY=RIGHT,
$
TYPE=HEADING,
SIZE=12,
STYLE=BOLD,
JUSTIFY=CENTER,
$
ENDSTYLE
END

webfocus 5.3.3; os: unix; solaris 2.8; pdf, html, exl2k, csv

Have you tried this

ON TABLE SUBTOTAL

yup. It put it to 2 lines. I just tried it again to confirm.

Pam,

You need to add the following to your request so that WebFOCUS knows to align the SUBFOOT text/fields in the colmns with the data.

TYPE=TABFOOTING, HEADALIGN=BODY,$

You will then need to adjust your SUBFOOT line accordingly.

It was good to meet you at Summit.

Try
ON TABLE COLUMN-TOTAL
OR

Remove ON TABLE NOTTOAL Line.

Hope this helps.

Pam,

Here's a simplier example.

TABLE FILE CAR
PRINT
COUNTRY
BODYTYPE
SALES
ON TABLE SUBFOOT
"TOTAL<+0> <TOT.SALES"
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=TABFOOTING, HEADALIGN=BODY,$
ENDSTYLE
END

Also,

ON TABLE COLUMN-TOTAL AS ''

will keep the number on one line but you will not have the word "Total" appearing on the line.

Thanks for all the suggestions. The headalign=body should work for me. I had tried headalign=internal and something else earlier today with no luck, but I didn't try the headalign=body. The body is positioning it now. My only complication is I have 3 more lines in the on table subfoot below the total that is centered across all the columns. That all got moved to the left when I did headalign=body. I'm working with the headalign=body on a bogus subfoot (i.e. blank) and leaving the 3 other lines in the on total subfoot and I think I should be able to get it to work. The business does want the word total so the on table column-total won't work this time.

Pam,

Use COLSPAN to make the other lines go across the three columns.

TABLE FILE CAR
PRINT
COUNTRY
BODYTYPE
SALES
ON TABLE SUBFOOT
"TOTAL<+0> <TOT.SALES"
"This is the second line."
"This is the third line."
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=TABFOOTING, HEADALIGN=BODY,$
TYPE=TABFOOTING, LINE=2, COLSPAN=3, JUSTIFY=CENTER,$
TYPE=TABFOOTING, LINE=3, COLSPAN=3, JUSTIFY=CENTER,$
ENDSTYLE
END

Thanks Mickey ... that worked perfectly. For some reason I only think of colspan when dealing with HTML.

Pam,

I believe this works because the format of the file that is fed to Excel is actually XML. The output of XML tends to support the HTML formatting quite a bit. However, I am no XML expert. Just trial and error.