Hello All,

I have a little challenge...
I have to create a mini-dashboard on a PDF page.
Basically i have 7 mini reports to fit on one page.
How i wanted to go about it, was to create all 7 reports and save them as images
then arrange the images accordingly on the PDF page:

i.e.

-* first report
TABLE FILE CAR
PRINT SALES
BY MODEL
ON TABLE HOLD AS IMG1 FORMAT GIF
END

-* second report
TABLE FILE CAR
PRINT SALES
BY BODYTYPE
ON TABLE HOLD AS IMG2 FORMAT GIF
END

-* main
TABLE FILE CAR
SUM SALES NOPRINT
HEADING
""First Report"
""Second Report"
...
ON TABLE SET STYLE *
TYPE=REPORT,IMAGE=IMG1.GIF,POSITION=(0.5 0.6),SIZE(2.2 2.2),$
TYPE=REPORT,IMAGE=IMG2.GIF,POSITION=(0.5 2.6),SIZE(2.2 2.2),$
....
ON TABLE PCHOLD FORMAT PDF
ENDSTYLE
END

The thing is that when I hold my reports as GIF or PNG I get the following error message:
(FOC36380) SPECIFIED HOLD FORMAT IS ONLY VALID WITH GRAPH REQUESTS


would there be a way around that? ? ?

Thanks in advance

Cynthia

Cynthia,

In the Graphical Tools manual:

COMPOUND LAYOUT PDF

Thanks!

Cynthia

Hello Hello

so here is the deal, I'm trying to put together this "Dashboard"
I am trying to do with with the PDF Layout Painter as suggested by Tom
Im currently testing some scenarios. I have imported 2 fexes in the pdf layout painter however only one report
is displayed when i run it.
The problem seems to be related to the USE command?
I have tried removing the USE and it works. However with my report specs i need to use USE, is there a way to make it work?

sample code:

-* File NEW
-* Default Mode: ResourceLayout
COMPOUND LAYOUT
UNITS=IN, $
SECTION=section1, LAYOUT=ON, MERGE=ON, ORIENTATION=PORTRAIT, PAGESIZE=Letter, $
pagelayout=1, name='Layout page 1', $
object=box, name='line1', position=(3.219 5.927), dimension=(0.063 0.063), backcolor=RGB(0 0 0), border-color=RGB(0 0 0), $
component='report1', type=report, position=(0.938 0.625), dimension=(4.271 0.938), $
component='report2', type=report, position=(0.938 2.292), dimension=(4.271 0.833), $
END
SET COMPONENT='report1'
-*component_type report
-SET &ECHO = ALL;
USE CLEAR *
USE
FIRST NEW
SECOND NEW
END
-*--first part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'CONVERTIBLE';
ON TABLE HOLD AS FIRST FORMAT FOCUS
END
-*-second part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'SEDAN';
ON TABLE HOLD AS SECOND FORMAT FOCUS
END
USE
FIRST AS FIRST
SECOND AS FIRST
END
TABLE FILE FIRST
SUM
SEATS
BY BODYTYPE
ON TABLE SET PAGE NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE PCHOLD FORMAT PDF
END
SET COMPONENT='report2'
-*component_type report
-SET &ECHO = ALL;
USE CLEAR *
USE
FIRST_A NEW
SECOND_A NEW
END
-*--first part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'ROADSTER';
ON TABLE HOLD AS FIRST_A FORMAT FOCUS
END
-*-second part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'HARDTOP';
ON TABLE HOLD AS SECOND_A FORMAT FOCUS
END
USE
FIRST_A AS FIRST_A
SECOND_A AS FIRST_A
END
TABLE FILE FIRST_A
SUM
SEATS
BY BODYTYPE
ON TABLE SET PAGE NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE PCHOLD FORMAT PDF
END
COMPOUND END



Cynthia

Cynthia

There is a lot wrong in this report.

1) a dashboard is as far as I know something you display on your website, what you are trying to do is building an compound pdf report.
that is not the most easy thing to start with.

2) one or more of your components seems to be a graph.
A graph can be generated with Webfocus by the graph function.
You start it with

GRAPH FILE CAR
SUM SALES
BY COUNTRY

....
END

A graph can be saved as SVG file, this file can be used in a compound report and then you can position it somewhere in your report in combination with free text or some tables.

2) why are you using USE? what is the purpose of this all?
Are the two separated reports running without the compound commands?

Hi Frank,

1) I know what a dashboard is. I put the term dashboard in quotes because im trying to reproduce a similar
effect using PDF.

What i want to create is one pdf page with multiple reports using the PDF Layout Painter.


2) There are no graphs in my report. (unless my specs change along the way)
but I am aware of how to save/create graphs.


2) The sample code i posted was to show the concept...
The reason I am using the USE command is to merge two data sets together...

As for the compound commands if you mean OPEN/CLOSE ...from what I have been reading, this syntax is not used with the PDF Layout Painter.

try changing the merge=on to merge=off. I'm not quite understanding what the gui is doing with this settting, but the output was very different and looks like what I would expect - don't know if it's what you were expecting

Cynthia,

Sorry, I've been on the road; your code is perfect, EXCEPT, set MERGE=OFF, and, I changed the POSITION for side-by-side report.

Also, you don't need your USE until the PDF steps:

COMPOUND LAYOUT
UNITS=IN, $
SECTION=section1, LAYOUT=ON, MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, $
pagelayout=1, name='Layout page 1', $
object=box, name='line1', position=(3.219 5.927), dimension=(0.063 0.063), backcolor=RGB(0 0 0), border-color=RGB(0 0 0), $
component='report1', type=report, position=(0.938 0.625), dimension=(4.271 0.938), $
component='report2', type=report, position=(4.938 0.625), dimension=(4.271 0.833), $
END
SET COMPONENT='report1'
-*component_type report
-SET &ECHO = ALL;
-*--first part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'CONVERTIBLE';
ON TABLE HOLD AS FIRST FORMAT FOCUS
END
-RUN
-*-second part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'SEDAN';
ON TABLE HOLD AS SECOND FORMAT FOCUS
END
-RUN
USE
FIRST AS FIRST
SECOND AS FIRST
END
-RUN
TABLE FILE FIRST
HEADING CENTER
"Convertible/Sedan"
SUM
SEATS
BY BODYTYPE
ON TABLE SET PAGE NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE PCHOLD FORMAT PDF
END
-RUN
SET COMPONENT='report2'
-*component_type report
-SET &ECHO = ALL;
-*--first part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'ROADSTER';
ON TABLE HOLD AS FIRST_B FORMAT FOCUS
END
-RUN
-*-second part
TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'HARDTOP';
ON TABLE HOLD AS SECOND_B FORMAT FOCUS
END
-RUN
USE
FIRST_B AS FIRST_B
SECOND_B AS FIRST_B
END
-RUN
TABLE FILE FIRST_B
"Roadster/Hardtop"
SUM
SEATS
BY BODYTYPE
ON TABLE SET PAGE NOLEAD
ON TABLE SET SQUEEZE ON
ON TABLE PCHOLD FORMAT PDF
END
COMPOUND END
-EXIT

Keep going and I will monitor, that is, if you need any more assistance; I'm sure you are getting it.

A good way to test is to debug each step, i.e.,

TABLE FILE CAR
SUM
SEATS
BY BODYTYPE
WHERE BODYTYPE EQ 'HARDTOP';
-* ON TABLE HOLD AS SECOND_B FORMAT FOCUS
END
-EXIT

Put each step at the top, then test, then move the code back to it's designated spot, uncommenting the ON TABLE HOLD line.

Then, you've put it all together...

Always impressed with people who help themselves!!!

GOOD JOB!!!

Tom

This message has been edited. Last edited by: Tom Flynn,

Thanks for your reply Darin!

Tom,

I have tried your code and it still displays only one report.
I tested it like you have mentioned. The report run fine on their own but together is a different thing...

I have also tried the code with a newer version of Webfocus (7.6.2) on a different computer but no luck...

I'm no expert but I'm starting to think that maybe it's a configuration issue?

I have just opened a case with IBI.

Thanks a lot for your help and words of encouragement!

Cynthia

Just a quick update...

My case is now closed with IBI.
They told me this issue had been fixed in 716 and higher. I tested it with 762 and it worked!!
(Both the Webfocus Client and Webfocus Reporting Server had to be 762).

Cynthia