Hello,

I'm looking to automate this process so I do not have to manually update the file and ftp it.

We have this file in fix format(alpha) that we include the Master file on top of the data. Currently I would cut and paste the master to the file then ftp. The other group prefer fix format and we cannot change the format. Can we add headers to Alpha format?

File looks like this:
#ofrecordsFILE=HOLD ,SUFFIX=FIX
SEGNAME=HOLD ,SEGTYPE=S0
FIELDNAME =UPDATE_DATE ,E01 ,A10 ,A10 ,$
FIELDNAME =REPORT_DATE ,E02 ,A10 ,A10 ,$
FIELDNAME =SUMDIV ,E03 ,A5 ,A05 ,$
FIELDNAME =SUMDIV_NAME ,E04 ,A31 ,A31 ,$
FIELDNAME =DIVISION ,E05 ,A5 ,A05 ,$
FIELDNAME =DIVISION_NAME ,E06 ,A31 ,A31 ,$
FIELDNAME =DISTRICT ,E07 ,A5 ,A05 ,$
FIELDNAME =DISTRICT_NAME ,E08 ,A31 ,A31 ,$
FIELDNAME =AREA ,E09 ,A5 ,A05 ,$
FIELDNAME =AREA_NAME ,E10 ,A31 ,A31 ,$
FIELDNAME =TOP_BRANCH ,E11 ,A5 ,A05 ,$
FIELDNAME =TOP_BRANCH_NAME ,E12 ,A31 ,A31 ,$
FIELDNAME =BRANCH ,E13 ,A4 ,A04 ,$
FIELDNAME =BRANCH_NAME ,E14 ,A31 ,A31 ,$
20110803 201107 SUM SUM OF DIVISIONS DIVISON DIVISION_NAME DISTRICT DISTRICT_NAMET AREA AREA_NAME TOP_BRANCH TOP_BRANCH_NAME BRANCH BRANCH NAME
20110803 201107 SUM SUM OF DIVISIONS DIVISON DIVISION_NAME DISTRICT DISTRICT_NAMET AREA AREA_NAME TOP_BRANCH TOP_BRANCH_NAME BRANCH BRANCH NAME
20110803 201107 SUM SUM OF DIVISIONS DIVISON DIVISION_NAME DISTRICT DISTRICT_NAMET AREA AREA_NAME TOP_BRANCH TOP_BRANCH_NAME BRANCH BRANCH NAME
20110803 201107 SUM SUM OF DIVISIONS DIVISON DIVISION_NAME DISTRICT DISTRICT_NAMET AREA AREA_NAME TOP_BRANCH TOP_BRANCH_NAME BRANCH BRANCH NAME

Code:

TABLE FILE BOD2011
HEADING
""SEGNAME=HOLD ,SEGTYPE=S0"
"FIELDNAME =UPDATE_DATE ,E01 ,A10 ,A10 ,$"
SUM BRANCH_NAME
BY UPDATE_DATE BY REPORT_DATE
BY SUMDIV BY SUMDIV_NAME
BY DIVISION BY DIVISION_NAME
BY DISTRICT BY DISTRICT_NAME
BY AREA BY AREA_NAME
BY TOP_BRANCH BY TOP_BRANCH_NAME
BY BRANCH
ON TABLE PCHOLD FORMAT ALPHA
END

Any assistant would be great

This message has been edited. Last edited by: Kerry,

WF 8105M
- Portal, Dashboard
- Rcaster, Data Migrator
- Windows 2012 Client Server
- Dev/App Studio 8105
- Data: SQL, Oracle, Neteeza,MVS

TABLE FILE BOD2011
HEADING
""SEGNAME=HOLD ,SEGTYPE=S0"
"FIELDNAME =UPDATE_DATE ,E01 ,A10 ,A10 ,$"
SUM BRANCH_NAME
BY UPDATE_DATE BY REPORT_DATE
BY SUMDIV BY SUMDIV_NAME
BY DIVISION BY DIVISION_NAME
BY DISTRICT BY DISTRICT_NAME
BY AREA BY AREA_NAME
BY TOP_BRANCH BY TOP_BRANCH_NAME
BY BRANCH
ON TABLE PCHOLD FORMAT ALPHA
END

Are you asking if the heading can be displayed in "fix format", such as Courier? If so, add the "FONT=(font face) to your stylesheet.

Also, remove the 2nd (of three) double quotes in HEADING LINE 1.

Yes I'm asking if header can display in fix format

Hi,

What I understand from your post is that you want to add the complete master file (of the created datafile) to the datafile itself before sending.
If that's the case, you could do something like this:

-Fred-

-* --------------------------------------------------------------------
-* Create report with data
-* --------------------------------------------------------------------
TABLE FILE CAR
  SUM
    DEALER_COST
  BY COUNTRY
  BY CAR
  BY MODEL
  BY SEATS
  ON TABLE HOLD AS DATAFILE FORMAT ALPHA
END
-RUN

-* --------------------------------------------------------------------
-* Write master for master-info
-* --------------------------------------------------------------------
APP FI MASTFILE DISK MASTFILE.MAS
-RUN
-WRITE MASTFILE SEGMENT=MASTFILE, SEGTYPE=S0, $
-WRITE MASTFILE  FIELDNAME=LINE     ,E01 ,A100     ,ACTUAL=A100 ,$


-* --------------------------------------------------------------------
-* Filedef for reporting on master file
-* --------------------------------------------------------------------
FILEDEF MASTFILE DISK DATAFILE.MAS
-RUN


-* --------------------------------------------------------------------
-* Create mixed file
-* --------------------------------------------------------------------
APP FI FILE2FTP DISK FILE2FTP.MAS (APPEND
-RUN

TABLE FILE MASTFILE
  PRINT *
  ON TABLE SAVE AS FILE2FTP FORMAT ALPHA
END
-RUN
TABLE FILE DATAFILE
  PRINT *
  ON TABLE SAVE AS FILE2FTP FORMAT ALPHA
END
-RUN

-* --------------------------------------------------------------------
-* Check file FILE2FTP (just for debugging)
-* --------------------------------------------------------------------
-HTMLFORM BEGIN
<html>
<pre>
!IBI.FIL.FILE2FTP;
</pre>
</html>
-HTMLFORM END

Thanks Fred!! I'll give that a try.