Hi there,

I'm looking to compile three different Excel output reports to one Excel report with three sheets, is it possible in App studio?

thank you

This message has been edited. Last edited by: FP Mod Chuck,

Hi Badr.A

You can create a compound document and reference the 3 report with the compound document output format of Excel.

quote:

compound document

Thank you!
placing the three tables in one text page and using the syntax

ON TABLE PCHOLD FORMAT EXL2K OPEN
...
ON TABLE PCHOLD FORMAT EXL2K CLOSE

but only one sheet is coming out, do you know why please?

Here's an example using code ... with the CAR/GGSALES/BROKERS files ...

Maybe this will help you get it done with the gui ...

SET EXCELSERVURL = ''
SET NODATA = ' '
-*
TABLE FILE CAR
PRINT
COUNTRY
CAR
MODEL
BODYTYPE
SEATS
SALES
WHERE RECORDLIMIT EQ 5
ON TABLE SET COMPOUND OPEN
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='CAR', $
ENDSTYLE
END
-RUN
TABLE FILE GGSALES
PRINT
SEQ_NO
CATEGORY
PCD
PRODUCT
DATE
UNITS
DOLLARS
WHERE RECORDLIMIT EQ 5
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='GGSALES', $
ENDSTYLE
END
-RUN
TABLE FILE BROKERS
PRINT
BROKER_ID
DEPARTMENTS
BROKER_NAME
WHERE RECORDLIMIT EQ 5
ON TABLE SET COMPOUND CLOSE
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT='BROKERS', $
ENDSTYLE
END
-RUN

I always filedef it to a network file and spit it out this way:

FILEDEF THE_FILE DISK '\\filepath\myfile.xlsx'
-RUN

-*table file 1
ON TABLE HOLD AS THE_FILE FORMAT XLSX OPEN
...
-*table file 2
ON TABLE HOLD AS THE_FILE FORMAT XLSX
...
-*table file 3
ON TABLE HOLD AS THE_FILE FORMAT XLSX CLOSE

that is good it is working now using the syntax, can anyone help me how to do it using the gui pls?

As an alternative to
ON TABLE SET COMPOUND ...
you can place free-standing SET statements
(SET COMPOUND=OPEN and =CLOSE)
before the first and last TABLE requests, resp.

That leaves you free to develop the three requests in the GUI, without coding any Compound-report-specific syntax.

(I would make them separate fex files, invoked by "-INCLUDE" directives)

In the GUI, all you have to do is click on the Insert tab on the ribbon and in the Pages section click on New and add your report to the new page.

Here is some code that was generated using the GUI. If you copy/paste it into a new procedure, save it, and reopen it in the GUI, you can see how it is laid out:

  
-* Default Mode: ResourceLayout
SET HTMLARCHIVE=ON
*-HOLD_SOURCE
COMPOUND LAYOUT PCHOLD FORMAT XLSX
UNITS=IN, $
SECTION=section1, LAYOUT=ON, METADATA='prop_with_names^Margins_Left=0.5^Margins_Top=0.5^Margins_Right=0.5^Margins_Bottom=0.5^thumbnailscale=4', MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, SHOW_GLOBALFILTER=OFF, $
PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2, POSITION=(0.500 0.521), DIMENSION=(7.665 3.437), BYTOC=0,  ARREPORTSIZE=DIMENSION, METADATA='left: 0.5in; top: 0.521in; width: 7.665in; height: 3.437in; position: absolute; z-index: 1;', $
PAGELAYOUT=2, NAME='Page layout 2', text='Page layout 2', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=2, POSITION=(0.604 0.604), DIMENSION=(7.396 2.813), BYTOC=0,  ARREPORTSIZE=DIMENSION, METADATA='left: 0.604in; top: 0.604in; width: 7.396in; height: 2.813in; position: absolute; z-index: 1;', $
PAGELAYOUT=3, NAME='Page layout 3', text='Page layout 3', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report3', TEXT='report3', TOC-LEVEL=2, POSITION=(0.604 0.688), DIMENSION=(7.604 3.958), BYTOC=0,  ARREPORTSIZE=DIMENSION, METADATA='left: 0.604in; top: 0.688in; width: 7.604in; height: 3.958in; position: absolute; z-index: 1;', $
END
SET COMPONENT='report1'
-*component_type report
TABLE FILE CAR
SUM
     DEALER_COST
BY  COUNTRY
BY  CAR
BY  MODEL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET XLSXPAGESETS ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
ENDSTYLE
END
SET COMPONENT='report2'
-*component_type report
TABLE FILE CAR
SUM
     RETAIL_COST
BY  COUNTRY
BY  CAR
BY  MODEL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET XLSXPAGESETS ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
ENDSTYLE
END
SET COMPONENT='report3'
-*component_type report
TABLE FILE CAR
SUM
     SALES
BY  COUNTRY
BY  CAR
BY  MODEL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT XLSX
ON TABLE SET XLSXPAGESETS ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
ENDSTYLE
END
COMPOUND END

thank you!