I have a three field report, that I'm tring to display field 1 in column A, and field 2 in column B & C that have been merged together.

I've tried using the DATA type in the "ON TABLE SET STYLE *":

TYPE=DATA,COLUMN=FACILITY_NAME,OBJECT=FIELD,ITEM=1,COLSPAN=2,SIZE=12, STYLE=UNDERLINE,$

This does not work. Am I using the correct process, and/or type?

This message has been edited. Last edited by: Kerry,

As far as I know, DATA columns cannot be merged. Only items in HEADING, SUBHEAD, FOOTING and SUBFOOT can via COLSPAN=n in HTML and EXL2K.

Is there another setting that would allow for data columns to be merged?

I hate when VBA has been able to do something for years that is not possible in WebFOCUS.

quote:

I hate when VBA has been able to do something for years that is not possible in WebFOCUS

You're comparing orangutans to oranges - they have one quality in common and many that are not.

Will concatenating the data in the columns provide a solution?

DEFINE FILE CAR
 CAR_MODEL/A40 = CAR | MODEL ;
END
-*
TABLE FILE CAR
 PRINT COUNTRY CAR_MODEL
 ON TABLE PCHOLD FORMAT EXL2K
END

Concatenating the data is not the problem.

I have one field value in the data, but I need it to appear in two cells in the same row that have been merged.

Francis - I was merely trying to say that I waste a lot of time trying get WebFOCUS to do actions that are simple with VBA, but I get told that "WebFOCUS can't do that". It is not a answer that my manager or customers will accept, so I can't accept it either.

There are 2 possible solutions, neither of which is perfect.
1. Create a template
2. Use GETTOK to separate the 2 fields

Have you sent a NFR? Request a new feature from IBI.

Actually, there's a third you headings, subheadings and subfootings to print your entire report.

I'm working right now on making this a "Header Only" report to see if I can get it to work.

I agree that a NFR might eventually get the functionality into WebFOCUS, but that does not help me meet my deadline. :-)

Even when I move the fields from the DATA to a SUBFOOT, and then try to merge the cells with TYPE=SUBFOOT, it does not work.

What am I missing?

DEFINE FILE BASELINE1
LABEL1A/A50= 'a. Facility Name:';
END

TABLE FILE BASELINE1
HEADING
"I.  FACILITY"
PRINT
BASELINE1.FACILITY_NAME NOPRINT

WHERE RECORDLIMIT EQ 1

ON TABLE SUBFOOT
"<LABEL1A"

ON TABLE SET STYLE *
TYPE=HEADING,LINE=1,OBJECT=TEXT,ITEM=1,COLSPAN=6,JUSTIFY=LEFT,STYLE=BOLD,SIZE=12,BACKCOLOR=RGB(210 210 210),$
TYPE=SUBFOOT, HEADALIGN=BODY, $
TYPE=SUBFOOT,LINE=1,COLSPAN=2,$
ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

It's best TO USE subhead, but, IF subfoot is what you want:

  
-SET &ECHO=ALL;
APP PREPENDPATH IBISAMP
-RUN
SET BYDISPLAY=ON

DEFINE FILE SHORT
LABEL1A/A50 = 'a. Facility Name:';
DUMMY/A1    = ' ';
END

TABLE FILE SHORT
HEADING
"I.  FACILITY"
SUM
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS ''

BY CONTINENT NOPRINT
WHERE RECORDLIMIT EQ 1
ON CONTINENT SUBFOOT
"<LABEL1A<+0> <+0> <+0> <+0> <+0>"

ON TABLE SET STYLE *
TYPE=REPORT, HEADALIGN=BODY, COLSPAN=6,$
TYPE=HEADING,LINE=1,COLSPAN=6,JUSTIFY=LEFT,STYLE=BOLD,SIZE=12,BACKCOLOR=RGB(210 210 210),$
TYPE=SUBFOOT, HEADALIGN=BODY, $
TYPE=SUBFOOT,ITEM=1,COLSPAN=2,$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

hth

what is the <+0>?

Its's a Placeholder, identifies each cell in the row. It's called a Spot Marker...

Put an X in between instead of a space and see what it does...

Here's another example:

  
-SET &ECHO=ALL;
APP PREPENDPATH IBISAMP
-RUN
SET BYDISPLAY=ON

DEFINE FILE SHORT
LABEL1A/A50 = 'a. Facility Name:';
DUMMY/A1    = ' ';
END

TABLE FILE SHORT
HEADING
"I.  FACILITY"
SUM
    DUMMY AS '' 
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS ''
    DUMMY AS '' OVER
    DUMMY AS ''
    DUMMY AS ''
    CONTINENT AS ''
    REGION AS ''
    DUMMY AS ''
    DUMMY AS ''
BY DUMMY NOPRINT
BY CONTINENT NOPRINT
-*WHERE RECORDLIMIT EQ 1
ON DUMMY SUBHEAD
"<LABEL1A<+0> <+0> <+0> <+0> <+0>"

ON TABLE SET STYLE *
TYPE=REPORT, HEADALIGN=BODY, COLSPAN=6,$
TYPE=HEADING,LINE=1,COLSPAN=6,JUSTIFY=LEFT,STYLE=BOLD,SIZE=12,BACKCOLOR=RGB(210 210 210),$
-*TYPE=SUBFOOT, HEADALIGN=BODY, $
TYPE=DATA, HEADALIGN=BODY,$
TYPE=SUBHEAD, ITEM=1, COLSPAN=2,$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

Thank you all for your help. I'll mention to Kerry that I would love to see merged data cells as a new feature.

Here is my working code:

DEFINE FILE BASELINE1
CELLSPACER/A1= '';
LABEL1A/A50= 'a. Facility Name:';
LABEL1B/A50= 'b. CAGE Code:';
END

TABLE FILE BASELINE1
HEADING
"I.  FACILITY"
SUM
CELLSPACER AS ''

BY BASELINE1.FACILITY_NAME NOPRINT

WHERE RECORDLIMIT EQ 1

ON BASELINE1.FACILITY_NAME SUBHEAD
"<LABEL1A<+0><BASELINE1.FACILITY_NAME<+0><LABEL1B<+0><BASELINE1.FACILITY_ID<+0>"

ON TABLE SET STYLE *
TYPE=HEADING,LINE=1,OBJECT=TEXT,ITEM=1,COLSPAN=6,JUSTIFY=LEFT,STYLE=BOLD,SIZE=12,BACKCOLOR=RGB(210 210 210),$
TYPE=SUBHEAD, HEADALIGN=BODY, $
TYPE=SUBHEAD,ITEM=1,COLSPAN=1,$
TYPE=SUBHEAD,ITEM=2,COLSPAN=3,STYLE=UNDERLINE,$
TYPE=SUBHEAD,ITEM=3,COLSPAN=1,$
TYPE=SUBHEAD,ITEM=4,COLSPAN=1,STYLE=UNDERLINE,$
ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

Well Done!

BTW, that is what COLSPAN does, doubt a NFR would get worked on, BUT, no harm in trying...

This message has been edited. Last edited by: Tom Flynn,

FYI, Here is something interesting, but probably not usable.

TABLE   FILE CAR
 PRINT  COMPUTE
        Blank/A1 = ' ' ; AS ''
        SEATS
 BY     COUNTRY
 BY     CAR
 ON     TABLE SET HTMLCSS ON
 ON     TABLE SET STYLE *
  TYPE=TITLE, COLOR=NAVY, STYLE=BOLD+UNDERLINE, $
  TYPE=REPORT, TITLETEXT='Testing', $
  TYPE=DATA, COLUMN=CAR, CLASS=MERGE, $
 ENDSTYLE
 ON   TABLE HOLD AS MERGE_TEST FORMAT EXL2K
END

-RUN

FILEDEF MERGE_TEST DISK merge_test.xht

-RUN

-* Write out a master to read the MERGE_TEST list
EX -LINES 4 EDAPUT MASTER,MERGE_TEST,CV,FILE
FILENAME=MERGE_TEST, SUFFIX=FIX,$
SEGNAME=MERGE_TEST, $
  FIELD=LINE ,ALIAS=  ,A1000 ,A1000 ,$

-RUN

FILEDEF NEW_EXL DISK new_excel.xht

DEFINE  FILE MERGE_TEST
 CHNG_FLAG/A1   = IF LINE CONTAINS '=xl101' THEN 'Y' ELSE 'N' ;
 NEW_LINE/A1000 = STRREP (1000, LINE, 5, 'xl101', 15, 'xl101 colspan=2', 1000, 'A1000') ;
 NEW_LEN/I9     = ARGLEN(1000, NEW_LINE, NEW_LEN) ;
END
TABLE   FILE MERGE_TEST
 PRINT  
        COMPUTE OUT_RES/I1 = PUTDDREC ('NEW_EXL',7,NEW_LINE, NEW_LEN,OUT_RES) ;

 WHERE  LAST CHNG_FLAG EQ 'N'

 ON     TABLE SAVE AS TMP_OUT

END

-RUN

SET HTMLFORMTYPE = XLS

-HTMLFORM NEW_EXL