Focal Point
[CLOSED] Compound report with drillthrough

This topic can be found at:
https://forums.informationbuilders.com/eve/forums/a/tpc/f/7971057331/m/6487032276

August 18, 2014, 11:45 AM
SWES
[CLOSED] Compound report with drillthrough
I'm trying to realize a compound report with drillthrough functionality (multiple components on top page and the next pages based upon detail from second component on top page, PDF). Going through the documentation it looks like that must be possible. However, the examples given are not very helpful for me.

Does anyone have some example code (car) for this?

This message has been edited. Last edited by: <Kathryn Henning>,


WebFOCUS 8105m
Windows 7, All Outputs

Member of the Benelux Usergroup
August 18, 2014, 01:06 PM
susannah
my guess is that you are forgetting to set your FOCEXURL
A PDF file won't be on your server, so it won't have anyway of knowing how to execute your drill. so you have to tell it.
In the code below, the app that i wrote it in is 'xsusantest', which is off-path, so i had to specifically provide it in the drilldown fexname.
SET FOCEXURL = http://&SERVERNAME|:&SERVER_PORT|/ibi_apps/WFServlet
-SET &fexname  = 'test_pdfdd';
-SET &DDO      = 'xsusantest/'|&fexname ;
-DEFAULT &WFFMT = 'PDF';
-DEFAULT &MYCAR = 'ALL';
-SET &filterCAR = IF &MYCAR.QUOTEDSTRING EQ 'ALL' THEN '' ELSE 'IF CAR EQ ''' | &MYCAR | '''';
TABLE FILE IBISAMP/CAR
BY COUNTRY BY CAR BY MODEL SUM SALES
&filterCAR
ON TABLE PCHOLD FORMAT &WFFMT
ON TABLE SET STYLE *
TYPE=DATA,TARGET=BLANK, COLUMN=CAR,FOCEXEC=&DDO(MYCAR = CAR WFFMT = 'PDF' ),$
END





In Focus since 1979///7706m/5 ;wintel 2008/64;OAM security; Oracle db, ///MRE/BID
August 25, 2014, 11:19 AM
SWES
Thank you for your reply Susan. Let me be more specific:

I'm using this documentation:
LINK

However, the syntax which IBI presents in the end:

 SET SQUEEZE=ONTABLE FILE GGSALESSUM UNITS BUDUNITS DOLLARS BUDDOLLARSBY CATEGORY NOPRINT BY PRODUCT NOPRINTON CATEGORY PAGE-BREAKHEADING CENTER"Category: <CATEGORY"" "ON PRODUCT SUBHEAD"**** Product: <PRODUCT"BY REGION BY CITYON TABLE PCHOLD FORMAT PDF CLOSEON TABLE SET STYLE *TYPE=SUBHEAD, LINE=1, ITEM=2, DRILLTHROUGH=FIRST(CATEGORY PRODUCT),COLOR=RED, $ENDSTYLEEND 


Is not the syntax for a compound PDF, which is sort of this:

[CODE] -* Coordinated Report
SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=IN, $
SECTION=section1, LAYOUT=ON, METADATA='0.5^0.5^0.5^0.5^1', MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, $
PAGELAYOUT=1, NAME='Layout page 1', text='Layout page 1', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=1, POSITION=(0.501 0.501), DIMENSION=(7.501 3.973), METADATA='Z-INDEX: 100; POSITION: absolute; WIDTH: 7.501in; HEIGHT: 3.973in; TOP: 0.501in; LEFT: 0.501in', $
PAGELAYOUT=2, NAME='Layout page 2', text='Layout page 2', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report3', TEXT='report3', TOC-LEVEL=1, POSITION=(0.499 0.496), DIMENSION=(7.496 4.641), METADATA='Z-INDEX: 100; POSITION: absolute; WIDTH: 7.496in; HEIGHT: 4.641in; TOP: 0.496in; LEFT: 0.499in', $
PAGELAYOUT=3, NAME='Layout page 3', text='Layout page 3', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=1, POSITION=(0.499 0.810), DIMENSION=(7.500 5.516), METADATA='Z-INDEX: 100; POSITION: absolute; WIDTH: 7.5in; HEIGHT: 5.516in; TOP: 0.81in; LEFT: 0.499in', $
END
SET COMPONENT='report2'
-*component_type report
TABLE FILE CAR
PRINT
LENGTH
WIDTH
BY COUNTRY
BY BODYTYPE
BY MODEL
WHERE COUNTRY EQ '&COUNTRY';
HEADING
"CAR SPECS"
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
END
/CODE]

I'm trying to include three components in the compound, where the second component is generating the compound report.


WebFOCUS 8105m
Windows 7, All Outputs

Member of the Benelux Usergroup
August 28, 2014, 02:53 AM
SWES
Has anyone tried this before?


WebFOCUS 8105m
Windows 7, All Outputs

Member of the Benelux Usergroup
August 28, 2014, 11:15 PM
StuBouyer
You seem to be missing some components in there.

Try this:

-* Default Mode: ResourceLayout
SET HTMLARCHIVE=ON
*-HOLD_SOURCE
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=IN, $
SECTION=section1, LAYOUT=ON, METADATA='prop_with_names^Margins_Left=0.5^Margins_Top=0.5^Margins_Right=0.5^Margins_Bottom=0.5^thumbnailscale=4', MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, SHOW_GLOBALFILTER=OFF, $
PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2, POSITION=(0.813 0.833), DIMENSION=(7.292 2.500), BYTOC=0,  DRILLMAP=((L1 report2)),  ARREPORTSIZE=DIMENSION, METADATA='left: 0.813in; top: 0.833in; width: 7.292in; height: 2.5in; position: absolute; z-index: 1;', $
PAGELAYOUT=2, NAME='Page layout 2', text='Page layout 2', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=2, POSITION=(0.604 0.708), DIMENSION=(7.500 5.104), BYTOC=0,  DRILLMAP=((L1 report3)),  ARREPORTSIZE=DIMENSION, METADATA='left: 0.604in; top: 0.708in; width: 7.5in; height: 5.104in; position: absolute; z-index: 3;', $
PAGELAYOUT=3, NAME='Page layout 3', text='Page layout 3', TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5, METADATA='BOTTOMMARGIN=0.5,TOPMARGIN=0.5,LEFTMARGIN=0,RIGHTMARGIN=0,', $
COMPONENT='report3', TEXT='report3', TOC-LEVEL=2, POSITION=(0.500 0.688), DIMENSION=(7.500 5.208), BYTOC=0,  ARREPORTSIZE=DIMENSION, METADATA='left: 0.5in; top: 0.688in; width: 7.5in; height: 5.208in; position: absolute; z-index: 5;', $
END
SET COMPONENT='report1'
-*component_type report
TABLE FILE CAR
SUM
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
     CAR.BODY.SALES
BY  LOWEST CAR.ORIGIN.COUNTRY
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=DATA,
     COLUMN=N1,
     DRILLTHROUGH=DOWN( \
     CAR.ORIGIN.COUNTRY=N1 \
     ),
$
ENDSTYLE
END
SET COMPONENT='report2'
-*component_type report
TABLE FILE CAR
PRINT
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
     CAR.BODY.SALES
BY  LOWEST CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR

ON CAR.ORIGIN.COUNTRY PAGE-BREAK
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=DATA,
     COLUMN=N2,
     DRILLTHROUGH=DOWN( \
     CAR.COMP.CAR=N2 \
     ),
$
ENDSTYLE
END
SET COMPONENT='report3'
-*component_type report
TABLE FILE CAR
PRINT
     CAR.BODY.DEALER_COST
     CAR.BODY.RETAIL_COST
     CAR.BODY.SALES
BY  LOWEST CAR.ORIGIN.COUNTRY NOPRINT
BY  LOWEST CAR.COMP.CAR
BY  LOWEST CAR.CARREC.MODEL

ON CAR.COMP.CAR PAGE-BREAK
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
ENDSTYLE
END
COMPOUND END
  


Cheers

Stu


WebFOCUS 8.2.03 (8.2.06 in testing)