[SOLVED] Space between Title and Data

October 28, 2010, 06:16 AM

Ram Prasad E

Ram, You need to insert that many rows into the hold file. Either use -WRITE in case of ALPHA hold file or Use MATCH command or SQL Translator to insert into FOCUS File.

DEFINE FILE CAR
DUMMY_1/A1='2';
END
TABLE FILE CAR
PRINT
CAR
COUNTRY
BY DUMMY_1
ON TABLE HOLD AS HLD_1 FORMAT ALPHA
END
DEFINE FILE CAR
DUMMY_1/A1='1';
END
TABLE FILE CAR
SUM
COMPUTE SALES1/D20=SALES;
BY DUMMY_1
BY COUNTRY
WHERE COUNTRY EQ 'ENGLAND' OR 'ITALY'
ON TABLE HOLD AS HLD_2 FORMAT ALPHA
END

MATCH FILE HLD_1
PRINT
CAR
COUNTRY
BY DUMMY_1
RUN
FILE HLD_2
PRINT
SALES1
BY DUMMY_1
AFTER MATCH HOLD OLD-OR-NEW
END
-RUN
TABLE FILE HOLD
PRINT
CAR AS 'Car'
COUNTRY AS 'Country'
BY DUMMY_1 NOPRINT
END

In Focus since 1993. WebFOCUS 7.7.03 Win 2003

October 28, 2010, 10:21 AM

GamP

My mistake, should not be on TABLE but on a field. Like:

DEFINE FILE CAR
SPACE/A1=' ';
END
TABLE FILE CAR
PRINT CAR SALES
BY SPACE NOPRINT
ON SPACE SUBHEAD
" " 
" "
END

GamP

- Using AS 8.2.01 on Windows 10 - IE11.
	in Focus since 1988

October 28, 2010, 10:38 AM

RSquared

Using Gamp's first idea, you can make the TITLE a header / sub header followed by 2 empty lines.

WF 7.6.11
Oracle
WebSphere
Windows NT-5.2 x86 32bit

October 28, 2010, 04:59 PM

Waz

The issue with this solution is that it will only work on the first page.

Perhaps this may help. It expands on GamP's suggestion.

DEFINE FILE TRADES
CNTR/I9 = LAST CNTR  + 1 ;
END
TABLE FILE TRADES
PRINT *
      TABPAGENO
BY CNTR NOPRINT
ON CNTR SUBHEAD
" " 
" "
WHEN TABPAGENO NE LAST TABPAGENO

WHERE RECORDLIMIT EQ 100
END

Waz...

Prod:	WebFOCUS 7.6.10/8.1.04	Upgrade:	WebFOCUS 8.2.07	OS:	Linux	Outputs:	HTML, PDF, Excel, PPT
In Focus since 1984
Pity the lost knowledge of an old programmer!

October 29, 2010, 03:59 AM

Ramkumar - Webfous

quote:
DEFINE FILE CAR
SPACE/A1=' ';
END
TABLE FILE CAR
PRINT CAR SALES
BY SPACE NOPRINT
ON SPACE SUBHEAD
" "
" "
END

Waz and Gamp.. That worked perfect. Thank you folks for your kind reply.

Thanks,

Ramkumar.
WebFOCUS/Tableau
Webfocus 8 / 7.7.02
Unix, Windows
HTML/PDF/EXCEL/AHTML/XML/HTML5

October 29, 2010, 04:18 AM

Håkan

Try this

TABLE FILE CAR
PRINT COUNTRY AS 'COUNTRY, , , '
END

WebFOCUS DS 8.0.06/08 DS/AS
WebFOCUS RS 8.0.08 (Linux/IBM i)
WebFOCUS Client 8.0.06 (Linux)

October 29, 2010, 09:02 AM

Prarie

H,

That's a new on me. I think that is what they wanted.

October 29, 2010, 09:29 AM

linus

I think this gives you what you're looking for and it's extremely simple coding. You will need stylesheet logic to place your heading properly.

  
DEFINE FILE CAR
BLANK/A1 = '';
END
TABLE FILE CAR
HEADING
"COUNTRY <+0> CAR <+0> SALES"
PRINT BLANK AS ''
OVER
BLANK AS ''
OVER
COUNTRY AS ''
CAR AS ''
SALES AS ''
BY COUNTRY NOPRINT
END
-EXIT

WF 7.7.05
HP-UX - Reporting Server, Windows 2008 - Client, MSSQL 2008, FOCUS Databases, Flat Files
HTML, Excel, PDF

October 29, 2010, 10:15 AM

Ramkumar - Webfous

In this case bordering will be quite a problem....

PRINT COUNTRY AS 'COUNTRY, , , '

Because, the entire title will be boxed.

I used Gamp's code

DEFINE FILE CAR
SPACE/A1=' ';
END
TABLE FILE CAR
PRINT CAR SALES
BY SPACE NOPRINT
ON SPACE SUBHEAD
" "
" "
END

and Styled Subhead to make all borders transparent. That made it perfect.

Thanks,

Ramkumar.
WebFOCUS/Tableau
Webfocus 8 / 7.7.02
Unix, Windows
HTML/PDF/EXCEL/AHTML/XML/HTML5