Hello Everyone,

I have created a KPI in pdf format using the below code. I got it in the expected format except the vertical alignment of a subfoot component. The growth percentage (4%) is at the bottom of the Budget number which is caused by the mandatory styling that is needed.Is it possible to bring it to middle like vertical align:middle? Please let me know your inputs.

8486002 (4%)
Budget


My Code

 
SET PAGE-NUM=OFF

TABLE FILE GGSALES
SUM GGSALES.SALES01.BUDDOLLARS
BY GGSALES.SALES01.CATEGORY
WHERE GGSALES.SALES01.DATE GE 19960101;
WHERE GGSALES.SALES01.DATE LE 19961212;
WHERE GGSALES.SALES01.CATEGORY EQ 'Coffee';
ON TABLE HOLD AS CUR_MTH
END

TABLE FILE GGSALES
SUM GGSALES.SALES01.BUDDOLLARS
BY GGSALES.SALES01.CATEGORY
WHERE GGSALES.SALES01.DATE GE 19970101;
WHERE GGSALES.SALES01.DATE LE 19971212;
WHERE GGSALES.SALES01.CATEGORY EQ 'Coffee';
ON TABLE HOLD AS PREV_MTH
END


JOIN INNER CATEGORY IN CUR_MTH TO CATEGORY IN PREV_MTH  TAG J1 AS 'J1'

TABLE FILE CUR_MTH
PRINT
BUDDOLLARS
J1.BUDDOLLARS
COMPUTE BUD_GROWTH/D8=((BUDDOLLARS-J1.BUDDOLLARS)/J1.BUDDOLLARS)*100;
COMPUTE ABS_BUD_GROWTH/A12=LTRIM(FTOA((ABS(BUD_GROWTH)),'(D8)',ABS_BUD_GROWTH));
COMPUTE GROWTH/A15=('('||ABS_BUD_GROWTH||'%'||')');
BY CATEGORY
ON TABLE HOLD AS BUDGET_WEEK
END


TABLE FILE BUDGET_WEEK
PRINT
BUD_GROWTH NOPRINT
ON TABLE SUBHEAD
"<BUDDOLLARS<+0><GROWTH"
""
"Budget"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
PAGESIZE='ENVELOPE-DL',$
TYPE=REPORT, FONT='Arial',$
TYPE=REPORT, ORIENTATION=LANDSCAPE, $
-*TYPE=TABHEADING,JUSTIFY=CENTER,$
TYPE=TABHEADING, LINE=1, ITEM=1,JUSTIFY=LEFT, OBJECT=FIELD,SIZE=32, STYLE=BOLD,COLOR=RGB(1 40 52), $
TYPE=TABHEADING, LINE=1, ITEM=2,JUSTIFY=LEFT,POSITION=(1.4 0.5),OBJECT=FIELD,SIZE=12,COLOR=RGB(75 205 62),WHEN=BUD_GROWTH GT 0, $
TYPE=TABHEADING, LINE=1, ITEM=2,JUSTIFY=LEFT,POSITION=(1.4 0.5),OBJECT=FIELD,SIZE=12,COLOR=RGB(255 31 62),WHEN=BUD_GROWTH LT 0, $
TYPE=TABHEADING, LINE=3, ITEM=1,JUSTIFY=LEFT, OBJECT=TEXT,SIZE=12,STYLE=NORMAL,COLOR=RGB(1 40 52), $
ENDSTYLE
END
 

This message has been edited. Last edited by: FP Mod Chuck,

Something like this ?

SET PAGE-NUM=OFF

TABLE FILE GGSALES
SUM GGSALES.SALES01.BUDDOLLARS
BY GGSALES.SALES01.CATEGORY
WHERE GGSALES.SALES01.DATE GE 19960101;
WHERE GGSALES.SALES01.DATE LE 19961212;
WHERE GGSALES.SALES01.CATEGORY EQ 'Coffee';
ON TABLE HOLD AS CUR_MTH
END

TABLE FILE GGSALES
SUM GGSALES.SALES01.BUDDOLLARS
BY GGSALES.SALES01.CATEGORY
WHERE GGSALES.SALES01.DATE GE 19970101;
WHERE GGSALES.SALES01.DATE LE 19971212;
WHERE GGSALES.SALES01.CATEGORY EQ 'Coffee';
ON TABLE HOLD AS PREV_MTH
END


JOIN INNER CATEGORY IN CUR_MTH TO CATEGORY IN PREV_MTH  TAG J1 AS 'J1'

TABLE FILE CUR_MTH
PRINT
BUDDOLLARS
J1.BUDDOLLARS
COMPUTE BUD_GROWTH/D8=((BUDDOLLARS-J1.BUDDOLLARS)/J1.BUDDOLLARS)*100;
COMPUTE ABS_BUD_GROWTH/A12=LTRIM(FTOA((ABS(BUD_GROWTH)),'(D8)',ABS_BUD_GROWTH));
COMPUTE GROWTH/A26=('<sup>('||ABS_BUD_GROWTH||'%'||')</sup>');
BY CATEGORY
ON TABLE HOLD AS BUDGET_WEEK
END


TABLE FILE BUDGET_WEEK
PRINT
BUD_GROWTH NOPRINT
ON TABLE SUBHEAD
"<BUDDOLLARS<+0><GROWTH"
""
"Budget"
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
PAGESIZE='ENVELOPE-DL',$
TYPE=REPORT, FONT='Arial',$
TYPE=REPORT, ORIENTATION=LANDSCAPE, $
-*TYPE=TABHEADING,JUSTIFY=CENTER,$
TYPE=TABHEADING, LINE=1, ITEM=1,JUSTIFY=LEFT, OBJECT=FIELD,SIZE=32, STYLE=BOLD,COLOR=RGB(1 40 52), $
TYPE=TABHEADING, LINE=1, ITEM=2,JUSTIFY=LEFT,POSITION=(1.4 0.5),OBJECT=FIELD,SIZE=20,COLOR=RGB(75 205 62),WHEN=BUD_GROWTH GT 0, MARKUP=ON, $
TYPE=TABHEADING, LINE=1, ITEM=2,JUSTIFY=LEFT,POSITION=(1.4 0.5),OBJECT=FIELD,SIZE=20,COLOR=RGB(255 31 62),WHEN=BUD_GROWTH LT 0, MARKUP=ON, $
TYPE=TABHEADING, LINE=3, ITEM=1,JUSTIFY=LEFT, OBJECT=TEXT,SIZE=12,STYLE=NORMAL,COLOR=RGB(1 40 52), $
ENDSTYLE
END

It uses a setting called MARKUP and I've set the string to superscript and adjusted the size to set it to the vertical middle of the line.

Hello Waz,

Thank you very much for your inputs.Could you provide your input on just one more thing? You may have seen the Budget dollar number is not exactly left even though it is justified left in the stylesheet. It is because of it's size(32), is it possible to justify it to left and still keep the same size.

Best Regards

My initial thoughts would be to convert the value to text and left justify.

quote:

thoughts would be to convert the value to text and left justify.

I agree Waz... convert the value to text and left justify. that 'space' to the left of the number is reserved for the 'sign' (+ or -)...

Or, maybe, change them in the HOLD Files using the ABS Values.