How can I default today's date to a calendar default from a fex to a launch page. We usually do this default:
-DEFAULT &BEGIN_DATE = '01/01/2007';
-DEFAULT &END_DATE = '12/31/2007';
and this will be shown on the launch page for these (calender ) fields.
Now, I want to calculate today's date and assign it to the end_date and &begin_date to be something else depending on the requirement..I tried -set with the calculation first then assign that &var to the -default &begin_date and &end_date. It does not work. why?
Any help is appreciated.

The todays date is an system amper value &DATE

You can calculate the first day of the actual year based on that date if that is what you want.

I need the documentation to give you the exact formulas. (tomorrow)

Thanks Frank. I will look for your document tomorrow again.
BTW, I sat in your session in Vegas. Were you the one in green pants? :-D

I do not have green pants....
I was in many sessions, but always as public...

kmafu,

Use the DATEMOV function, but make sure you use the correct date format for the input date -

-SET &STARTDATE   = '30/11/2006';
-SET &STARTYYMD   = DATECVT(EDIT('&STARTDATE.EVAL','99$99$9999'), 'A8DMYY', 'YYMD');
-SET &STARTofYEAR = DATECVT(DATEMOV(&STARTYYMD,'BOY'), 'YYMD', 'I8YYMD');
-? &START

Where BOY can be one of -

EOM is the end of month.
BOM is the beginning of month.
EOQ is the end of quarter.
BOQ is the beginning of quarter.
EOY is the end of year.
BOY is the beginning of year.
EOW is the end of week.
BOW is the beginning of week.
NWD is the next weekday.
NBD is the next business day.
PWD is the prior weekday.
PBD is the prior business day.
WD- is a weekday or earlier.
BD- is a business day or earlier.
WD+ is a weekday or later.
BD+ is a business day or later.

A business day calculation is affected by the BUSDAYS and HDAY parameter settings.

T

This message has been edited. Last edited by: Tony A,

We have put these settings in the EDASPROV.PRF file so we can use them in all programs (see the double ampersands)

-* this settings are in my EDASPROFso we have them in all our reports available

-SET &DOWK = DOWK(&YYMD,'A4');
-SET &DIFF = IF &DOWK EQ 'MON' THEN -3 ELSE
-                   IF &DOWK EQ 'SUN' THEN -2 ELSE -1;
-* this can be corrected for the holiday calander
-* calculates the previous working day
-SET &&VRG_WRKDAG = AYMD(&YYMD, &DIFF, 'I8YYMD'); 
-*
-* calculate the actual year
-* and the prvious two years
-SET &&LPD_JAAR   = EDIT('&&VRG_WRKDAG.EVAL','9999'); 
-SET &&VRG_JAAR   = &&LPD_JAAR.EVAL - 1;
-SET &&VRG_JR2    = &&LPD_JAAR.EVAL - 2;
-*
-* the actual month based on the preious working day as 'YYYYMM'
-* and the act month
-SET &&LPD_JRMND  = EDIT('&&VRG_WRKDAG.EVAL','999999');
-SET &LPD_MND    = EDIT('&&VRG_WRKDAG.EVAL','$$$$99');
-*
-* the previous month and year as 'YYYYMMD'
-SET &VRG_MNDNUM = IF &LPD_MND.EVAL EQ 1 THEN  12 ELSE &LPD_MND.EVAL - 1;
-SET &VRG_MND    = IF &VRG_MNDNUM.EVAL LT 10 THEN '0'||'&VRG_MNDNUM.EVAL' ELSE '&VRG_MNDNUM.EVAL';
-SET &&VRG_JRMND  = IF &LPD_MND.EVAL EQ 1 THEN '&&VRG_JAAR.EVAL'||'1201' ELSE '&&LPD_JAAR.EVAL'||'&&VRG_MND.EVAL'||'01';
-* 
-* first day of the actual month and the actual year
-SET &&LPD_JMD    = '&&LPD_JRMND.EVAL'||'01';
-SET &&NIEUWJAAR  = '&&LPD_JAAR.EVAL' || '0101';
-* and convert the first day of the year to a number
-SET &&DAGNUMNJ   = DATECVT(&&NIEUWJAAR, 'I8YYMD', 'I8');
-*
-* the same with the previous year
-SET &&VRG_JMD    = '&&VRG_JAAR.EVAL'||'0101';
-SET &&DAGNUMVJ   = DATECVT(&&VRG_JMD, 'I8YYMD', 'I8');
-*
-* convert the last working day to a number
-SET &&DAGNUM     = DATECVT(&&VRG_WRKDAG, 'I8YYMD', 'I8');
-*